_ProcessGetPid()

[Nahuel]

It may have been done before, but still.

;________________________________________________________________________________
;Description: Returns the Process ID's (PID) of a given process name.
;Parameters -  $sName: The name (ending with .exe) of a currently running process.
;Return value: An array containing the Process ID's (PID)
;               Element 0 contains number of occurences.
;Author: Nahuel
;__________________________________________________________________________________
Func _ProcessGetPid($sName)
    If Not ProcessExists($sName) Then
        SetError(1)
        Return ""
    EndIf
    Local $aPList=ProcessList($sName)
    If @error Then Return ""
    Local $aMatches[UBound($aPList)]
    $aMatches[0] = $aPList[0][0]
    For $i=1 To $aPList[0][0]
        $aMatches[$i] = $aPList[$i][1]
    Next
    Return $aMatches
EndFunc

Example:

$Pid=_ProcessGetPid("svchost.exe")

For $i=1 To $Pid[0]
    MsgBox(0,"","svchost.exe's PID: " & $Pid[$i])
Next

-edit-

I just noticed that _ProcessGetName() works on a similar way... so why hasn't something like this been included in Process.au3?

Edited December 28, 2007 by Nahuel

[MrCreatoR]

And why ProcessExists() is not good for such task?

And yes, Process.au3 library should be expanded, i have many functions in seperated examples, i can collect them to one UDF library.. fucntions such as _ProcessPathExists(), _ProcessGetPath(), they are very usefull...

[Nahuel]

And why ProcessExists() is not good for such task?

Didn't you ask me this already? Look

expandcollapse popup

Run("notepad.exe")
Run("notepad.exe")
Run("notepad.exe")

Sleep(1000)

;Using ProcessExist()
$Pid=ProcessExists("notepad.exe")
MsgBox(0,"ProcessExist()","Notepad's pid: " & $Pid)

;Using _ProcessGetPid()
$Pid=_ProcessGetPid("notepad.exe")

For $i=1 To $Pid[0]
    MsgBox(0,"_ProcessGetPid()","Notepad's pid: " & $Pid[$i])
Next

;________________________________________________________________________________
;Description: Returns the Process ID's (PID) of a given process name.
;Parameters -  $sName: The name (ending with .exe) of a currently running process.
;Return value: An array containing the Process ID's (PID)
;            Element 0 contains number of occurences.
;Author: Nahuel
;__________________________________________________________________________________
Func _ProcessGetPid($sName)
    If Not ProcessExists($sName) Then
        SetError(1)
        Return ""
    EndIf
    Local $aPList=ProcessList($sName)
    If @error Then Return ""
    Local $aMatches[UBound($aPList)]
    $aMatches[0] = $aPList[0][0]
    For $i=1 To $aPList[0][0]
        $aMatches[$i] = $aPList[$i][1]
    Next
    Return $aMatches
EndFunc

[MrCreatoR]

Oh i see, sorry, now i see that this func return the PID's of all processes with certain name

Please accept my apology, and Happy new Year to you!

[Nahuel]

Haha, appology accepted It's just different because ProcessExist() will return only one pid of a process that may have many occurences. This func will return an array will all of them. It's nothing you couldn't figure out by yourself, but since Process.au3 has _ProcessGetName() ...

I'm very interested in your UDF's, specially _ProcessGetPath(). I'll check it out now!

Happy New Year to you too!!

[MrCreatoR]

Here are _ProcessGetPath() and _ProcessPathExists()...

expandcollapse popup

