GUICtrlRead() return -1 on context menu item

[MrCreatoR 73]

Hi,

I am trying to get state of the item in context menu, but GUICtrlRead() always returns -1, is this a bug?

#include <GUIConstantsEx.au3>

GUICreate("GUICtrlRead() Bug?", 200, 100)

$hMenu = GUICtrlCreateContextMenu()

$MenuItem = GUICtrlCreateMenuItem("Test", $hMenu)
$ExitItem = GUICtrlCreateMenuItem("Exit", $hMenu)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE, $ExitItem
            Exit
        Case $MenuItem
            MsgBox(0, "", "State of Context MenuItem = " & GUICtrlRead($MenuItem))
    EndSwitch
WEnd

Call the context menu, and press the "Test" item, GUICtrlRead() return -1, why? on 3.2.8.1 it was working fine, now (on 3.2.12.0) it's not muttley

Maybe there is some sort of workaround for this? really need it now...

Edited July 22, 2008 by MrCreatoR

[rasim 20]

MrCreatoR

Hi! Mayb this behavior fixed in the latest version?

From changelog:

12th June, 2008 - v3.2.12.1

AutoIt:

Fixed: RunAs() and RunAsWait() now use @SystemDir as the working directory instead of @WorkingDir when a user-supplied working directory is not specified.

Fixed: Contextmenuitem not firing events.

Fixed: Icon transparency refresh when on tab regression.

Fixed #360: RunAs() under Windows 2000.

[MrCreatoR 73]

Hi! Mayb this behavior fixed in the latest version?

Indeed, thank you... Btw, i didn't knew about the last version, i thought 3.2.12.0 is the last released muttley

[MrCreatoR 73]

Oops, it's fixed only in the last beta, not in 3.2.12.1...

Need ideas how to make it work on 3.2.12.1.

[rasim 20]

Oops, it's fixed only in the last beta, not in 3.2.12.1...

Need ideas how to make it work on 3.2.12.1.

Use functions from GuiMenu.au3

Example:

expandcollapse popup

#include <GuiMenu.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>

Global Enum $idOpen = 1000, $idSave, $idInfo

$hGUI = GUICreate("Menu", 400, 300)

$hMenu = _GUICtrlMenu_CreatePopup()

_GUICtrlMenu_InsertMenuItem($hMenu, 0, "Open", $idOpen)
_GUICtrlMenu_InsertMenuItem($hMenu, 1, "Save", $idSave)
_GUICtrlMenu_InsertMenuItem($hMenu, 3, "", 0)
_GUICtrlMenu_InsertMenuItem($hMenu, 3, "Info", $idInfo)
    
GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")
GUIRegisterMsg($WM_CONTEXTMENU, "WM_CONTEXTMENU")

GUISetState()

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

Func WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
    Switch $wParam
        Case $idOpen
            ConsoleWrite("!> Open" & @LF)
            _GUICtrlMenu_CheckRadioItem ($hMenu, 0, 3, 0)
        Case $idSave
            ConsoleWrite("!> Save" & @LF)
        Case $idInfo
            ConsoleWrite("!> Open" & @LF)
    EndSwitch
EndFunc   ;==>WM_COMMAND

; Handle WM_CONTEXTMENU messages
Func WM_CONTEXTMENU($hWnd, $Msg, $wParam, $lParam)
    _GUICtrlMenu_TrackPopupMenu($hMenu, $wParam)
    
    Return True
EndFunc   ;==>WM_CONTEXTMENU

muttley