List Folder in Menu...

[HardHackz]

Is it possible to make a menu that reads all the files in a certain folder? Such as the start menu does. Here is my script:

http://www.esnips.com/web/AutoIT-Scripts

It's the only one there, I want to add a menu that is called Desktop and has links to all the files/directories on the desktop.

[_Kurt]

Perhaps you are looking for something like this:

;Quick example
;Note: parts of the code were taken from the helpfile

; Shows the filenames of all files in the current directory.
$search = FileFindFirstFile("*.*");Note you could only search a specific filetype if needed
                                  ;Example: FileFindFirstFile("*.au3") <-- Finds .au3 files inside the directory

; Check if the search was unsuccessful
If $search = -1 Then ;If $search returns -1, it has failed to find any files
    MsgBox(0, "Error", "No files/directories matched the search pattern")
    Exit
EndIf

While 1
    $file = FileFindNextFile($search) ;Find next existing file in the directory
    If @error Then ;Until the function fails, we continue to loop
        ExitLoop   ;If $file failed, meaning there are no more files left in the directory, we exit.
    Else           ;If the function succeeded then
        $readfile = FileRead($file) ;Read the text within the file
        MsgBox(0,"","The following are lines read from the file:" & @CRLF & $file & @CRLF & @CRLF & $readfile);Msgbox :)
    EndIf
WEnd

Basically reads each existing file in a directory, hope that helps.

Kurt

[HardHackz]

Ehh...kinda, that reads a file, I want to be able to see the names of the files and be able to click on them and open it.

[_Kurt]

Ugh, FINE. Another excellent example:

expandcollapse popup

#include <GUIConstants.au3>
#Include <GuiList.au3>

Local $data = ""

; Shows the filenames of all files in the current directory.
$search = FileFindFirstFile("*.*");Note you could only search a specific filetype if needed
                                  ;Example: FileFindFirstFile("*.au3") <-- Finds .au3 files inside the directory

; Check if the search was unsuccessful
If $search = -1 Then ;If $search returns -1, it has failed to find any files
    MsgBox(0, "Error", "No files/directories matched the search pattern")
    Exit
EndIf

While 1
    $file = FileFindNextFile($search) ;Find next existing file in the directory
    If @error Then ;Until the function fails, we continue to loop
        ExitLoop   ;If $file failed, meaning there are no more files left in the directory, we exit.
    Else           ;If the function succeeded then
        $readfile = FileRead($file) ;Read the text within the file
        $data     = $data & $file & "|"
    EndIf
WEnd

GUICreate("", 300, 450)
$List = GUICtrlCreateList("", 5, 5, 290, 390, BitOR($WS_BORDER, $WS_VSCROLL))
GUICtrlSetData(-1,$data)
$OK   = GUICtrlCreateButton("Read File", 5, 410, 290, 20)
GUISetState()

While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $OK
            $index = _GUICtrlListGetCaretIndex($List)
            $path  = _GUICtrlListGetText($List, $index)
            $read  = FileRead($path)
            MsgBox(0,"",$read)
        Case $msg = $GUI_EVENT_CLOSE
            Exit
    EndSelect
WEnd

Kurt

EDIT: Minor correction in script

Edited February 28, 2007 by _Kurt

[MrCreatoR]

HardHackz

Hi,

Here is example of what i think you want to acomplish (It lists in to menu all links from desktop, and all shortcuts from favorites directory) :

expandcollapse popup

Opt("GuiOnEventMode", 1)
Opt("RunErrorsFatal", 0)

$DesktopDir = @DesktopDir
$FavoritesDir = @FavoritesDir
$DirsArr = StringSplit($DesktopDir & "|" & $FavoritesDir, "|")


GUICreate("Files List In Menu Demo", 300, 200, 0, 0)
GUISetOnEvent(-3, "Quit")

$MainMenuID = GUICtrlCreateMenu("Files List")
$DesktopMenu = GUICtrlCreateMenu("Desktop", $MainMenuID)
$FavoritesMenu = GUICtrlCreateMenu("Favorites", $MainMenuID)

GUISetState()

;Searching for Desktop
$FindFirstFile = FileFindFirstFile($DesktopDir & "\*.lnk")
Do
    $NextFileSearch = FileFindNextFile($FindFirstFile)
    If @error Then ExitLoop
    GUICtrlCreateMenuitem($NextFileSearch, $DesktopMenu)
    GUICtrlSetOnEvent(-1, "DesktopMenuItem")
Until @error
FileClose($NextFileSearch)

;Searching for favorites
$FindFirstFile = FileFindFirstFile($FavoritesDir & "\*.url")
Do
    $NextFileSearch = FileFindNextFile($FindFirstFile)
    If @error Then ExitLoop
    GUICtrlCreateMenuitem($NextFileSearch, $FavoritesMenu)
    GUICtrlSetOnEvent(-1, "FavoritesMenuItem")
Until @error
FileClose($NextFileSearch)


While 1
    Sleep(100)
WEnd

Func Quit()
    Exit
EndFunc

Func DesktopMenuItem()
    $FileName = GUICtrlRead(@GUI_CtrlId, 1)
    ShellExecute($DesktopDir & "\" & $FileName)
EndFunc

Func FavoritesMenuItem()
    $FileName = GUICtrlRead(@GUI_CtrlId, 1)
    ShellExecute($FavoritesDir & "\" & $FileName)
EndFunc

Edited February 28, 2007 by MsCreatoR

[HardHackz]

HardHackz

Hi,

Here is example of what i think you want to acomplish (It lists in to menu all links from desktop, and all shortcuts from favorites directory) :

expandcollapse popup

Opt("GuiOnEventMode", 1)
Opt("RunErrorsFatal", 0)

$DesktopDir = @DesktopDir
$FavoritesDir = @FavoritesDir
$DirsArr = StringSplit($DesktopDir & "|" & $FavoritesDir, "|")
GUICreate("Files List In Menu Demo", 300, 200, 0, 0)
GUISetOnEvent(-3, "Quit")

$MainMenuID = GUICtrlCreateMenu("Files List")
$DesktopMenu = GUICtrlCreateMenu("Desktop", $MainMenuID)
$FavoritesMenu = GUICtrlCreateMenu("Favorites", $MainMenuID)

GUISetState()

;Searching for Desktop
$FindFirstFile = FileFindFirstFile($DesktopDir & "\*.lnk")
Do
    $NextFileSearch = FileFindNextFile($FindFirstFile)
    If @error Then ExitLoop
    GUICtrlCreateMenuitem($NextFileSearch, $DesktopMenu)
    GUICtrlSetOnEvent(-1, "DesktopMenuItem")
Until @error
FileClose($NextFileSearch)

;Searching for favorites
$FindFirstFile = FileFindFirstFile($FavoritesDir & "\*.url")
Do
    $NextFileSearch = FileFindNextFile($FindFirstFile)
    If @error Then ExitLoop
    GUICtrlCreateMenuitem($NextFileSearch, $FavoritesMenu)
    GUICtrlSetOnEvent(-1, "FavoritesMenuItem")
Until @error
FileClose($NextFileSearch)
While 1
    Sleep(100)
WEnd

Func Quit()
    Exit
EndFunc

Func DesktopMenuItem()
    $FileName = GUICtrlRead(@GUI_CtrlId, 1)
    ShellExecute($DesktopDir & "\" & $FileName)
EndFunc

Func FavoritesMenuItem()
    $FileName = GUICtrlRead(@GUI_CtrlId, 1)
    ShellExecute($FavoritesDir & "\" & $FileName)
EndFunc

Yea, but I'm not using GUI. I'm using menus from the taskbar icon.