;===============================================================================
;
; Function Name:    _ProcessGetPath()
; Description:      Get the executable path of certain process.
;
; Parameter(s):     $vProcess - PID or name of a process.
;
; Requirement(s):   AutoIt v3.2.8.1 or higher.
;                   Kernel32.dll (included with Windows)
;                   Psapi.dll (included with most Windows versions)
;
; Return Value(s):  On Success - Returns full path to the executed process.
;                   On Failure - Returns -1 and sets @Error to:
;                                                               1 - Given process not exists.
;                                                               2 - Error to call Kernel32.dll.
;                                                               3 - Error to open Psapi.dll.
;                                                               4 - Unable to locate path of executed process,
;                                                                   (or can be other error related to DllCall).
;
; Author(s):        G.Sandler (a.k.a CreatoR) - CreatoR's Lab (http://creator-lab.ucoz.ru)
;
;===============================================================================
Func _ProcessGetPath($vProcess)
    Local $iPID = ProcessExists($vProcess)
    If Not $iPID Then Return SetError(1, 0, -1)
    
    Local $aProc = DllCall('kernel32.dll', 'hwnd', 'OpenProcess', 'int', BitOR(0x0400, 0x0010), 'int', 0, 'int', $iPID)
    If Not IsArray($aProc) Or Not $aProc[0] Then Return SetError(2, 0, -1)
    
    Local $vStruct = DllStructCreate('int[1024]')
    
    Local $hPsapi_Dll = DllOpen('Psapi.dll')
    If $hPsapi_Dll = -1 Then $hPsapi_Dll = DllOpen(@SystemDir & '\Psapi.dll')
    If $hPsapi_Dll = -1 Then $hPsapi_Dll = DllOpen(@WindowsDir & '\Psapi.dll')
    If $hPsapi_Dll = -1 Then Return SetError(3, 0, '')
    
    DllCall($hPsapi_Dll, 'int', 'EnumProcessModules', _
        'hwnd', $aProc[0], _
        'ptr', DllStructGetPtr($vStruct), _
        'int', DllStructGetSize($vStruct), _
        'int_ptr', 0)
    Local $aRet = DllCall($hPsapi_Dll, 'int', 'GetModuleFileNameEx', _
        'hwnd', $aProc[0], _
        'int', DllStructGetData($vStruct, 1), _
        'str', '', _
        'int', 2048)
    
    DllClose($hPsapi_Dll)
    
    If Not IsArray($aRet) Or StringLen($aRet[3]) = 0 Then Return SetError(4, 0, '')
    Return $aRet[3]
EndFunc

;===============================================================================
;
; Function Name:    _ProcessPathExists()
; Description:      Check if given path is an existing process.
;
; Parameter(s):     $sPath - Path of executable to check.
;
; Requirement(s):   AutoIt v3.2.8.1 or higher.
;                   Kernel32.dll (included with Windows)
;                   Psapi.dll (included with most Windows versions)
;
; Return Value(s):  On Success - Returns PID of executable process, @extended include total number of similar processes runing.
;                   On Failure - Returns False and sets @Error to:
;                                                               1 - Given path not exists.
;                                                               2 - Process with name of the executable not exists.
;                                                               3 - Error to open Psapi.dll.
;                                                               4 - Error to call Kernel32.dll.
;                                                               5 - Unknown/other error related to DllCalls.
;
; Author(s):        G.Sandler (a.k.a CreatoR) - CreatoR's Lab (http://creator-lab.ucoz.ru)
;
;===============================================================================
Func _ProcessPathExists($sPath)
    If Not FileExists($sPath) Then Return SetError(1, 0, False)
    
    Local $sPathName = StringRegExpReplace($sPath, "^.*\\", "")
    Local $aProcList = ProcessList($sPathName)
    
    If Not ProcessExists($sPathName) Then Return SetError(2, 0, False)
    Local $iUbound = UBound($aProcList)-1
    
    Local $hPsapi_Dll = DllOpen('Psapi.dll')
    If $hPsapi_Dll = -1 Then $hPsapi_Dll = DllOpen(@SystemDir & '\Psapi.dll')
    If $hPsapi_Dll = -1 Then $hPsapi_Dll = DllOpen(@WindowsDir & '\Psapi.dll')
    If $hPsapi_Dll = -1 Then Return SetError(3, 0, False)
    
    Local $aProc, $aPath
    Local $vStruct = DllStructCreate('int[1024]')
    
    For $i = 1 To $iUbound
        $aProc = DllCall('kernel32.dll', 'hwnd', 'OpenProcess', 'int', BitOR(0x0400, 0x0010), 'int', 0, 'int', $aProcList[$i][1])
        If Not IsArray($aProc) Or Not $aProc[0] Then Return SetError(4, 0, False)
        
        DllCall($hPsapi_Dll, 'int', 'EnumProcessModules', _
            'hwnd', $aProc[0], _
            'ptr', DllStructGetPtr($vStruct), _
            'int', DllStructGetSize($vStruct), _
            'int_ptr', 0) 
        
        $aPath = DllCall($hPsapi_Dll, 'int', 'GetModuleFileNameEx', _
            'hwnd', $aProc[0], _
            'int', DllStructGetData($vStruct, 1), _
            'str', '', _
            'int', 2048)
        
        If IsArray($aPath) And $aPath[3] = $sPath Then
            DllClose($hPsapi_Dll)
            Return SetExtended($iUbound, $aProcList[$i][1])
        EndIf
    Next
    
    DllClose($hPsapi_Dll)
    Return SetError(5, 0, False)
EndFunc