Sign in to follow this  
Followers 0
SadBunny

Countdown snooze/showering/cooking alarm clock

35 posts in this topic

#1 ·  Posted (edited)

Hi people! My purely mechanic cooking countdown clock (one of those cooking clocks where you turn the upper side of the egg and set it for X minutes, and then it turns around slowly to 0 and it rings, you know what I mean) broke down due to the fact that I mostly kept it in my bathroom and I forgot that nasty little thing called rust. :shocked:

This was an unprecedented emotional blow to my personal life, of which I had to recover for weeks. You see, I used it when cooking, showering and snoozing in bed in the morning, so obviously I stayed in bed, took too long showers and was late at work every day. On top of that, all my cooking was ruined so I have been suffering from severe intestine injuries and malnutrition. Now you see how life-threateningly important a countdown snooze/cooking/showering alarm clock is to me.

Since I did not feel like spending 3 euro's on a new mechanical countdown clock because I'm ridiculously cheap, I created a countdown clock myself instead. Very simple but I think it looks nice and what's more, it works like a charm. I know there are many of these freely available on the internet (so if you want you can consider this a good example of reinventing the wheel) but none that I tried fitted my needs perfectly so I made it myself... If you want to take a look at it go ahead.

It features nothing more than:

- setting a countdown timer, or an alarm clock. Also features two shurtcuts to 8 and 16 minutes snooze.

- starting/stopping it

- selecting a sound file to play when countdown is done

- testing the sound file to see if the alarm will work

- selection to turn on a clicking sound for the seconds passing during countdown

By default I used two default files (at least i think they are default, otherwise plz change them) in Windows XP's c:\windows\media\ folder.

/edit: uploaded completely rewritten code. Now much cooler :(

; Countdown/Snooze/Alarm Clock
;
; Written by SadBunny.
;
; penizverdweniz at hot mail dot Charlie Oscar Mike
;
; EULA:
; 
; Use or distribute this code any way you want to, except for commercially! Credit me if you do anything with it.

#include <GUIConstants.au3>
#include <Misc.au3>
#include <Date.au3>
#include <Sound.au3>

HotKeySet("{ESC}", "_exiting")

Global Const $INPUT_MODE = 0
Global Const $COUNT_MODE = 1
Global Const $ALARM_MODE = 2

Global $userWantsToQuit = False
Global $escExitsFunction = False

Global $alarmFile = @WindowsDir & "\media\ringin.wav"
Global $secClickerFile = @WindowsDir & "\media\start.wav"

#Region ### START Koda GUI section ### Form=C:\Documents and Settings\PenZ\Mijn documenten\AForm1.kxf
$Form1 = GUICreate("Countdown/Alarm Clock", 239, 395)
GUISetBkColor(0x000000)
$alarmFileInput = GUICtrlCreateInput($alarmFile, 11, 235, 215, 21, $GUI_SS_DEFAULT_INPUT + $ES_READONLY)
GUICtrlSetBkColor($alarmFileInput, 0x000000)
GUICtrlSetColor($alarmFileInput, 0xCCCCCC)
$alarmFileChooseButton = GUICtrlCreateButton("Choose alarmfile", 11, 260, 135, 25, 0)
$alarmFileTestButton = GUICtrlCreateButton("Test Alarm", 146, 260, 81, 25, 0)

Dim $userSetLabel[3]
Dim $udUpDown[3][2]
Dim $userSetLabelLimit[3]

$userSetLabelLimit[0] = 23
$userSetLabelLimit[1] = 59
$userSetLabelLimit[2] = 59

For $d1 = 0 To 2
    $userSetLabel[$d1] = GUICtrlCreateLabel(StringFormat("%.2d", Int($d1 / 2) * 30), 10 + 80 * $d1, 161, 40, 26)
    GUICtrlSetFont($userSetLabel[$d1], 18, 800, 0, "Terminal")
    GUICtrlSetColor($userSetLabel[$d1], 0x00FF00)
    GUICtrlSetBkColor($userSetLabel[$d1], 0x000000)
    For $d2 = 0 To 1
        $udUpDown[$d1][$d2] = GUICtrlCreateLabel(StringMid(" + -", $d2 * 2 + 1, 2), 52 + 80 * $d1, 156 + 16 * $d2, 24, 15, 0)
        GUICtrlSetFont($udUpDown[$d1][$d2], 9, 500, -1, "Courier")
        GUICtrlSetBkColor($udUpDown[$d1][$d2], 0x333333)
        GUICtrlSetColor($udUpDown[$d1][$d2], 0xFFFFFF)
    Next
Next

$secondClicks = GUICtrlCreateCheckbox("Audible second counting clicks?", 13, 348, 212, 17)
GUICtrlSetColor(-1, 0xCCCCCC)
GUICtrlSetBkColor(-1, 0x000000)
GUICtrlSetState(-1, $GUI_CHECKED)
$loopAlarmCheckbox = GUICtrlCreateCheckbox("Loop alarm?", 13, 370, 212, 17)
GUICtrlSetColor(-1, 0xCCCCCC)
GUICtrlSetBkColor(-1, 0x000000)
GUICtrlSetState(-1, $GUI_CHECKED)

$Label4 = GUICtrlCreateLabel("Hour    Min     Sec", 11, 190, 200, 28)
GUICtrlSetFont(-1, 15, 800, 0, "Comic Sans MS")
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, 0x000000)
$currentTimeLbl = GUICtrlCreateLabel("Current time: " & _DateTimeFormat(_NowCalc(), 5), 13, 7, 201, 17)
GUICtrlSetFont(-1, 12, 1000, 0, "Verdana")
GUICtrlSetColor(-1, 0xFFFF00)
GUICtrlSetBkColor(-1, 0x000000)

