Another Question ;==> Need Help

[zFrank]

how can i close Yahoo! Messenger from its tray menu?

i dont want to use processclose() , winkill , etc

i want to close it directly from tray menu by selecting exit from it.

if it is not able to be done then please tell me about it.

thanks.

[d4rk]

MouseMove()
MouseClick()

[zFrank]

@ d4rk

hey! thanks for the reply but can it work on different screen resolutions?

or will it work if tray icons are on different place?

i have tried it before..... it does not work if there are more icons in system tray.

please help....

[Xenobiologist]

Hi,

you need the Systray UDF

#include<Systray.au3>
Opt('WinTitleMatchMode', 4)
Global $title = "Check Point Integrity Agent"
Global $prcoess = "icq.exe"
;Global $prcoess = "winampa.exe"

clickSysTrayByTitle($title, "secondary", 1)
;clickSysTrayByProcess($prcoess, "right")

Func clickSysTrayByTitle($winTitle, $click = "left", $times = 1)
    Local $a = _SysTrayIconTitles ()
    Local $p = MouseGetPos()
    For $i = 0 To UBound($a) - 1
        If $a[$i] = $winTitle Then
            $pos = _SysTrayIconPos ($i)
            MouseClick($click, $pos[0], $pos[1], $times, 1)
            ExitLoop
        EndIf
    Next
    MouseMove($p[0], $p[1], 1)
EndFunc   ;==>clickSysTrayByTitle

Func clickSysTrayByProcess($winProcess, $click = "left", $times = 1)
    If Not ProcessExists($winProcess) Then Return -1
    Local $a = _SysTrayIconProcesses ()
    Local $p = MouseGetPos()
    For $i = 0 To UBound($a) - 1
        If $a[$i] = $winProcess Then
            $pos = _SysTrayIconPos ($i)
            MouseClick($click, $pos[0], $pos[1], $times, 1)
            ExitLoop
        EndIf
    Next
    MouseMove($p[0], $p[1], 1)
EndFunc   ;==>clickSysTrayByProcess

Mega

[zFrank]

@ Xenobiologist

thanks... you are really a great man.