Sign in to follow this  
Followers 0
Info

Hide the taskbar

10 posts in this topic

I'm looking for a function to hide the task, and not let it appear...

tank u :D

Share this post


Link to post
Share on other sites



Why would you need such a thing :D


----------------------------------90% of teens today would die if Myspace,Bebo + FaceBook had a system failure and was completely destroyed. If you are one of the 10% that would be laughing, copy and paste this to your signature.----------------------------------Code to win, 'till you die, 'till the compiler dies from your linesCode to win, take it all, just keep coding till you fallDay by day, codin' all the way, I'm not cavin' inLet another App begin, code to win

Share this post


Link to post
Share on other sites

Regshot shows these changes when I minimize the taskbar...

HKU\S-1-5-21-3021850519-1567384275-499896294-1011\Software\Microsoft\Internet Explorer\Desktop\Components\0\Position: 2C 00 00 00 4C 00 00 00 00 00 00 00 34 07 00 00 96 04 00 00 00 00 00 00 01 00 00 00 01 00 00 00 01 00 00 00 00 00 00 00 00 00 00 00

HKU\S-1-5-21-3021850519-1567384275-499896294-1011\Software\Microsoft\Internet Explorer\Desktop\Components\0\Position: 2C 00 00 00 4C 00 00 00 00 00 00 00 34 07 00 00 AC 04 00 00 00 00 00 00 01 00 00 00 01 00 00 00 01 00 00 00 00 00 00 00 00 00 00 00

HKU\S-1-5-21-3021850519-1567384275-499896294-1011\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced\TaskbarSizeMove: 0x00000000

HKU\S-1-5-21-3021850519-1567384275-499896294-1011\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced\TaskbarSizeMove: 0x00000001

Share this post


Link to post
Share on other sites

#4 ·  Posted (edited)

Of course the SID would be different for each computer/account. So, HKU\<SID>\... And you would probably have to notify the system of the update in some way (DllCall).

Edited by zorphnog

Share this post


Link to post
Share on other sites

#include <WinAPI.au3>

Global Const $SW_HIDE = 0
Global Const $SW_SHOW = 5

_ShowTaskBar(False)
Sleep(2000)
_ShowTaskBar()

_ShowStartButton(False)
Sleep(2000)
_ShowStartButton()

_ShowTaskBarClock(False)
Sleep(2000)
_ShowTaskBarClock()

_ShowTaskBarIcons(False)
Sleep(2000)
_ShowTaskBarIcons()

For $x = 1 To _TaskBarIndexCount()
    _ShowProgramsShowingInTaskBar(False, $x)
    Sleep(2000)
    _ShowProgramsShowingInTaskBar(True, $x)
Next

Func _ShowTaskBar($fShow = True)
    Local $hTaskBar
    $hTaskBar = _WinAPI_FindWindow("Shell_TrayWnd", "")
    If $fShow Then
        _WinAPI_ShowWindow($hTaskBar, $SW_SHOW)
    Else
        _WinAPI_ShowWindow($hTaskBar, $SW_HIDE)
    EndIf
EndFunc   ;==>_ShowTaskBar

Func _ShowStartButton($fShow = True)
    Local $hTaskBar, $hStartButton
    $hTaskBar = _WinAPI_FindWindow("Shell_TrayWnd", "")
    $hStartButton = ControlGetHandle($hTaskBar, "", "Button1")
    If $fShow Then
        _WinAPI_ShowWindow($hStartButton, $SW_SHOW)
    Else
        _WinAPI_ShowWindow($hStartButton, $SW_HIDE)
    EndIf
EndFunc   ;==>_ShowStartButton

Func _ShowTaskBarClock($fShow = True)
    Local $hTaskBar, $hParent, $hClock
    $hTaskBar = _WinAPI_FindWindow("Shell_TrayWnd", "")
    $hParent = ControlGetHandle($hTaskBar, "", "TrayNotifyWnd1")
    $hClock = ControlGetHandle($hParent, "", "TrayClockWClass1")
    If $fShow Then
        _WinAPI_ShowWindow($hClock, $SW_SHOW)
    Else
        _WinAPI_ShowWindow($hClock, $SW_HIDE)
    EndIf
EndFunc   ;==>_ShowTaskBarClock

Func _ShowTaskBarIcons($fShow = True)
    Local $hTaskBar, $hParent, $hChild
    $hTaskBar = _WinAPI_FindWindow("Shell_TrayWnd", "")
    $hParent = ControlGetHandle($hTaskBar, "", "TrayNotifyWnd1")
    $hChild = ControlGetHandle($hParent, "", "ToolbarWindow321")
    If $fShow Then
        _WinAPI_ShowWindow($hChild, $SW_SHOW)
    Else
        _WinAPI_ShowWindow($hChild, $SW_HIDE)
    EndIf
