Creating a panel to group items in

[dinodod]

I am trying to create a panel that I can use to basically group things in and manage via the panel, not each item.

I am trying to create a panel where I can hide all my controls with 1 command rather than have to hide each control individually. I've tried various controls but alas, still to no avail.

Is this possible?

[FuryCell]

Did you try tab controls?

Edited January 13, 2007 by SolidSnake

[GaryFrost]

or child windows

[CompWiz]

I don't think there is any way to hide an entire group at once

[GaryFrost]

I don't think there is any way to hide an entire group at once

Think again, two choices have already been suggested.

[CompWiz]

The way I read it though is that using just a single GUI not child windows and tabs there is no other way. The post was asking about a way to hide all controls at once and I know there has been several times I needed to do this and tabs and child windows just won't work. They will hide it but sometimes you just can't incorpate them and in that case there is no other way of doing so without hiding them all individually.

[GaryFrost]

The way I read it though is that using just a single GUI not child windows and tabs there is no other way. The post was asking about a way to hide all controls at once and I know there has been several times I needed to do this and tabs and child windows just won't work. They will hide it but sometimes you just can't incorpate them and in that case there is no other way of doing so without hiding them all individually.

Sure you can with a child window, have done it myself before, actually with one project we had several child windows with controls on each windows and depending on the tab or button pressed would show/hide a window(s).

[dinodod]

Thank you for your replies. I've heard of child windows and was thinking of them a bit but alas I can not find any such option to make them. From my research in google and the forums, it sounds like I would be making another GUI alltogether? I've seen several posts where they use GUISETSTATE and hide the buttons, etc and wasn't sure if that was part of it.

If there is an example I can be referred to (complete working code of course), I wil assimilate the code and learn from it.

I appreciate the help greatly.

I'll be posting another question here that maybe you've seen as well. Look for my new post.

Thanks!

[GaryFrost]

expandcollapse popup

#include <GUIConstants.au3>

_Main()

Func _Main()
    Local $nFileMenu, $nExititem, $GUIMsg, $hGUI, $h_cGUI, $h_cGUI2
    Local $button, $button2

    $hGUI = GUICreate("My GUI", 500, 500, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU))
    GUISetBkColor(0x88AABB)
    $nFileMenu = GUICtrlCreateMenu("File")
    $nExititem = GUICtrlCreateMenuitem("Exit", $nFileMenu)
    
    $h_cGUI = GUICreate("Child GUI 1", 250, 200, 0, 0, $WS_CHILD, $WS_EX_CLIENTEDGE, $hGUI)
    GUISetBkColor(0X006400)
    $listview = GUICtrlCreateListView("col1  |col2|col3  ", 10, 10, 200, 150)
    $button = GUICtrlCreateButton("Hide", 75, 170, 70, 20)
    For $x = 1 To 30
        GUICtrlCreateListViewItem("item" & $x & "|col2|col3", $listview)
    Next
    GUISetState(@SW_SHOW, $h_cGUI)

    GUISwitch($hGUI)
    $button2 = GUICtrlCreateButton("UnHide", 75, 250, 70, 20)
    GUICtrlSetState($button2, $GUI_DISABLE)

    GUISetState(@SW_SHOW, $hGUI)

    While 1
        $GUIMsg = GUIGetMsg()

        Switch $GUIMsg
            Case $GUI_EVENT_CLOSE, $nExititem
                ExitLoop
            Case $button
                GUISetState(@SW_HIDE, $h_cGUI)
                GUICtrlSetState($button2, $GUI_ENABLE)
            Case $button2
                GUISetState(@SW_SHOW, $h_cGUI)
                GUICtrlSetState($button2, $GUI_DISABLE)
        EndSwitch
    WEnd

    Exit
EndFunc   ;==>_Main

[dinodod]

I'll be darned. That might just be the trick!

Thanks very much!

[Richard Robertson]

Every control on a window is a child window. Every control with controls in it, has subchildren, but they are enumerated strangely sometimes.