Post date for yesterday

[Mel]

We currently use the below code for yesterdays date but it does not work on the first of the month so we use 1/31/08 I would like to change this so on the first it reflects th last day of the previous month.

Please assist....

$mm = @MDAY - 1

$yy = @YEAR - 2000

If $mm < 10 Then $PDate = @MON & "0" & $mm & "0" & $yy

If $mm > 10 Then $PDate = @MON & "" & $mm & "0" & $yy

If $mm = 10 Then $PDate = @MON & "" & $mm & "0" & $yy

If $mm = 00 Then $PDate = ("013108")

[monoceres]

This is very simple if you use the date UDF

#include <date.au3>
$now=_NowCalc()
MsgBox(0,"",$now)
$yesterday=_DateAdd("D",-1,$now)
MsgBox(0,"",$yesterday)

[Xenobiologist]

Hi,

#include <Date.au3>
ConsoleWrite(_DateAdd('d','-1', _NowCalcDate()) & @CRLF)

Mega

[Mel]

Not exactly what I needed but it's a start. I need the output to be "041508". The output is 2008/04/15 12:22:17. Do you know of a quick fix.

Edited April 16, 2008 by Mel

[Xenobiologist]

#include <Date.au3>

$date = _DateAdd('d','-1', _NowCalcDate())

$date = StringMid($date, 6,2) & StringRight($date, 2) & StringMid($date, 3,2)

ConsoleWrite($date & @CRLF)

[SmOke_N]

#include <date.au3>

MsgBox(0, 0, _DateDaysAgo())
MsgBox(0, 0, _DateDaysAgo(2))
MsgBox(0, 0, _DateDaysAgo(3))

Func _DateDaysAgo($nDaysAgo = 1)
    Local $szDiff = _DateAdd("d", "-" & $nDaysAgo, _NowCalcDate())
    Local $szPattern = "(\d+)/(\d+)/(\d+)"
    Local $aSRE = StringRegExp($szDiff, $szPattern, 1)
    Return $aSRE[1] & $aSRE[2] & StringTrimLeft($aSRE[0], 2)
EndFunc

[Mel]

Thanks guys I got it. You guys are like batman!