IsArray function

[jercfd]

Hello. I seem to be having a problem with the IsArray function. In my code, when GUIGetCursorInfo returns an array, the If statements in "If IsArray($MouseInfo) = 1 Then" don't seem to respond when IsArray is sucessful. I don't know what is wrong and was wondering if someone here can please help me.

expandcollapse popup

#include <GUIConstants.au3>

$MouseInfo = GUIGetCursorInfo()
$Height = 600
$Width = 800

$GUI = GUICreate("Mac Os X Theme", $Width, $Height, -1, -1, BitOR($WS_SIZEBOX, $WS_POPUP))
GUISetBkColor(0xACACAC)
GUICtrlCreatePic(@ScriptDir & "\Brushed Metal.jpg", -5, -5, $Width + 10, $Height + 10, $GUI_SS_DEFAULT_PIC, $GUI_WS_EX_PARENTDRAG)
GUICtrlSetResizing(-1, $GUI_DOCKBORDERS)
GUICtrlSetState(-1, $GUI_DISABLE)
$Close = GUICtrlCreatePic(@ScriptDir & "\close_off.gif", 8, 4, 14, 14)
GUICtrlSetResizing(-1, $GUI_DOCKHEIGHT + $GUI_DOCKWIDTH + $GUI_DOCKTOP + $GUI_DOCKLEFT)
GUICtrlSetTip(-1, "Close")
$Minimize = GUICtrlCreatePic(@ScriptDir & "\minimize_off.gif", 30, 4, 14, 14)
GUICtrlSetResizing(-1, $GUI_DOCKHEIGHT + $GUI_DOCKWIDTH + $GUI_DOCKTOP + $GUI_DOCKLEFT)
GUICtrlSetTip(-1, "Minimize")
$Maximize = GUICtrlCreatePic(@ScriptDir & "\maximize_off.gif", 51, 4, 14, 14)
GUICtrlSetResizing(-1, $GUI_DOCKHEIGHT + $GUI_DOCKWIDTH + $GUI_DOCKTOP + $GUI_DOCKLEFT)
GUICtrlSetTip(-1, "Maximize")

AdlibEnable("CMM", 250)

GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    If IsArray($MouseInfo) = 1 Then
        If $MouseInfo[2] = 1 And $MouseInfo[4] = $Close Then Exit
        If $MouseInfo[2] = 1 And $MouseInfo[4] = $Minimize Then GUISetState(@SW_MINIMIZE, $GUI)
        If $MouseInfo[2] = 1 And $MouseInfo[4] = $Maximize Then GUISetState(@SW_MAXIMIZE, $GUI)
    EndIf
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func CMM()
    If IsArray($MouseInfo) = 1 Then
        If $MouseInfo[4] = $Close Or $MouseInfo[4] = $Minimize Or $MouseInfo[4] = $Maximize Then
            GUICtrlSetImage($Close, @ScriptDir & "\close_on.gif")
            GUICtrlSetImage($Minimize, @ScriptDir & "\minimize_on.gif")
            GUICtrlSetImage($Maximize, @ScriptDir & "\maximize_on.gif")
        Else
            GUICtrlSetImage($Close, @ScriptDir & "\close_off.gif")
            GUICtrlSetImage($Minimize, @ScriptDir & "\minimize_off.gif")
            GUICtrlSetImage($Maximize, @ScriptDir & "\maximize_off.gif")
        EndIf
    EndIf
EndFunc   ;==>CMM

[MrCreatoR]

Hi,

How do you know if $MouseInfo is an array? you should use «$MouseInfo = GUIGetCursorInfo()» inside the main loop, so it will get needed information in "real time".

[jercfd]

That is what i am doing. The $MouseInfo is only an array when the mouse is in the application and it is on a control.

[therks]

Which is exactly how it's supposed to work, unless you provide it a handle to the GUI window you want to check. You are only checking that function once as well, you need to check and recheck and recheck, etc. Put $MouseInfo = GUIGetCursorInfo() at the top of your While loop.

[MrCreatoR]

That is what i am doing

I can't see in your example that this variable is changed. You need to place that checking in the main loop, like this:

While 1
    $nMsg = GUIGetMsg()
    $MouseInfo = GUIGetCursorInfo()
    
    If IsArray($MouseInfo) = 1 Then
        If $MouseInfo[2] = 1 And $MouseInfo[4] = $Close Then Exit
        If $MouseInfo[2] = 1 And $MouseInfo[4] = $Minimize Then GUISetState(@SW_MINIMIZE, $GUI)
        If $MouseInfo[2] = 1 And $MouseInfo[4] = $Maximize Then GUISetState(@SW_MAXIMIZE, $GUI)
    EndIf
    
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

[jercfd]

Okay. I understand now. Thanks for solving my problem.