$startStopLbl = GUICtrlCreateLabel("", 0, 35, 239, 45, $SS_CENTER)
GUICtrlSetFont(-1, 13, 1000, 0, "Verdana")
GUICtrlSetColor(-1, 0x00FF00)
GUICtrlSetBkColor(-1, 0x009500)
$snooze8min = GUICtrlCreateLabel("snooze" & @CRLF & "8 minutes", 0, 80, 118, 45, $SS_CENTER)
$snooze16min = GUICtrlCreateLabel("snooze" & @CRLF & "16 minutes", 123, 80, 118, 45, $SS_CENTER)
GUICtrlSetFont($snooze8min, 13, 1000, 0, "Verdana")
GUICtrlSetColor($snooze8min, 0x55CC55)
GUICtrlSetBkColor($snooze8min, 0x115511)
GUICtrlSetFont($snooze16min, 13, 1000, 0, "Verdana")
GUICtrlSetColor($snooze16min, 0x55CC55)
GUICtrlSetBkColor($snooze16min, 0x115511)
GUISetState(@SW_SHOW)

$treatAsCountdownRad = GUICtrlCreateRadio("Countdown (count down specified time)", 12, 300, 250, 20)
GUICtrlSetColor($treatAsCountdownRad, 0xCCCCCC)
GUICtrlSetBkColor($treatAsCountdownRad, 0x000000)
$treatAsClockRad = GUICtrlCreateRadio("Alarm Clock (sound alarm on specified time)", 12, 320, 250, 20)
GUICtrlSetState($treatAsClockRad, $GUI_CHECKED)
GUICtrlSetColor($treatAsClockRad, 0xCCCCCC)
GUICtrlSetBkColor($treatAsClockRad, 0x000000)
#EndRegion ### END Koda GUI section ###

