Hiding a DOS box

[mikelee33]

Performing a forum search on this topic shows me that it is difficult (not possible?), and I'm afraid I haven't seen it completely addressed. I wish to hide the box, or at least minimize it. Many thanks for any help.

Mike

[Jos]

Are you using Run/RunWait ? if so Check the helpfile for the 3rd parameter.

[Xenobiologist]

Hi,

or somethig like this:

expandcollapse popup

Global $a = ProcessGetId('cmd.EXE')
If IsArray($a) Then
    ConsoleWrite(ProcessGetWindow($a[1]) & @CRLF)
    WinSetState(ProcessGetWindow($a[1]), "", @SW_HIDE)
    Sleep(2000)
    WinSetState(ProcessGetWindow($a[1]), "", @SW_SHOW)
EndIf

Func ProcessGetWindow($PId)
    If IsNumber($PId) = 0 Or ProcessExists(ProcessGetName($PId)) = 0 Then
        SetError(1)
    Else
        Local $WinList = WinList()
        Local $i = 1
        Local $WindowTitle = ""
        While $i <= $WinList[0][0] And $WindowTitle = ""
            If WinGetProcess($WinList[$i][0], "") = $PId Then
                $WindowTitle = $WinList[$i][0]
            Else
                $i += 1
            EndIf
        WEnd
        Return $WindowTitle
    EndIf
EndFunc   ;==>ProcessGetWindow

Func ProcessGetId($Process)
    If IsString($Process) = 0 Then
        SetError(2)
    ElseIf ProcessExists($Process) = 0 Then
        SetError(1)
    Else
        Local $PList = ProcessList($Process)
        Local $i
        Local $PId[$PList[0][0] + 1]
        $PId[0] = $PList[0][0]
        For $i = 1 To $PList[0][0]
            $PId[$i] = $PList[$i][1]
        Next
        Return $PId
    EndIf
EndFunc   ;==>ProcessGetId

Func ProcessGetName($PId)
    If IsNumber($PId) = 0 Then
        SetError(2)
    ElseIf $PId > 9999 Then
        SetError(1)
    Else
        Local $PList = ProcessList()
        Local $i = 1
        Local $ProcessName = ""

        While $i <= $PList[0][0] And $ProcessName = ""
            If $PList[$i][1] = $PId Then
                $ProcessName = $PList[$i][0]
            Else
                $i += 1
            EndIf
        WEnd
        Return $ProcessName
    EndIf
EndFunc   ;==>ProcessGetName

Mega

Edited January 19, 2008 by Xenobiologist

[mikelee33]

Where this works perfectly well:

run ( $prog2 & ' ' &' -r -E -b '& $optionread & ' "'&GUICtrlRead($file)&'"')

If I add this:

run ( $prog2 & ' ' &' -r -E -b '& $optionread & ' "'&GUICtrlRead($file)&'"', @SW_HIDE) it doesn't.

I get an unable to execute external program error.

[GaryFrost]

Where this works perfectly well:

run ( $prog2 & ' ' &' -r -E -b '& $optionread & ' "'&GUICtrlRead($file)&'"')

If I add this:

run ( $prog2 & ' ' &' -r -E -b '& $optionread & ' "'&GUICtrlRead($file)&'"', @SW_HIDE) it doesn't.

I get an unable to execute external program error.

Try:

run ( $prog2 & '  ' &' -r -E -b  '& $optionread & ' "'&GUICtrlRead($file)&'"', "", @SW_HIDE)

[mikelee33]

GaryFrost,

Perfect! Such a little (but important) thing has just made my day.

Thank you.