Convert to date/time

[MrCreatoR 74]

Hi all,

I want to build a function to convert string format of date/time to real value, but the problem is, that there two strings of MM (mounth and minutes)...

Here is what i mean:

expandcollapse popup

$FullDateTime = _DateTimeConvertFormat("DD/MM/YYYY, HH:MM:SS")
MsgBox(64, "Date/Time Convert Results", $FullDateTime)

Func _DateTimeConvertFormat($sFormat)
    Local $RetDateTime
    Local $Year_Raw = @YEAR
    Local $Year_Part = StringRight($Year_Raw, 2)
    
    Local $Mounth_Raw = @MON
    Local $Mounth_Part = StringRight($Mounth_Raw, 1)
    If $Mounth_Raw > 9 Then $Mounth_Part = $Mounth_Raw
    
    Local $Day_Raw = @MDAY
    Local $Day_Part = StringRight($Day_Raw, 1)
    If $Day_Raw > 9 Then $Day_Part = $Day_Raw
    
    Local $Hours_Raw = @HOUR
    Local $Hours_Part = StringRight($Hours_Raw, 1)
    If $Hours_Raw > 9 Then $Hours_Part = $Hours_Raw
    
    Local $Minutes_Raw = @MIN
    Local $Minutes_Part = StringRight($Minutes_Raw, 1)
    If $Minutes_Raw > 9 Then $Minutes_Part = $Minutes_Raw
    
    Local $Seconds_Raw = @SEC
    Local $Seconds_Part = StringRight($Seconds_Raw, 1)
    If $Seconds_Raw > 9 Then $Seconds_Part = $Seconds_Raw
    
    
    $RetDateTime = StringReplace($sFormat, "yyyy", $Year_Raw)
    $RetDateTime = StringRegExpReplace($RetDateTime, "(?i)y+", $Year_Part)
    
    $RetDateTime = StringReplace($RetDateTime, "mm", $Mounth_Raw, 1)
    
    $RetDateTime = StringReplace($RetDateTime, "dd", $Day_Raw)
    $RetDateTime = StringReplace($RetDateTime, "d", $Day_Part)
    
    
    $RetDateTime = StringReplace($RetDateTime, "hh", $Hours_Raw)
    $RetDateTime = StringReplace($RetDateTime, "h", $Hours_Part)
    
    $RetDateTime = StringReplace($RetDateTime, "mm", $Minutes_Raw)
    $RetDateTime = StringReplace($RetDateTime, "m", $Minutes_Part)
    
    $RetDateTime = StringReplace($RetDateTime, "ss", $Seconds_Raw)
    $RetDateTime = StringReplace($RetDateTime, "s", $Seconds_Part)
    
    Return $RetDateTime
EndFunc

If we set the string like this:

$FullDateTime = _DateTimeConvertFormat("DD/M/YYYY, HH:MM:SS")

Then we get switched mounth with minutes...

And also, is there maybe an easyer (faster/quicker) way to make such function?

[enaiman 15]

You can do a StringSplit ("DD/MM/YYYY, HH:MM:SS", ",") using "," as separator and work separately with every part.

[MrCreatoR 74]

Thanks, but it's not an option, the string can be like this:

"DD/MM/YYYY_HH:MM:SS"

or like this:

"HH:MM:SS DD/MM/YYYY"

