Trying to move all images to a single directory

[Steve1040 0]

How can I modify the following code to move all image file to a specific folder.

The files are all currently in sub-folders within $path.

I want to goto each folder and move any image files (about 100 folders 1K images total

) to $desination (overwrite is ok)

$path="C:\all\"
$files="*.txt"
$desination="C:\new\directory\"

FileMover($path,$files,$desination)

Func FileMover($path,$files,$dest)
    $err=1
    $move=FileFindFirstFile ($path & $files) 
    While $err=1
 $err=FileMove ($path & $move,$dest & $move)
    $move=FileFindNextFile () 
Wend
EndFunc

Edited September 20, 2007 by Steve1040

[PsaltyDS 29]

FileFindFirstFile/FileFindNextFile only search the current directory, and only find files, not the subdirectories that need to be searched recursively. So use _FileListToArray() instead, and make the function recursive:

#include <file.au3>

$path = "C:\all" 
$files = ".txt" 
$desination = "C:\new\directory" 

FileMover($path, $files, $desination)

Func FileMover($sSrc, $sMask, $sDest)
    If StringRight($sSrc, 1) <> "\"  Then $sSrc &= "\" 
    If StringRight($sDest, 1) <> "\"  Then $sDest &= "\" 
    Local $avList = _FileListToArray($sSrc) ; list all files and dirs
    For $n = 1 To $avList[0]
        ; Test for directories
        If StringInStr(FileGetAttrib($sSrc & $avList[$n]), "D") Then
            ; Search subdirectory
            FileMover($sSrc & $avList[$n], $sMask, $sDest)
        Else
            ; Test file name for search string
            If StringInStr($avList[$n], $sMask) Then FileMove($sSrc & $avList[$n], $sDest & $avList[$n])
        EndIf
    Next
EndFunc   ;==>FileMover

[MrCreatoR 73]

#include <File.au3>

$sPath = "C:\all"
$dPath = "C:\new\directory"
$Mask = "*.txt"

_FileMoveEx($sPath, $dPath, $Mask, 9)
MsgBox(64, "Results", @extended & " Files was moved")

Func _FileMoveEx($sPath, $dPath, $sMask='*', $Flag=0)
    Local $Extended=0
    
    $Search = FileFindFirstFile($sPath & "\" & $sMask)
    While $Search <> -1
        $FileToCopy = FileFindNextFile($Search)
        If @error = 1 Then ExitLoop
        $Extended += FileMove($sPath & "\" & $FileToCopy, $dPath & "\", $Flag)
    WEnd
    FileClose($Search)
    
    Local $DirsArr = _FileListToArray($sPath, '*', 2)
    
    For $i = 1 To UBound($DirsArr)-1
        _FileMoveEx($sPath & "\" & $DirsArr[$i], $dPath, $sMask, $Flag)
        $Extended += @extended
    Next
    Return SetExtended($Extended)
EndFunc