FileOpenDialog()

[Aassdd]

1. How can I get the filename only from FileOpenDialog, e.g. C:/Notes.txt >>> Notes.txt?

2. Also without extension just StringTrimLeft($path, 4) right?

I'm sure this has been asked before, but I don't know what to search.

Edited March 23, 2008 by Aassdd

[rasim]

Try this:

$file = FileOpenDialog("Select the file", "", "All (*.*)")
If @error Then Exit
MsgBox(0, "File name + ext", StringRegExpReplace($file, "^.*\\", ""))
MsgBox(0, "File name", StringRegExpReplace($file, "^.*\\(.*)\..*", "\1"))

Or see _PathSplit() function in the help file.

[Aassdd]

Thanks a lot.

[Aassdd]

Sorry, another quick question. How can I add hotkeys to menu items? (Open [tab] Ctrl+O)

Edited March 23, 2008 by Aassdd

[rasim]

Aassdd

How can I add hotkeys to menu items? (Open [tab] Ctrl+O)

This?:

#include <GuiConstants.au3>

HotKeySet("^o", "_OpenFile")

$hGui = GUICreate("Test GUI", 300, 200)

$hMenu = GUICtrlCreateMenu("&File")
$MenuOpen = GUICtrlCreateMenuItem("&Open", $hMenu)

GUISetState()

While 1
    $msg = GUIGetMsg()
    Switch $msg
        Case $GUI_EVENT_CLOSE
            ExitLoop
        Case $MenuOpen
            _OpenFile()
            
    EndSwitch
WEnd

Func _OpenFile()
    Local $iFile
    
    $iFile = FileOpenDialog("Select a file", "", "All files (*.*)")
    If Not @error Then MsgBox(0, "", $iFile & " file selected")
EndFunc

Edited March 23, 2008 by rasim

[Aassdd]

No

Edited March 23, 2008 by Aassdd

[MrCreatoR]

Just add them to the item text after tab...

#include <GuiConstants.au3>

HotKeySet("^o", "_OpenFile")
HotKeySet("^e", "_Quit")

$hGui = GUICreate("Test GUI", 300, 200)

$hMenu = GUICtrlCreateMenu("&File")
$MenuOpen = GUICtrlCreateMenuItem("&Open File   CTRL+O", $hMenu)
$MenuExit = GUICtrlCreateMenuItem("Exit Program CTRL+E", $hMenu)

GUISetState()

While 1
    $msg = GUIGetMsg()
    Switch $msg
        Case $GUI_EVENT_CLOSE, $MenuExit
            _Quit()
        Case $MenuOpen
            _OpenFile()
    EndSwitch
WEnd

Func _Quit()
    Exit
EndFunc

Func _OpenFile()
    Local $iFile
    
    $iFile = FileOpenDialog("Select a file", "", "All files (*.*)")
    If Not @error Then MsgBox(0, "", $iFile & " file selected")
EndFunc

[Aassdd]

Yes, but the hotkey is global isn't it? Functions will be activated even I press ^o in other windows.

[MrCreatoR]

Yes, but the hotkey is global isn't it? Functions will be activated even I press ^o in other windows.

Yes they Global, you can check the window status when user press the hotkey...

expandcollapse popup

#include <GuiConstants.au3>

HotKeySet("^o", "_HotKey_Events")
HotKeySet("^e", "_HotKey_Events")

$hGui = GUICreate("Test GUI", 300, 200)

$hMenu = GUICtrlCreateMenu("&File")
$MenuOpen = GUICtrlCreateMenuItem("&Open File   CTRL+O", $hMenu)
$MenuExit = GUICtrlCreateMenuItem("Exit Program CTRL+E", $hMenu)

GUISetState()

While 1
    $msg = GUIGetMsg()
    Switch $msg
        Case $GUI_EVENT_CLOSE, $MenuExit
            Exit
        Case $MenuOpen
            _OpenFile()
    EndSwitch
WEnd

Func _HotKey_Events()
    If Not WinActive($hGui) Then
        HotKeySet(@HotKeyPressed)
        Send(@HotKeyPressed)
        HotKeySet(@HotKeyPressed, "_HotKey_Events")
        Return
    EndIf
    
    Switch @HotKeyPressed
        Case "^o"
            _OpenFile()
        Case "^e"
            Exit
    EndSwitch
EndFunc

Func _OpenFile()
    Local $sFile = FileOpenDialog("Select a file", "", "All files (*.*)")
    If Not @error Then MsgBox(0, "", $sFile & " file selected")
EndFunc

Or use GUISetAccelerators with the latest beta.

Edited March 23, 2008 by MsCreatoR

[monoceres]

Edit: I was late

Edited March 23, 2008 by monoceres

[Aassdd]

Thank you Creator, work's perfectly. Still need some help here http://www.autoitscript.com/forum/index.php?showtopic=66988

[MrCreatoR]

I edited a little my last post, there was a wrong function name on restoring the HotKeys events.