Wild cards with file paths

[houseonfire]

I need to navigate to an xml file. But i do not know what the full path is.

Is there anyway to do something like

@MyDocumentsDir &"\files\unknown named files\file\unknown named files.xml"

[JustinReno]

No.

Maybe if you use AutoIt to search for a an XML file in @MyDocumentsDir.

Edited November 24, 2007 by JustinReno

[MrCreatoR]

Try this my function to search files:

expandcollapse popup

#include <Array.au3> ;Only for _ArrayDisplay()

$sPath = @MyDocumentsDir

$Results = _FileFind($sPath, "*.xml", 1)
If @error = 3 Then
    MsgBox(48, "Attention", "No files found.")
Else
    _ArrayDisplay($Results)
EndIf

;Flag = 1 search with recurse
;Flag <> 1 search without recurse
;On Failure return @error as following:
;   1 - $sPath is not a dir or it not exists (in this case returned -1 as well).
;   2 - $sPath is empty dir.
;   3 - No files found in $sPath dir.
;
;On Seccess return array with founded files.
Func _FileFind($sPath, $Mask, $Flag=0)
    If Not StringInStr(FileGetAttrib($sPath), "D") Then Return SetError(1, 0, -1)
    
    Local $RetPathArr[1], $FindNextFile, $CurrentPath, $SubDirFindArr, $Ubound = 0
    If StringInStr($Mask, "*") Then $Mask = StringReplace($Mask, "*.", "")
    
    $sPath = StringRegExpReplace($sPath, '\\+ *$', '\')
    
    Local $FindFirstFile = FileFindFirstFile($sPath & "\*.*")
    If @error = 1 Then Return SetError(2, 0, 0)
    If $FindFirstFile = -1 Then Return SetError(3, 0, 0)
    
    While 1
        $FindNextFile = FileFindNextFile($FindFirstFile)
        If @error = 1 Then ExitLoop
        $CurrentPath = $sPath & "\" & $FindNextFile
        If $Flag = 1 And StringInStr(FileGetAttrib($CurrentPath), "D") Then
            $SubDirFindArr = _FileFind($CurrentPath, $Mask, $Flag)
            If IsArray($SubDirFindArr) Then
                For $i = 1 To UBound($SubDirFindArr)-1
                    $Ubound = UBound($RetPathArr)
                    ReDim $RetPathArr[$Ubound+1]
                    $RetPathArr[$Ubound] = $SubDirFindArr[$i]
                Next
            EndIf
        Else
            If $Mask = "*" Or $FindNextFile = $Mask Or StringRegExpReplace($CurrentPath, '^.*\.', '') = $Mask Then
                $Ubound = UBound($RetPathArr)
                ReDim $RetPathArr[$Ubound+1]
                $RetPathArr[$Ubound] = $CurrentPath
            EndIf
        EndIf
    WEnd
    FileClose($FindFirstFile)
    
    If $Ubound = 0 Then Return SetError(3, 0, 0)
    $RetPathArr[0] = $Ubound
    Return $RetPathArr
EndFunc

[houseonfire]

Awesome! Thanks.

Now if the file starts with something, but i do not know the ending of it..

Example:

Name Of something bla bla bla

-------------------------^

Do not know what the bla bla bla is

Edited November 25, 2007 by houseonfire

[MrCreatoR]

Now if the file starts with something, but i do not know the ending of it..

Try this, should work:

$Results = _FileFind($sPath, "Name Of something*.xml", 1)