Dragging image

[Minikori]

Trying to drag an image around, but I'd like it not to drag from the top left, but from wherever the mouse is on the image. By the way, if your going to copy the code, just replace my image with one of your own that doesn't fit in the GUI.

Code:

#include <GUIConstants.au3>

Opt("MouseCoordMode", 0)

GUICreate("Test", 300, 200)

$Image = GUICtrlCreatePic("C:\Documents and Settings\User\My Documents\My Pictures\EPIX.bmp", 0, 0, 400, 330)
GUICtrlSetCursor($Image, 9)

GUISetState()
While 1
    $msg = GUIGetMsg()
    $Mmsg = GUIGetCursorInfo()
    If $msg = $GUI_EVENT_CLOSE Then
        ExitLoop
    EndIf
    If $Mmsg[4] = $Image Then
        While $Mmsg[2] = 1
            $Mmsg = GUIGetCursorInfo()
            GUICtrlSetPos($Image, $Mmsg[0], $Mmsg[1])
        WEnd
    EndIf
WEnd
Exit

[Vindicator209]

Heres a script I threw together a while ago, this one you can click & hold the image and you can drag it around and let go of it. just replace test.bmp with whatever your using

EDIT: Okay I edited it to drag from the very point you clicked it at

#include <GUIConstants.au3>
#include <Misc.au3>
$Form1 = GUICreate("Pick up", 1000, 900, 0, 0)
$Pic1 = GUICtrlCreatePic("test.bmp", 96, 88, 100, 100)
GUISetState(@SW_SHOW)
While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $Pic1
            _PickUp("Pick up",$Pic1,100,100)
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd
Func _PickUp($z_WinName,$z_control,$z_controlWidth,$z_controlHeight)
    ;Requires #include <Misc.au3>
    $dll = DllOpen("user32.dll")
    $Mpos = MouseGetPos()
    $Wpos = WinGetPos($z_WinName)
    $Cpos = ControlGetPos($z_WinName,"",$z_control)
    $Additional0 = $Mpos[0] - ($Wpos[0] + $Cpos[0]) ;Add the position of the window and the control
    $Additional1 = $Mpos[1] - ($Wpos[1] + $Cpos[1]) ;Then subtract it from the mouse position
    Do
    $Mpos = MouseGetPos()
    $Wpos = WinGetPos($z_WinName)
    $XCpos = $Mpos[0] - $Wpos[0] - $Additional0 ;The Addition vars add the extra pixels from the
    $YCpos = $Mpos[1] - $Wpos[1] - $Additional1 ;mouse's position
    ControlMove($z_WinName,"",$z_control,$XCpos,$YCpos)
    ToolTip($XCpos & " " & $YCpos)
Until Not(_IsPressed(01,$dll))
ToolTip("")
    DllClose($dll)
EndFunc

Edited August 29, 2008 by VindicatorOmega