_guiChangeMode(0)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            _exiting()
        Case $udUpDown[0][0]
            changeTimeLabel($userSetLabel[0], 0, 1) ; plus
        Case $udUpDown[0][1]
            changeTimeLabel($userSetLabel[0], 0, -1) ; minus
        Case $udUpDown[1][0]
            changeTimeLabel($userSetLabel[1], 1, 1)
        Case $udUpDown[1][1]
            changeTimeLabel($userSetLabel[1], 1, -1)
        Case $udUpDown[2][0]
            changeTimeLabel($userSetLabel[2], 2, 1)
        Case $udUpDown[2][1]
            changeTimeLabel($userSetLabel[2], 2, -1)
        Case $startStopLbl
            _doCountdown()
        Case $alarmFileChooseButton
            $oldAlarmFile = $alarmFile
            $alarmFile = FileOpenDialog("Welk bestand wil je afspelen?", "D:\", "WAV Files (*.wav)|MP3 Files (*.mp3)|All Files (*.*)")
            If $alarmFile = "" Then
                $alarmFile = $oldAlarmFile
            EndIf
            GUICtrlSetData($alarmFileInput, $alarmFile)
        Case $alarmFileTestButton
            _soundAlarm()
            _guiChangeMode(0)
        Case $treatAsClockRad
            _guiChangeMode(0)
        Case $treatAsCountdownRad
            _guiChangeMode(0)
        Case $snooze8min
            GUICtrlSetData($userSetLabel[0], "00")
            GUICtrlSetData($userSetLabel[1], "08")
            GUICtrlSetData($userSetLabel[2], "00")
            GUICtrlSetState($treatAsCountdownRad, $GUI_CHECKED)
            _doCountdown()
        Case $snooze16min
            GUICtrlSetData($userSetLabel[0], "00")
            GUICtrlSetData($userSetLabel[1], "16")
            GUICtrlSetData($userSetLabel[2], "00")
            GUICtrlSetState($treatAsCountdownRad, $GUI_CHECKED)
            _doCountdown()
    EndSwitch
    Sleep(10)
    _updateCurrentTimeLabel()
WEnd

Func _doCountdown()
    _guiChangeMode($COUNT_MODE)
    Local $clickSeconds
    If GUICtrlRead($treatAsClockRad) = $GUI_CHECKED Then ; <-- clock mode
        If GUICtrlRead($secondClicks) = $GUI_CHECKED Then
            $clickSeconds = True
        Else
            $clickSeconds = False
        EndIf
        Do
            Sleep(10)
            _updateCurrentTimeLabel(True)
            Local $str = GUICtrlRead($userSetLabel[0]) & ":" & GUICtrlRead($userSetLabel[1]) & ":" & GUICtrlRead($userSetLabel[2])
            If $str > _DateTimeFormat(_NowCalc(), 5) Then
                _soundAlarm()
                $userWantsToQuit = True
            EndIf
            $msg = GUIGetMsg()
        Until $msg = $startStopLbl Or $msg = $GUI_EVENT_CLOSE Or $userWantsToQuit
        $userWantsToQuit = False
    Else ; <-- countdown mode
        $timerinit = TimerInit()
        $timerCountSec = 0
        $ok = _countOneSecond()
        Do
            _updateCurrentTimeLabel()
            $timerDiff = TimerDiff($timerinit) - $timerCountSec

            If $timerDiff > 1000 Then
                $timerCountSec += 1000
                $ok = _countOneSecond()
            EndIf
            Sleep(10)
            $msg = GUIGetMsg()
        Until $msg = $startStopLbl Or $msg = $GUI_EVENT_CLOSE Or $msg = $snooze8min Or $msg = $snooze16min Or $userWantsToQuit Or Not $ok
        Switch $msg
            Case $snooze8min
                GUICtrlSetData($userSetLabel[0], "00")
                GUICtrlSetData($userSetLabel[1], "08")
                GUICtrlSetData($userSetLabel[2], "00")
                GUICtrlSetState($treatAsCountdownRad, $GUI_CHECKED)
                _doCountdown()
            Case $snooze16min
                GUICtrlSetData($userSetLabel[0], "00")
                GUICtrlSetData($userSetLabel[1], "16")
                GUICtrlSetData($userSetLabel[2], "00")
                GUICtrlSetState($treatAsCountdownRad, $GUI_CHECKED)
                _doCountdown()
        EndSwitch
        $userWantsToQuit = False
    EndIf
    _guiChangeMode($INPUT_MODE)
EndFunc   ;==>_doCountdown

Func _countOneSecond()
    Local $hour = GUICtrlRead($userSetLabel[0])
    Local $min = GUICtrlRead($userSetLabel[1])
    Local $sec = GUICtrlRead($userSetLabel[2])
    Local $clickSeconds
    If GUICtrlRead($secondClicks) = $GUI_CHECKED Then
        $clickSeconds = True
    Else
        $clickSeconds = False
    EndIf

    
    If $hour = 0 And $min = 0 And $sec = 0 Then
        _soundAlarm()
        Return False
    EndIf
    
    changeTimeLabel($userSetLabel[2], 2, -1, True)
    
    If $clickSeconds Then SoundPlay($secClickerFile, 0)
    
    Return True
EndFunc   ;==>_countOneSecond

Func _soundAlarm()
    _guiChangeMode(2)
    $soundHandle = _SoundOpen($alarmFile, "alarmfile")
    _SoundPlay($soundHandle, 0)
    Do
        If _SoundStatus($soundHandle) <> "playing" And GUICtrlRead($loopAlarmCheckbox) = $GUI_UNCHECKED Then
            $userWantsToQuit = True
        ElseIf _SoundStatus($soundHandle) <> "playing" And GUICtrlRead($loopAlarmCheckbox) = $GUI_CHECKED Then
            _SoundPlay($soundHandle, 0)
        EndIf
        Sleep(10)
        
        $msg = GUIGetMsg()
        _updateCurrentTimeLabel()
    Until $userWantsToQuit Or $msg = $GUI_EVENT_CLOSE Or $msg = $snooze8min Or $msg = $snooze16min Or $msg = $startStopLbl
    _SoundStop($soundHandle)
    _SoundClose($soundHandle)
    Switch $msg
        Case $snooze8min
            GUICtrlSetData($userSetLabel[0], "00")
            GUICtrlSetData($userSetLabel[1], "08")
            GUICtrlSetData($userSetLabel[2], "00")
            GUICtrlSetState($treatAsCountdownRad, $GUI_CHECKED)
            _doCountdown()
        Case $snooze16min
            GUICtrlSetData($userSetLabel[0], "00")
            GUICtrlSetData($userSetLabel[1], "16")
            GUICtrlSetData($userSetLabel[2], "00")
            GUICtrlSetState($treatAsCountdownRad, $GUI_CHECKED)
            _doCountdown()
    EndSwitch

    $userWantsToQuit = False ; <-- reset esc stopper
EndFunc   ;==>_soundAlarm

Func _guiChangeMode($mode) ; <-- 0 = input mode, 1 = countdown mode, 2 = alarm mode
    Switch $mode
        Case 0
            $escExitsFunction = False
            If GUICtrlRead($treatAsClockRad) = $GUI_CHECKED Then
                GUICtrlSetData($startStopLbl, "Click here to activate alarm clock!")
                GUICtrlSetColor($currentTimeLbl, 0xFFFF00)
            Else
                GUICtrlSetData($startStopLbl, "Click here to start countdown!")
                GUICtrlSetColor($currentTimeLbl, 0xFFFF00)
            EndIf
            GUICtrlSetColor($startStopLbl, 0x00FF00)
            GUICtrlSetBkColor($startStopLbl, 0x009500)

            GUICtrlSetData($snooze8min,"snooze" & @CRLF & "8 minutes")
            GUICtrlSetData($snooze16min,"snooze" & @CRLF & "16 minutes")

            GUICtrlSetState($alarmFileChooseButton, $GUI_SHOW)
            GUICtrlSetState($alarmFileTestButton, $GUI_SHOW)
            GUICtrlSetState($treatAsClockRad, $GUI_SHOW)
            GUICtrlSetState($treatAsCountdownRad, $GUI_SHOW)

            For $d1 = 0 To 2
                GUICtrlSetColor($userSetLabel[$d1], 0x00FF00)
                For $d2 = 0 To 1
                    GUICtrlSetState($udUpDown[$d1][$d2], $GUI_SHOW)
                Next
            Next
        Case 1 ; <-- counting mode
            If GUICtrlRead($treatAsClockRad) = $GUI_CHECKED Then
                GUICtrlSetData($startStopLbl, "Click here to DEactivate alarm clock!")
                GUICtrlSetColor($currentTimeLbl, 0x00FFFF)
                GUICtrlSetData($snooze8min,"")
                GUICtrlSetData($snooze16min,"")
            Else
                GUICtrlSetData($startStopLbl, "Click here to stop countdown!")
                GUICtrlSetColor($currentTimeLbl, 0x888888)
                GUICtrlSetData($snooze8min,"snooze" & @CRLF & "8 minutes")
                GUICtrlSetData($snooze16min,"snooze" & @CRLF & "16 minutes")
            EndIf
            $escExitsFunction = True
            GUICtrlSetColor($startStopLbl, 0xFF0000)
            GUICtrlSetBkColor($startStopLbl, 0x950000)

            GUICtrlSetColor($snooze8min, 0x55CC55)
            GUICtrlSetBkColor($snooze8min, 0x115511)
            GUICtrlSetColor($snooze16min, 0x55CC55)
            GUICtrlSetBkColor($snooze16min, 0x115511)

            GUICtrlSetState($alarmFileChooseButton, $GUI_HIDE)
            GUICtrlSetState($alarmFileTestButton, $GUI_HIDE)
            GUICtrlSetState($treatAsClockRad, $GUI_HIDE)
            GUICtrlSetState($treatAsCountdownRad, $GUI_HIDE)
            
            For $d1 = 0 To 2
                GUICtrlSetColor($userSetLabel[$d1], 0xFF0000)
                For $d2 = 0 To 1
                    GUICtrlSetState($udUpDown[$d1][$d2], $GUI_HIDE)
                Next
            Next
        Case 2 ; <-- alarm mode
            $escExitsFunction = True
            GUICtrlSetData($startStopLbl, "Click here or press ESC to stop alarm!")
            GUICtrlSetColor($startStopLbl, 0xFF0000)
            GUICtrlSetBkColor($startStopLbl, 0x950000)
            GUICtrlSetColor($currentTimeLbl, 0x666666)

            GUICtrlSetData($snooze8min,"snooze" & @CRLF & "8 minutes")
            GUICtrlSetData($snooze16min,"snooze" & @CRLF & "16 minutes")

            GUICtrlSetState($alarmFileChooseButton, $GUI_HIDE)
            GUICtrlSetState($alarmFileTestButton, $GUI_HIDE)
            GUICtrlSetState($treatAsClockRad, $GUI_HIDE)
            GUICtrlSetState($treatAsCountdownRad, $GUI_HIDE)

            For $d1 = 0 To 2
                GUICtrlSetColor($userSetLabel[$d1], 0xFF0000)
                For $d2 = 0 To 1
                    GUICtrlSetState($udUpDown[$d1][$d2], $GUI_HIDE)
                Next
            Next
        Case Else
            MsgBox(16, "error", "_guiChangeMode got wrong parameter: 0 = input mode, 1 = action mode, 2 = alarm mode. Now exiting.")
            Exit
    EndSwitch
EndFunc   ;==>_guiChangeMode

Func _updateCurrentTimeLabel($doClickIfChanged = False)
    $return = False
    If StringRight(GUICtrlRead($currentTimeLbl), 8) <> _DateTimeFormat(_NowCalc(), 5) Then
        GUICtrlSetData($currentTimeLbl, "Current time: " & _DateTimeFormat(_NowCalc(), 5))
        If $doClickIfChanged Then SoundPlay($secClickerFile, 0)
        $return = True
    EndIf
    Return $return
EndFunc   ;==>_updateCurrentTimeLabel

Func changeTimeLabel($labelHandle, $labelNumber, $mode, $auto = False) ; <-- $mode = 1 telt 1 op, $mode = -1 trekt 1 af van label, $auto voor automatisch
    Local $labelVal = GUICtrlRead($labelHandle)
    Local $justStarted = True
    Local $continue = True
    
    Do
        $labelVal += $mode * 1
        If $labelVal > $userSetLabelLimit[$labelNumber] Then
            $labelVal = 0
            If $labelNumber > 0 Then changeTimeLabel($userSetLabel[$labelNumber - 1], $labelNumber - 1, 1, True)
        EndIf
        If $labelVal < 0 Then
            $labelVal = $userSetLabelLimit[$labelNumber]
            If $labelNumber > 0 Then changeTimeLabel($userSetLabel[$labelNumber - 1], $labelNumber - 1, -1, True)
        EndIf
        GUICtrlSetData($labelHandle, StringFormat("%.2d", $labelVal))
        If $justStarted And Not $auto Then
            For $d = 1 To 10
                Sleep(25)
            Next
            $justStarted = False
        Else
            If Not $auto Then Sleep(75)
        EndIf
    Until Not _IsPressed(0x01) Or $continue = False Or $auto = True
EndFunc   ;==>changeTimeLabel

Func _exiting()
    If $escExitsFunction Then
        $userWantsToQuit = True
        While _IsPressed("1B")
            Sleep(10)
        WEnd
    Else
        Exit
    EndIf
EndFunc   ;==>_exiting
Edited by SadBunny

Roses are FF0000, violets are 0000FF... All my base are belong to you.

Share this post


Link to post
Share on other sites

#3 ·  Posted (edited)

Funny..I would like to see the GUI look a bit better.. :shocked::sorcerer:

Also, a 'press any key' to cancel the alarm, would be cool. :(

Well thanks for checking it out so quickly! :P Also thanks for the suggestions.

Actually I started out trying to make it 'any key' but then I couldn't find the 'any key' I realized that I intend to actually use this for morning time snoozing. And as we all very well know, a too-easy-to-hit-snooze alarm clock is deadly for your job position... Also, sometimes I will be wanting to stop the alarm when working with another active window, so one hotkey suits my needs better...

Also I might be making a nice background picture and fiddle with fonts and colors some more, but that is for later. For now, the app is very easy to read and to understand and to use, and it saved me a trip to the store (the Blokker, you might know it).

Thanks again! ;)

/edit: typo

Edited by SadBunny

Roses are FF0000, violets are 0000FF... All my base are belong to you.

Share this post


Link to post
Share on other sites

#4 ·  Posted (edited)

.../showering/...

errr....you have a computer in your bathroom?...we all know Manadar does thanks to him telling us that he was scripting and posting and taking a sh*t @ the same time....thanks again for that :shocked:, but I thought he would be the only one... Edited by Nikolai

Share this post


Link to post
Share on other sites

errr....you have a computer in your bathroom?...we all know Manadar does thanks to him telling us that he was scripting and posting and taking a sh*t @ the same time....thanks again for that :shocked:, but I thought he would be the only one...

Well normally I don't have a computer in the bathroom, but I must confess I do take my laptop with me sometimes. I do however have speakers in the bathroom, connected to my system in the living room.

But yes, we Dutch people are a strange kind I guess..... :(


Roses are FF0000, violets are 0000FF... All my base are belong to you.

Share this post


Link to post
Share on other sites

FAntastic! =P

I use for my sourvival cooking


Console Browse: Navigate on the WEB in a textual consoleMultiPing!: Show computer on the lan and/or show the local/remote task, ALL animated!KillaWin: Event executingCryptPage: Crypt your webpage and show only with key

Share this post


Link to post
Share on other sites

Well normally I don't have a computer in the bathroom, but I must confess I do take my laptop with me sometimes. I do however have speakers in the bathroom, connected to my system in the living room.

But yes, we Dutch people are a strange kind I guess..... :shocked:

Cool! :( I have a few computer speakers in my room, and I sometimes take those with me when taking a shower.. It's nice to have music from your laptop when you are taking a shower.. :P

Share this post


Link to post
Share on other sites

Cool! :shocked: I have a few computer speakers in my room, and I sometimes take those with me when taking a shower.. It's nice to have music from your laptop when you are taking a shower.. :(

Hey... This sounds exactly like me! Are you sure we aren't the same person?? :P

Roses are FF0000, violets are 0000FF... All my base are belong to you.

Share this post


Link to post
Share on other sites

Well, you're both Dutch ;-)

Me too btw, but I don't have speakers in my bathroom :|

I'm a weird now? :shocked:

Share this post


Link to post
Share on other sites

Well, you're both Dutch ;-)

Me too btw, but I don't have speakers in my bathroom :|

I'm a weird now? :shocked:

Yes. You are weird. Now go live in another country where no-one has speakers in the bathroom. :(

I think I should introduce this EULA:

; EULA: Anyone may freely use and/or distribute this code or any compiled form of it, as long as

; I am given credit and there are no commercial interests involved.

;

; Exclusion: anyone with no speakers in the bathroom is totally uncool and a communist, and is not

; allowed to use my script. (Americans should like this statement. :P)


Roses are FF0000, violets are 0000FF... All my base are belong to you.

Share this post


Link to post
Share on other sites

SadBunny, I have no speakers in the bathroom, but I started to take baths in the bedroom (where the speakers are). Will it count?

Share this post


Link to post
Share on other sites

SadBunny, I have no speakers in the bathroom, but I started to take baths in the bedroom (where the speakers are). Will it count?

Ok, you can use my clock, but only for max. 10 times! :shocked:


Roses are FF0000, violets are 0000FF... All my base are belong to you.

Share this post


Link to post
Share on other sites

Thanks, man!

(Man? Bunny?)

alc

Share this post


Link to post
Share on other sites

#14 ·  Posted (edited)

Thanks, man!

(Man? Bunny?)

alc

I am a man. But I call myself a bunny. Long story. Has to do with elementray school musical performance where I performed as Neptune.

I didn't notice that you aren't Dutch... Ok then then your situation is forgivable (though pitiful), so ok, use it as much as you want to.

; ADDITION TO EULA:

;

; All people who are not Dutch are excused for not having sound speakers in their bathrooms, and can use the software freely even

; without speakers in bathrooms. Just as long as they agree to listen to at least one Afroman, Jefferson Airplane and Stephen Lynch album,

; and learn at least twenty Weird All songs from front to end. Surprise tests will be taken.

/ edit: added elementary school musical story.

Edited by SadBunny

Roses are FF0000, violets are 0000FF... All my base are belong to you.

Share this post


Link to post
Share on other sites

You should place the EULA in your source code. :shocked:

Point taken, suggestion used, thanks. Placed EULA in source code. Now it's really cool with the EULA and everything. Now to get drunk and celebrate the weekend! :(

Roses are FF0000, violets are 0000FF... All my base are belong to you.

Share this post


Link to post
Share on other sites

#17 ·  Posted (edited)

@ SadBunny

Thank you for pointing me that you are a man, not a bunny. And specially for the bunny-music performance-Neptune stuff, I've should figure out this.

Following the order of your answer, I understand I can use the script without your beloved music.

I double saved my download before suggesting you the following: in order to acomplish your goals, change your current script to Dutch lang, for home users. For the rest of all (me excluded, of course), write a new version. Strip the controls to select the sound file, attach the songs of those albums, and make the script to randomly play one of them. This way will be easy to learn them.

OK, happy weekend to everybody out there

alc

edit: typos

Edited by alc

Share this post


Link to post
Share on other sites

You mean that everyone in the world doesn't know at least twenty Weird Al songs???? I am shocked and amazed. I know many of his songs. Yoda being one of my favourites. I have even seen him in concert.. Yes, yes, I have.. :( After all. Being Canadian he is almost a national hero. :shocked:

Share this post


Link to post
Share on other sites

You mean that everyone in the world doesn't know at least twenty Weird Al songs???? I am shocked and amazed. I know many of his songs. Yoda being one of my favourites. I have even seen him in concert.. Yes, yes, I have.. :P After all. Being Canadian he is almost a national hero. :shocked:

You would be amazed how many people in Europe have never heard of him. If they even know him, all they know is one song: I'm fat. Possibly even Like A Surgeon. If I could go see him here in Holland, I would like to. I like everything about him. I guess the difficult part about liking his music is that it is quite culture-specific, and that you have to actually listen to his stories to appreciate his songs in full.

My favourites are Yoda, Biggest Ball Of Twine In Minnesota, Trigger Happy and The Truck Driver Song.

Anyway, you are hereby granted lifelong free usage of this clock! :(


Roses are FF0000, violets are 0000FF... All my base are belong to you.

Share this post


Link to post
Share on other sites

Yay! thanks bunnyman. :shocked:

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0