blur an image ?

[komalo]

Hi

I was wondering if there's a way to blur an image, I tried using GDI+ Graphic Functions But I can't save it and it

All blurring happens on the screen only, tried prospeed but I couldn't understand it, finally

Searched the internet looking for an image blur tool with no success.

also , i wanted to know if there's a way to use a bitmap resource in dll

thanx in advance

[dbzfanatic]

Try blurring the image then using _ScreenCapture_CaptureWnd() to save the image.

[komalo]

well i use this now but i was wondering if there's another way

the code i am using got it from here :

#458911

Edited August 26, 2008 by komalo

[jpam]

change autoit_builder_wall_800x600.jpg with your own picture

#include <Prospeed30.au3>

Opt("GUIOnEventMode", 1)
HotKeySet("{Esc}","_Exit")

$Gui = GUICreate("Blur", 800, 600)
GUISetOnEvent(-3, "_exit")
GUISetState()

$hdc = GetHDC()

$image = LoadFileImage("autoit_builder_wall_800x600.jpg")
$array = InitFx($image)

For $i = 1 To 50
    blur($hdc,0,0,$array)
    Sleep(10)
Next

While 1
    Sleep(1000)
WEnd

Func _exit()
    Exit
EndFunc

[komalo]

thanx man but this draws blur on the screen and i want to be in file

any way i will keep modifying on this script until i make blur the image in the file

[jpam]

saves the effect as jpg or bmp to disk

#include <Prospeed30.au3>

Opt("GUIOnEventMode", 1)

$Gui = GUICreate("blur", 800, 600)
GUISetState()

$hdc = GetHDC()

$image  = LoadFileImage("autoit_builder_wall_800x600.jpg")
$array  = InitFx($image)
$bitmap = CreateImage(800,600)

For $i = 1 To 30
    blur($bitmap,0,0,$array)
Next

;SaveImage(bitmapdata, "path+filename", bmp/jpg, Quality for jpg format)
SaveImage($bitmap, "C:\blurpicture.jpg", 1, 10)  ; save as jpg
;SaveImage($bitmap, "C:\blurpicture.bmp", 0, 10) ; save as bmp

Exit

[rasim]

Hmm...very interesting, example with GDIPlus, technique is to resize the original image to a MUCH SMALLER size, and then resize it to the original size

expandcollapse popup

#include <GDIPlus.au3>

_GDIPlus_Startup()

$file = "c:\runner.jpg"

$ResFile = _ImageResize($file)

_GDIPlus_Shutdown()

Func _ImageResize($sFile, $sReduce = 2)
    Local $hSourceIMG, $iWidth, $iHeight, $hBitmap, $hImage, $hGraphics, $iOutput = @ScriptDir & "\reduced.jpg"
    
    $hSourceIMG = _GDIPlus_ImageLoadFromFile($sFile)
    
    $iWidth = _GDIPlus_ImageGetWidth($hSourceIMG)
    $iHeight = _GDIPlus_ImageGetHeight($hSourceIMG)
    
    $hBitmap = _CreateBMP($iWidth / $sReduce, $iHeight / $sReduce)
    $hImage = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap)
    $hGraphics = _GDIPlus_ImageGetGraphicsContext($hImage)

    _GDIPLus_GraphicsDrawImageRect($hGraphics, $hSourceIMG, 0, 0, $iWidth / $sReduce, $iHeight / $sReduce)
    _GDIPlus_ImageSaveToFile($hImage, $iOutput)

    _WinAPI_DeleteObject($hBitmap)
    _GDIPlus_ImageDispose($hSourceIMG)
    _GDIPlus_ImageDispose($hImage)
    _GDIPlus_GraphicsDispose($hGraphics)
    
    $hSourceIMG = _GDIPlus_ImageLoadFromFile($iOutput)
    
    $hBitmap = _CreateBMP($iWidth, $iHeight)
    $hImage = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap)
    $hGraphics = _GDIPlus_ImageGetGraphicsContext($hImage)
    
    _GDIPLus_GraphicsDrawImageRect($hGraphics, $hSourceIMG, 0, 0, $iWidth, $iHeight)
    _GDIPlus_ImageSaveToFile($hImage, @ScriptDir & "\blur_factor" & $sReduce & ".jpg")
    
    _WinAPI_DeleteObject($hBitmap)
    _GDIPlus_ImageDispose($hSourceIMG)
    _GDIPlus_ImageDispose($hImage)
    _GDIPlus_GraphicsDispose($hGraphics)
    FileDelete($iOutput)
EndFunc   ;==>_ImageResize

Func _CreateBMP($sWidth, $sHeight)
    Local $hWnd = _WinAPI_GetDesktopWindow()
    Local $hDC = _WinAPI_GetDC($hWnd)
    Local $hBMP = _WinAPI_CreateCompatibleBitmap($hDC, $sWidth, $sHeight)
    _WinAPI_ReleaseDC($hWnd, $hDC)
    Return $hBMP
EndFunc   ;==>_CreateBMP

Original:

blur by factor 2

blur by factor 3

blur by factor 4

[komalo]

thank you all

i got it work