Resize GUI width only

[daveed]

How do you make the form so that only the width can be resized like in Koda

Thanks in advance

[MrCreatoR]

Hi,

Maybe something like this:

#include <GUIConstants.au3>
Global Const $WM_GETMINMAXINFO = 0x24

Global $Width = 300
Global $Height = 300

GUICreate("Resize Limit GUI", $Width, $Height, -1, -1, BitOR($GUI_SS_DEFAULT_GUI, $WS_SIZEBOX))
GUIRegisterMsg($WM_GETMINMAXINFO, "MY_WM_GETMINMAXINFO")

GUISetState(@SW_SHOW)


While 1
    $msg = GUIGetMsg()
    If $msg = $GUI_EVENT_CLOSE Then ExitLoop
Wend
    
Func MY_WM_GETMINMAXINFO($hWnd, $Msg, $wParam, $lParam)
    Local $MINMAXINFO = DllStructCreate("int;int;int;int;int;int;int;int;int;int", $lParam)
    ;DllStructSetData($MINMAXINFO, 7, $Width) ;Minimum X
    DllStructSetData($MINMAXINFO, 8, $Height+27) ;Minimum Y
    ;DllStructSetData($MINMAXINFO, 9, $Width+100) ;Maximum X
    DllStructSetData($MINMAXINFO, 10, $Height+22) ;Maximum Y
    Return 0
EndFunc

The idea is from here (by Zedna).

Edited September 7, 2007 by MsCreatoR

[daveed]

Very good,

And it dose not flicker

Thanks again