Must converted as it is (without replacing any character except the date/time format.

Here is what i came up with at the end(?):

expandcollapse popup

$Str = 'DD/MM/YYYY, [HH;MM;SS]'

ConsoleWrite(_DateTimeConvertFormat($Str))

Func _DateTimeConvertFormat($sFormat)
    Local $RetDateTime = $sFormat
    
    If StringRegExp($sFormat, '(?i)\[(.*)\]') Then
        $TPos_1 = StringInStr($sFormat, "[")
        $TPos_2 = StringInStr($sFormat, "]")
        
        $TruimVal = 1
        If StringInStr(StringMid($sFormat, $TPos_2 + 1), "]") Then $TruimVal = 0
        
        $TimeStr = StringMid($sFormat, $TPos_1+1, ($TPos_2 - $TPos_1) - $TruimVal)
        $TimeStr = _TimeConvertFormat($TimeStr)
        $DateStr = _DateConvertFormat(StringRegExpReplace($sFormat, '(?i)\[(.*)\]', '', 1))
        If StringRegExp(StringMid($sFormat, $TPos_2), '(?i)D|MM/Y') Then
            $RetDateTime = $TimeStr & $DateStr
        Else
            $RetDateTime = $DateStr & $TimeStr
        EndIf
    Else
        $RetDateTime = _DateConvertFormat($sFormat)
    EndIf
    
    If $RetDateTime = $sFormat Then $RetDateTime = _DateConvertFormat($sFormat)
    Return $RetDateTime
EndFunc

Func _TimeConvertFormat($sFormat)
    Local $RetDateTime = $sFormat
    
    Local $Hours_Raw = @HOUR
    Local $Hours_Part = StringRight($Hours_Raw, 1)
    If $Hours_Raw > 9 Then $Hours_Part = $Hours_Raw
    
    Local $Minutes_Raw = @MIN
    Local $Minutes_Part = StringRight($Minutes_Raw, 1)
    If $Minutes_Raw > 9 Then $Minutes_Part = $Minutes_Raw
    
    Local $Seconds_Raw = @SEC
    Local $Seconds_Part = StringRight($Seconds_Raw, 1)
    If $Seconds_Raw > 9 Then $Seconds_Part = $Seconds_Raw
    
    $RetDateTime = StringReplace($RetDateTime, "hh", $Hours_Raw)
    $RetDateTime = StringReplace($RetDateTime, "h", $Hours_Part)
    
    $RetDateTime = StringReplace($RetDateTime, "mm", $Minutes_Raw)
    $RetDateTime = StringReplace($RetDateTime, "m", $Minutes_Part)
    
    $RetDateTime = StringReplace($RetDateTime, "ss", $Seconds_Raw)
    $RetDateTime = StringReplace($RetDateTime, "s", $Seconds_Part)
    
    Return $RetDateTime
EndFunc

Func _DateConvertFormat($sFormat)
    Local $RetDateTime = $sFormat
    
    StringReplace($RetDateTime, "y", "")
    Local $Year = StringRight(@YEAR, @extended)
    
    Local $Mounth_Raw = @MON
    Local $Mounth_Part = StringRight($Mounth_Raw, 1)
    If $Mounth_Raw > 9 Then $Mounth_Part = $Mounth_Raw
    
    Local $Day_Raw = @MDAY
    Local $Day_Part = StringRight($Day_Raw, 1)
    If $Day_Raw > 9 Then $Day_Part = $Day_Raw
    
    $RetDateTime = StringReplace($RetDateTime, "y", $Year, 1)
    $RetDateTime = StringReplace($RetDateTime, "y", "")
    
    $RetDateTime = StringReplace($RetDateTime, "mm", $Mounth_Raw)
    $RetDateTime = StringReplace($RetDateTime, "m", $Mounth_Part)
    
    $RetDateTime = StringReplace($RetDateTime, "dd", $Day_Raw)
    $RetDateTime = StringReplace($RetDateTime, "d", $Day_Part)
    Return $RetDateTime
EndFunc

[MrCreatoR 74]

Ok, here is the final version, works greate, thanks to amel27:

expandcollapse popup

$FullDateTime = _DateTimeConvertFormat('MM/DD/YYYY, [HH:MM:SS]')
MsgBox(64, "Date/Time Convert Results", $FullDateTime)

Func _DateTimeConvertFormat($sFormat)
    Local $Stamp = '<_>'
    While StringInStr($sFormat, $Stamp)
        $Stamp = '<' & Random(10000000,99999999,1) & '>'
    WEnd
    
    StringReplace($sFormat, "y", "")
    Local $Year = StringRight(@YEAR, @extended)
    Local $Mounth = @MON
    Local $Day = @MDAY
    Local $Hours = @HOUR
    Local $Minutes = @MIN
    Local $Seconds = @SEC

    $sFormat = StringRegExpReplace($sFormat, "(?i)(?:(d+|y+)(\W*)(mm)|(mm)(\W*)(d+|y+))", '\1\2' & $Stamp & '\5\6')
    If @extended Then $sFormat = StringReplace($sFormat, $Stamp, $Mounth)
    $sFormat = StringRegExpReplace($sFormat, "(?i)(?:(d+|y+)(\W*)(m)|(m)(\W*)(d+|y+))", '\1\2' & $Stamp & '\5\6')
    If @extended Then $sFormat = StringReplace($sFormat, $Stamp, $Mounth+0)
    
    $sFormat = StringRegExpReplace($sFormat, '(?i)y+', $Year)
    
    $sFormat = StringReplace($sFormat, "mm",$Minutes)
    $sFormat = StringReplace($sFormat, "m", $Minutes+0)
    
    $sFormat = StringReplace($sFormat, "dd",$Day)
    $sFormat = StringReplace($sFormat, "d", $Day+0)
    
    $sFormat = StringReplace($sFormat, "hh",$Hours)
    $sFormat = StringReplace($sFormat, "h", $Hours+0)
    
    $sFormat = StringReplace($sFormat, "ss",$Seconds)
    $sFormat = StringReplace($sFormat, "s", $Seconds+0)
    
    Return $sFormat
EndFunc

Edit: I don't know why, but in autoit tags the smiles are shown as smiles - so i edited it to standard code tags.

Edited August 16, 2007 by MsCreatoR