how to loop filesavedialog(same file exist)

[icadea]

Hi all,

This is the code below i'm havin currently,

Func PrnscrO()
    
    Global $hBMPO, $fsaveO
    _Clip_Empty ()
    $hBMPO = _ScreenCap_Capture ("", 0, 0, -1, -1, False)
    $fsaveO = FileSaveDialog("Choose a name and location to save.", @WorkingDir, "Jpg (*.jpg)", 18) & ".jpg" 
    If @error Then Return
    
    If FileExists($fsaveO) Then
        MsgBox(4096, $fsaveO, "File Exists, Please rename")
    Else
    EndIf

    _Clip_SetData ($hBMPO)
    _ScreenCap_SaveImage ($fsaveO, $hBMPO)

What i would like to know is ,

1) How could I loop the filesavedialog in case the same filename exist. Right now it only says the same filename exist and returns back to the main function.

What is needed, when the program finds same file name exist, it should prompt message. When ok is clicked a rename filesavedialog is shown/ or the same filesavedialog is shown till the same name does not exist in the directory to be saved. Is this possible?

I've searched the forum and could not find. Pls help or show the way, thanks

[PsaltyDS]

Just put it in a loop that doesn't exit until you get what you want:

Func PrnscrO()
    
    Global $hBMPO, $fsaveO
    _Clip_Empty ()
    $hBMPO = _ScreenCap_Capture ("", 0, 0, -1, -1, False)
    While 1
        $fsaveO = FileSaveDialog("Choose a name and location to save.", @WorkingDir, "Jpg (*.jpg)", 18) & ".jpg" 
        If @error Then Return
        If FileExists($fsaveO) Then
            MsgBox(4096, $fsaveO, "File Exists, Please rename")
        Else
            ExitLoop
        EndIf
    WEnd
    _Clip_SetData ($hBMPO)
    _ScreenCap_SaveImage ($fsaveO, $hBMPO)

P.S. It's not generally good practice to declare global variables insid a function.

[icadea]

Thanks for the help,it works great. I have changed the global variables declaration outside the function. Thanks again for your quick help.

[icadea]

sorry to reopen the thread, just noticed a small issue while troubleshooting.

1) Screen capture and save(given name test)

2) File is saved as test.jpg

but on the next

3) Screen capture and save(click on test.jpg)

4) File exist prompt(Press YES to replace and SAVE)

When this is done the older file test.jpg and the new file test.jpg.jpg exist.

$fsaveO = FileSaveDialog("Choose a name and location to save.", @WorkingDir, "Jpg (*.jpg)", 18) & ".jpg"

Is it possible once the file is renamed the old file is replaced completely instead or creating a clone. Searched the forum on Filedialogsave but none seems to help on file extension

Pls point me to the right direction so i could learn from there. thanks

[MrCreatoR]

You might want to use file name that user type, but the existing file always rename (programly)?

Try this:

Func PrnscrO()
    Global $hBMPO, $fsaveO
    _Clip_Empty ()
    $hBMPO = _ScreenCap_Capture ("", 0, 0, -1, -1, False)
    While 1
        $fsaveO = FileSaveDialog("Choose a name and location to save.", @WorkingDir, "Jpg (*.jpg)", 18)
        If @error Then Return
        
        If StringRight($fsaveO, 4) <> ".jpg" Then $fsaveO &= ".jpg"
        
        If FileExists($fsaveO) Then
            Local $sFile = StringRegExpReplace($fsaveO, "^.*\\", "")
            Local $NewFileName = _GetNewFileName($sFile, @WorkingDir)
            FileMove($fsaveO, @WorkingDir & "\" & $NewFileName)
        EndIf
        ExitLoop
    WEnd
    _Clip_SetData ($hBMPO)
    _ScreenCap_SaveImage ($fsaveO, $hBMPO)
EndFunc

Func _GetNewFileName($sFile, $dDir, $Delim1 = " (", $Delim2 = ")")
    If Not FileExists($dDir & "\" & $sFile) Then Return $sFile
    $dDir = StringRegExpReplace($dDir, "\\ *$", "")
    Local $sName = StringRegExpReplace($sFile, "\.[^.]*$", "")
    Local $sExtn = StringMid($sFile, StringLen($sName) +1)
    Local $i = 1, $dFile = $sFile
    While FileExists($dDir & "\" & $dFile)
        $dFile = $sName & $Delim1 & $i & $Delim2 & $sExtn
        $i += 1
    WEnd
    Return $dFile
EndFunc

So the old file will be always renamed to file(1).jpg, file(2).jpg etc.

[icadea]

thanks so much, this will give me some ideas. thanks again