Custom MsgBox

[zamboni128]

I'm looking for a way to create a function that will accept labels for 3 buttons and return a value based on the button selected. Can anyone point me to some example code for this? Thanks

[MrCreatoR]

Hi, and wellcome to the forum!

Something like this maybe:

expandcollapse popup

#include <GuiConstants.au3>

$Ret = _MyMsgBox("Title", "Prompt", 300, 200, "OK", "Cancel", "Retry", WinGetHandle(""))

ConsoleWrite($Ret)

Func _MyMsgBox($sTitle, $sPrompt, $iWidth, $iHeghit, $sButton1, $sButton2="", $sButton3="", $hParent_hWnd=0)
    Local $iOld_Opt_GOEM, $hMsgBox, $iRet_Value = 0
    Local $iButton1 = -1, $iButton2 = -1, $iButton3 = -1
    
    $iOld_Opt_GOEM = Opt("GuiOnEventMode", 0)
    
    If IsHWnd($hParent_hWnd) Then WinSetState($hParent_hWnd, "", @SW_DISABLE)
    
    $hMsgBox = GUICreate($sTitle, $iWidth, $iHeghit, -1, -1, $WS_CAPTION+$WS_SYSMENU, -1, $hParent_hWnd)
    GUICtrlCreateLabel($sPrompt, 20, 20, $iWidth - 40)
    
    If $sButton2 <> "" And $sButton3 = "" Then
        $iButton1 = GUICtrlCreateButton($sButton1, ($iWidth / 2) - 90, $iHeghit - 40, 60, 20)
        $iButton2 = GUICtrlCreateButton($sButton2, ($iWidth / 2) + 30, $iHeghit - 40, 60, 20)
    ElseIf $sButton3 <> "" Then
        $iButton1 = GUICtrlCreateButton($sButton1, 40, $iHeghit - 40, 60, 20)
        $iButton2 = GUICtrlCreateButton($sButton2, ($iWidth / 2) - 30, $iHeghit - 40, 60, 20)
        $iButton3 = GUICtrlCreateButton($sButton3, $iWidth - 100, $iHeghit - 40, 60, 20)
    Else
        $iButton1 = GUICtrlCreateButton($sButton1, ($iWidth / 2) - 30, $iHeghit - 40, 60, 20)
    EndIf
    
    GUISetState(@SW_SHOW, $hMsgBox)
    
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
            Case $iButton1
                $iRet_Value = 1
                ExitLoop
            Case $iButton2
                $iRet_Value = 2
                ExitLoop
            Case $iButton3
                $iRet_Value = 3
                ExitLoop
        EndSwitch
    WEnd
    
    If IsHWnd($hParent_hWnd) Then WinSetState($hParent_hWnd, "", @SW_ENABLE)
    GUIDelete($hMsgBox)
    Opt("GuiOnEventMode", $iOld_Opt_GOEM)
    Return $iRet_Value
EndFunc

Edited February 10, 2008 by MsCreatoR

[zamboni128]

Hi, and wellcome to the forum!

Something like this maybe:

expandcollapse popup

#include <GuiConstants.au3>

$Ret = _MyMsgBox("Title", "Prompt", 300, 200, "OK", "Cancel", "Retry", WinGetHandle(""))

ConsoleWrite($Ret)

Func _MyMsgBox($sTitle, $sPrompt, $iWidth, $iHeghit, $sButton1, $sButton2="", $sButton3="", $hParent_hWnd=0)
    Local $iOld_Opt_GOEM, $hMsgBox, $iRet_Value = 0
    Local $iButton1 = -1, $iButton2 = -1, $iButton3 = -1
    
    $iOld_Opt_GOEM = Opt("GuiOnEventMode", 0)
    
    If IsHWnd($hParent_hWnd) Then WinSetState($hParent_hWnd, "", @SW_DISABLE)
    
    $hMsgBox = GUICreate($sTitle, $iWidth, $iHeghit, -1, -1, $WS_CAPTION+$WS_SYSMENU, -1, $hParent_hWnd)
    GUICtrlCreateLabel($sPrompt, 20, 20, $iWidth - 40)
    
    If $sButton2 <> "" And $sButton3 = "" Then
        $iButton1 = GUICtrlCreateButton($sButton1, ($iWidth / 2) - 90, $iHeghit - 40, 60, 20)
        $iButton2 = GUICtrlCreateButton($sButton2, ($iWidth / 2) + 30, $iHeghit - 40, 60, 20)
    ElseIf $sButton3 <> "" Then
        $iButton1 = GUICtrlCreateButton($sButton1, 40, $iHeghit - 40, 60, 20)
        $iButton2 = GUICtrlCreateButton($sButton2, ($iWidth / 2) - 30, $iHeghit - 40, 60, 20)
        $iButton3 = GUICtrlCreateButton($sButton3, $iWidth - 100, $iHeghit - 40, 60, 20)
    Else
        $iButton1 = GUICtrlCreateButton($sButton1, ($iWidth / 2) - 30, $iHeghit - 40, 60, 20)
    EndIf
    
    GUISetState(@SW_SHOW, $hMsgBox)
    
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
            Case $iButton1
                $iRet_Value = 1
                ExitLoop
            Case $iButton2
                $iRet_Value = 2
                ExitLoop
            Case $iButton3
                $iRet_Value = 3
                ExitLoop
        EndSwitch
    WEnd
    
    If IsHWnd($hParent_hWnd) Then WinSetState($hParent_hWnd, "", @SW_ENABLE)
    GUIDelete($hMsgBox)
    Opt("GuiOnEventMode", $iOld_Opt_GOEM)
    Return $iRet_Value
EndFunc

Thank you very much. The code was simple and straight forward. Even me as a novice can understand the code.