GUICtrlCreateGroup()

[comradeb14ck]

Hey guys. Long time no see. I'm currently working on some code, and I would like to change the color and font size of the group text. Is there anyway I can do this? I tried doing GUICtrlSetColor() to set the font color, but it apparently has no effect. Thanks for your time.

[MrCreatoR]

Hi,

You can turn off the xp style, so you can set color/font for the Group control (the same for CheckBox)...

#include <GuiConstants.au3>

$GUI = GUICreate("Test Script", 300, 200)

;Disable XP theme
DllCall("uxtheme.dll", "none", "SetThemeAppProperties", "int", 0)

GUICtrlCreateGroup("My Colored Group", 20, 20, 260, 160)
GUICtrlSetColor(-1, 0x0000FF)
GUICtrlSetFont(-1, 9, 800, 0, "Georgia")

;Enable XP theme back
DllCall("uxtheme.dll", "none", "SetThemeAppProperties", "int", 3)

GUISetState(@SW_SHOW, $GUI)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

[comradeb14ck]

Thanks, worked perfectly.

[rasim]

Or:

#include <GuiConstants.au3>

$GUI = GUICreate("Test Script", 300, 200)

$hGroup = GUICtrlCreateGroup("My Colored Group", 20, 20, 260, 160, $BS_CENTER)
GUICtrlSetColor(-1, 0xFF0000)
GUICtrlSetFont(-1, 9, 800, 0, "Georgia")

DllCall("UxTheme.dll", "int", "SetWindowTheme", "hwnd", GUICtrlGetHandle($hGroup), "wstr", "", "wstr", "")

GUISetState(@SW_SHOW, $GUI)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

[MrCreatoR]

Thanks rasim, i didn't know about SetWindowTheme