how do i update a text field when a radio button is clicked?

[dwaynek]

i have a gui with a bunch of radio buttons (the text of which is taken from the 1st column of a 2x2 array) and a text input field as shown below. when i click on a radio button, i want the text field to be updated with 2nd column value from the array. how do i do that?

#include <GUIConstants.au3>
#include <Array.au3>
Opt("GUIOnEventMode", 1) ; Change to OnEvent mode
Opt("WinTitleMatchMode", 2) ;1=start, 2=subStr, 3=exact, 4=advanced

;GUICtrlCreateTabItem("avArray")
Dim $avArray[2][2]
$avArray[0][0] = "Allied Waste Services"
$avArray[0][1]= "123.23"
$avArray[1][0] = "Amazon Corp"
$avArray[1][1]= "87.23"

$mainwindow = GUICreate("Outlook Entry", 500, 670); will create a dialog box that when displayed is centered

Dim $radio[ (ubound($avArray) + 1) ]
while $i < UBound($avArray)
    $i=$i+1
    $radio[$i] = GUICtrlCreateRadio ($avArray[$i-1][0], 10, $top)
    $top=$top+20
WEnd

$input = GUICtrlCreateInput ("", 10, $top)
$okbutton = GUICtrlCreateButton("OK", 225, $top, 60)
GUICtrlSetOnEvent($okbutton, "OKButton")
GUICtrlSetOnEvent($radio[2], "radio2")
GUISetOnEvent($GUI_EVENT_CLOSE, "CLOSEClicked")

GUISetState(@SW_SHOW)

; Just idle around
While 1
    Sleep(10)
Wend

[MrCreatoR]

Hi,

Maybe like this:

expandcollapse popup

#include <GUIConstants.au3>
#include <Array.au3>
Opt("GUIOnEventMode", 1) ; Change to OnEvent mode
Opt("WinTitleMatchMode", 2)    ;1=start, 2=subStr, 3=exact, 4=advanced

;GUICtrlCreateTabItem("avArray")
Dim $avArray[2][2]
$avArray[0][0] = "Allied Waste Services"
$avArray[0][1]= "123.23"
$avArray[1][0] = "Amazon Corp"
$avArray[1][1]= "87.23"

$mainwindow = GUICreate("Outlook Entry", 500, 670); will create a dialog box that when displayed is centered

Dim $radio[Ubound($avArray) + 1]
Dim $top = 20

For $i = 0 To UBound($avArray)-1
    $radio[$i] = GUICtrlCreateRadio($avArray[$i][0], 10, $top)
    GUICtrlSetOnEvent($radio[$i], "RadioEvent")
    $top += 20
Next

$input = GUICtrlCreateInput("", 10, $top+10)
$okbutton = GUICtrlCreateButton("OK", 225, $top, 60)
;GUICtrlSetOnEvent($okbutton, "OKButton")

GUISetOnEvent($GUI_EVENT_CLOSE, "CLOSEClicked")

GUISetState(@SW_SHOW)

; Just idle around
While 1
    Sleep(10)
Wend

Func CLOSEClicked()
    Exit
EndFunc

Func RadioEvent()
    For $i = 0 To UBound($radio)-1
        If $radio[$i] = @GUI_CtrlId Then
            GUICtrlSetData($input, $avArray[$i][1])
            Return
        EndIf
    Next
EndFunc

P.S

You should never post an half of example, i needed to complete the missing parts

[dwaynek]

you're soooo totally awesome!! and sorry about the half-code.