Draggable input control

[AustrianOak]

Been working on trying to hide the first one like you said with no luck. I tried using a loop and hiding the first one and it didn't work.

I'm lost...

[AustrianOak]

ok i've solved the problem with creating multiple icons from multiple base images but I am still having trouble adding functionality for new items I add to the context menu.

Can someone please help me. This is what I have done in an attempt to add functionality for the additional menu items I added but whenever I create more than one icon and try to right click and delete it, it gives me an error saying "array variable has incorrect number of subscripts or subscript dimension range exceeded." and says that while pointing to the ElseIf $msg[0] = $ahInput[$i][4] Then line. please offer a better way of adding functionality as mine obviously sucks

For $i = 1 To $ahInput[0][0]
        If $msg[0] = $ahInput[$i][3] Then
            msgbox(0, "", "")
            ExitLoop
        ElseIf $msg[0] = $ahInput[$i][4] Then
            MsgBox(0, "", "lion")
        ElseIf $msg[0] = $ahInput[$i][6] Then
            If $CheckRegister = False Then
                If $lastdragIP < 5 Then
                    $lastdragIP += 1
                    createNextdragIP($lastdragIP)
                EndIf
            Else
                If $lastdragIP < 5 Then
                    $lastdragIP += 1
                    createNextdragIP($lastdragIP)
                EndIf
            EndIf
        ElseIf $msg[0] = $ahInput[$i][7] Then
            function()
        EndIf
Next
...

Edited August 7, 2008 by IWantIt

[AustrianOak]

BUMP

MrCreator: How do I add functionality?

Edited August 7, 2008 by IWantIt

[AustrianOak]

And how do I hide ALL of the open icons?

[AustrianOak]

Need help

[AustrianOak]

Bump.

[AustrianOak]

Still having trouble with adding functionality. MrCreator, when you have the time, could you show me the proper way to add functionality for multiple controls? And how to hide all the icons at once.

Thanks.

[AustrianOak]

Bump

[AustrianOak]

Bump

[MrCreatoR]

@IWantIt

About the hiding of first (or any other) icon - just use the first element of the array:

GUISetState(@SW_HIDE, $ahInput[1][0])

About “adding functionality”... i am not sure if i understand you correctly, can you be more specific?

[AustrianOak]

Well what I mean is adding functionality for the menus that I have when I right click. For example, in a previous post by martin on page 3 there is a delete item that appears on the context menu when you right click on the item, and it has functionality for it to delete it.

But when I try to add more menu items I don't know how to add functionality for them to "do something" like the delete item.

[MrCreatoR]

Ok, i understand now what you want to do...

Well, you will have to add an items but also increase the elements in the second dimention, for example if you want to add an item to delete all the icons, then you do it like this (follow the commented lines, i wrote all the changes):

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $ahInput[2][5] ;Cganged 4 to 5

$GUI = GUICreate("Dragable Controls", 300, 300)

$Create_DIP_Button = GUICtrlCreatePic(@SystemDir & "\oobe\images\merlin.gif", 32, 58, 26, 26)

GUISetState()

While 1
    $nMsg = GUIGetMsg(1)
    
    Switch $nMsg[0]
        Case $GUI_Event_Close
            Exit
        Case $Create_DIP_Button
            CreateDragIP()
        Case $ahInput[1][1] To $ahInput[$ahInput[0][0]][1] ;$GUI_EVENT_PRIMARYDOWN
            If $nMsg[0] = 0 Then ContinueLoop
            
            Local $aMouse_Pos = MouseGetPos()
            Local $aCursorInfo = GUIGetCursorInfo($nMsg[1]), $aCurrent_Mouse_Pos, $aInputGUI_Pos
            
            $aInputGUI_Pos = WinGetPos($nMsg[1])
            If Not IsArray($aInputGUI_Pos) Then ContinueLoop
            
            While IsArray($aCursorInfo) And $aCursorInfo[2] = 1
                $aCursorInfo = GUIGetCursorInfo($nMsg[1])
                $aCurrent_Mouse_Pos = MouseGetPos()
                
                WinMove($nMsg[1], "", _
                    $aInputGUI_Pos[0] - $aMouse_Pos[0] + $aCurrent_Mouse_Pos[0], _
                    $aInputGUI_Pos[1] - $aMouse_Pos[1] + $aCurrent_Mouse_Pos[1])
                
                Sleep(10)
            WEnd
    EndSwitch
    
    ;Changed the all loop (to work more effective with more than one message)
    For $i = 1 To $ahInput[0][0]
        Switch $nMsg[0]
            Case $ahInput[$i][3] ;This is the "Delete" item message
                DeleteDragIP($nMsg[0])
                ExitLoop
            Case $ahInput[$i][4] ;This is the "Delete All" item message
                DeleteAllDragIP()
                ExitLoop
        EndSwitch
    Next
WEnd

Func CreateDragIP()
    Local $aMainGUI_Pos = WinGetPos($GUI)
    
    $ahInput[0][0] += 1
    ReDim $ahInput[$ahInput[0][0]+1][5] ;4 changed to 5
    
    $ahInput[$ahInput[0][0]][0] = GUICreate("", 26, 26, $aMainGUI_Pos[0] + 65, $aMainGUI_Pos[1] + 60 + 25, _
        $WS_POPUP, BitOR($WS_EX_TOOLWINDOW, $WS_EX_LAYERED))
    
    $ahInput[$ahInput[0][0]][1] = GUICtrlCreatePic(@SystemDir & "\oobe\images\merlin.gif", 0, 0, 26, 26, -1)
    
    $ahInput[$ahInput[0][0]][2] = GUICtrlCreateContextMenu($ahInput[$ahInput[0][0]][1])
    $ahInput[$ahInput[0][0]][3] = GUICtrlCreateMenuItem("&Delete", $ahInput[$ahInput[0][0]][2])
    $ahInput[$ahInput[0][0]][4] = GUICtrlCreateMenuItem("&Delete All", $ahInput[$ahInput[0][0]][2]) ;Added
    
    GUISetState(@SW_SHOW, $ahInput[$ahInput[0][0]][0])
    
    WinSetOnTop($ahInput[$ahInput[0][0]][0], "", 1)
EndFunc

Func DeleteDragIP($iCtrlID)
    Local $aTmpArr[2][5] ;Changed 4 to 5
    
    For $i = 1 To $ahInput[0][0]
        If $ahInput[$i][3] = $iCtrlID Then
            GUIDelete($ahInput[$i][0])
        Else
            $aTmpArr[0][0] += 1
            ReDim $aTmpArr[$aTmpArr[0][0]+1][5] ;Changed 4 to 5
            
            $aTmpArr[$aTmpArr[0][0]][0] = $ahInput[$i][0]
            $aTmpArr[$aTmpArr[0][0]][1] = $ahInput[$i][1]
            $aTmpArr[$aTmpArr[0][0]][2] = $ahInput[$i][2]
            $aTmpArr[$aTmpArr[0][0]][3] = $ahInput[$i][3]
            $aTmpArr[$aTmpArr[0][0]][4] = $ahInput[$i][4] ;This line was added
        EndIf
    Next
    
    $ahInput = $aTmpArr
EndFunc

;Added new function
Func DeleteAllDragIP()
    For $i = 1 To $ahInput[0][0]
        GUIDelete($ahInput[$i][0])
    Next
    
    $ahInput = 0
    Dim $ahInput[2][5]
EndFunc

[AustrianOak]

This is magnificent. And using the concept of deleting all the icons I now can minimize them all. Thanks so much for all the time you've spent helping me.