Content-type from URL

[Synapse]

Hi i made a script the downloads file from a given url. The problem is that i want it to download all kind of files except web pages (html, php, asp..etc).

How can i get the content-type of the url and decide if it`s a webpage or a file (exe, zip, etc) ?

[MrCreatoR]

You need to get header of the page and then parse it, something like this:

expandcollapse popup

Global $HTTPUserAgent = "Mozilla/5.0 (Windows; U; Windows NT 5.1; en-US; rv:1.8.1) Gecko/20061010 Firefox/2.0"

$Host = "www.autoitscript.com"
$Page = "/forum/index.php"

$Ret = _HTTPGetContentType($Host, $Page)
MsgBox(64, $Host, "Content-Type for <" & $Host & $Page & "> is: " & @LF & _
    $Ret & @LF & @LF & "Response time: " & @extended & " milliseconds")

Func _HTTPGetContentType($Host, $Page)
    Local $Response_Time = TimerInit()
    Local $Socket = _HTTPConnect($Host)
    If @error Then Return SetError(1, 0, "")
    
    _HTTPHead($Host, $Page, $Socket)
    
    Local $Recv = "", $CurrentRecv
    While 1
        $CurrentRecv = TCPRecv($Socket, 16)
        If @error <> 0 Then ExitLoop
        If $CurrentRecv <> "" Then $Recv &= $CurrentRecv
    WEnd
    
    $Response_Time = Round(TimerDiff($Response_Time), 1)
    
    _HTTPClose($Socket)
    
    Local $ContentType = StringRegExp($Recv, '(?s)(?i)Content-Type: (.*?)\n', 3)
    If Not IsArray($ContentType) Or $ContentType[0] = "" Then Return "Unknown"
    
    Return SetExtended($Response_Time, $ContentType[0])
EndFunc

Func _HTTPConnect($Host)
    TCPStartup()
    Local $Name_To_IP = TCPNameToIP($Host)
    Local $Socket = TCPConnect($Name_To_IP, 80)
    
    If $Socket = -1 Then
        TCPCloseSocket($Socket)
        Return SetError(1, 0, "")
    EndIf
    
    Return $Socket
EndFunc

Func _HTTPHead($Host, $Page, $Socket)
    Local $Command = "HEAD " & $Page & " HTTP/1.1" & @CRLF
    $Command &= "Host: " & $Host & @CRLF
    $Command &= "User-Agent: " & $HTTPUserAgent & @CRLF
    $Command &= "Connection: close" & @CRLF & @CRLF
    
    Local $BytesSent = TCPSend($Socket, $Command)
    If $BytesSent = 0 Then Return SetError(2, @error, 0)
    Return $BytesSent
EndFunc

Func _HTTPClose($Socket)
    TCPCloseSocket($Socket)
    TCPShutdown()
EndFunc

Edited November 5, 2007 by MsCreatoR

[Synapse]

You need to get header of the page and then parse it, something like this:

expandcollapse popup

Global $HTTPUserAgent = "Mozilla/5.0 (Windows; U; Windows NT 5.1; en-US; rv:1.8.1) Gecko/20061010 Firefox/2.0"

$Host = "www.autoitscript.com"
$Page = "/forum/index.php"

$Ret = _HTTPGetContentType($Host, $Page)
MsgBox(64, $Host, "Content-Type for <" & $Host & $Page & "> is: " & @LF & _
    $Ret & @LF & @LF & "Response time: " & @extended & " milliseconds")

Func _HTTPGetContentType($Host, $Page)
    Local $Response_Time = TimerInit()
    Local $Socket = _HTTPConnect($Host)
    If @error Then Return SetError(1, 0, "")
    
    _HTTPHead($Host, $Page, $Socket)
    
    Local $Recv = "", $CurrentRecv
    While 1
        $CurrentRecv = TCPRecv($Socket, 16)
        If @error <> 0 Then ExitLoop
        If $CurrentRecv <> "" Then $Recv &= $CurrentRecv
    WEnd
    
    $Response_Time = Round(TimerDiff($Response_Time), 1)
    
    _HTTPClose($Socket)
    
    Local $ContentType = StringRegExp($Recv, '(?s)(?i)Content-Type: (.*?)\n', 3)
    If Not IsArray($ContentType) Or $ContentType[0] = "" Then Return "Unknown"
    
    Return SetExtended($Response_Time, $ContentType[0])
EndFunc

Func _HTTPConnect($Host)
    TCPStartup()
    Local $Name_To_IP = TCPNameToIP($Host)
    Local $Socket = TCPConnect($Name_To_IP, 80)
    
    If $Socket = -1 Then
        TCPCloseSocket($Socket)
        Return SetError(1, 0, "")
    EndIf
    
    Return $Socket
EndFunc

Func _HTTPHead($Host, $Page, $Socket)
    Local $Command = "HEAD " & $Page & " HTTP/1.1" & @CRLF
    $Command &= "Host: " & $Host & @CRLF
    $Command &= "User-Agent: " & $HTTPUserAgent & @CRLF
    $Command &= "Connection: close" & @CRLF & @CRLF
    
    Local $BytesSent = TCPSend($Socket, $Command)
    If $BytesSent = 0 Then Return SetError(2, @error, 0)
    Return $BytesSent
EndFunc

Func _HTTPClose($Socket)
    TCPCloseSocket($Socket)
    TCPShutdown()
EndFunc

Thx man it`s just what i was looking 4 10x