EndFunc   ;==>_ShowTaskBarIcons

Func _ShowProgramsShowingInTaskBar($fShow = True, $iIndex = 1)
    Local $hTaskBar, $hRebar, $hToolBar
    $hTaskBar = _WinAPI_FindWindow("Shell_TrayWnd", "")
    $hRebar = ControlGetHandle($hTaskBar, "", "ReBarWindow321")
    $hToolBar = ControlGetHandle($hRebar, "", "ToolbarWindow32" & $iIndex)
    If $hToolBar <> 0x00000000 Then
        If $fShow Then
            _WinAPI_ShowWindow($hToolBar, $SW_SHOW)
        Else
            _WinAPI_ShowWindow($hToolBar, $SW_HIDE)
        EndIf
    EndIf
EndFunc   ;==>_ShowProgramsShowingInTaskBar

Func _TaskBarIndexCount()
    Local $hTaskBar, $hRebar, $hToolBar, $iCount = 0
    $hTaskBar = _WinAPI_FindWindow("Shell_TrayWnd", "")
    $hRebar = ControlGetHandle($hTaskBar, "", "ReBarWindow321")
    While 1
        $hToolBar = ControlGetHandle($hRebar, "", "ToolbarWindow32" & $iCount + 1)
        If $hToolBar = 0x00000000 Then ExitLoop
        $iCount += 1
    WEnd
    Return $iCount
EndFunc   ;==>_TaskBarIndexCount

Mega


Scripts & functions Organize Includes Let Scite organize the include files

Yahtzee The game "Yahtzee" (Kniffel, DiceLion)

LoginWrapper Secure scripts by adding a query (authentication)

_RunOnlyOnThis UDF Make sure that a script can only be executed on ... (Windows / HD / ...)

Internet-Café Server/Client Application Open CD, Start Browser, Lock remote client, etc.

MultipleFuncsWithOneHotkey Start different funcs by hitting one hotkey different times

Share this post


Link to post
Share on other sites

Thank you Mega :D

Share this post


Link to post
Share on other sites

Welcome!


Scripts & functions Organize Includes Let Scite organize the include files

Yahtzee The game "Yahtzee" (Kniffel, DiceLion)

LoginWrapper Secure scripts by adding a query (authentication)

_RunOnlyOnThis UDF Make sure that a script can only be executed on ... (Windows / HD / ...)

Internet-Café Server/Client Application Open CD, Start Browser, Lock remote client, etc.

MultipleFuncsWithOneHotkey Start different funcs by hitting one hotkey different times

Share this post


Link to post
Share on other sites

Small modification for Vista:

Func _ShowTaskBar($fShow = True)
    Local $hTaskBar
    If @OSVersion = "WIN_VISTA" Then _ShowStartButton($fShow)
    $hTaskBar = _WinAPI_FindWindow("Shell_TrayWnd", "")
    If $fShow Then
        _WinAPI_ShowWindow($hTaskBar, $SW_SHOW)
    Else
        _WinAPI_ShowWindow($hTaskBar, $SW_HIDE)
    EndIf
EndFunc   ;==>_ShowTaskBar

Func _ShowStartButton($fShow = True)
    Local $hTaskBar, $hStartButton
    If @OSVersion = "WIN_VISTA" Then
        $hStartButton = _WinAPI_FindWindow("Button", "Start")
    Else
        $hTaskBar = _WinAPI_FindWindow("Shell_TrayWnd", "")
        $hStartButton = ControlGetHandle($hTaskBar, "", "Button1")
    EndIf
    If $fShow Then
        _WinAPI_ShowWindow($hStartButton, $SW_SHOW)
    Else
        _WinAPI_ShowWindow($hStartButton, $SW_HIDE)
    EndIf
EndFunc   ;==>_ShowStartButton

Share this post


Link to post
Share on other sites

EWWWWW, Vista!

Share this post


Link to post
Share on other sites

EWWWWW, Vista!

LOL, I don't have VISTA, that is why I Coulnd't test it.

Anyway, thanks!

Mega


Scripts & functions Organize Includes Let Scite organize the include files

Yahtzee The game "Yahtzee" (Kniffel, DiceLion)

LoginWrapper Secure scripts by adding a query (authentication)

_RunOnlyOnThis UDF Make sure that a script can only be executed on ... (Windows / HD / ...)

Internet-Café Server/Client Application Open CD, Start Browser, Lock remote client, etc.

MultipleFuncsWithOneHotkey Start different funcs by hitting one hotkey different times

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0