Unicode with IniWrite ?

[zxzxzx]

Unicode with IniWrite ????

I can't !

This not work.

IniWrite("C:\1.ini", "1", "1", "Đất nước Việt Nam")

Help me please

[PsaltyDS]

Unicode with IniWrite ????

I can't !

This not work.

IniWrite("C:\1.ini", "1", "1", "Đất nước Việt Nam")

Help me please

I don't think the windows convention for INI files include Unicode. You would have to write a custom function that would use Unicode modes in FileOpen() before writing to the file.

[MrCreatoR]

expandcollapse popup

_IniWriteEx("C:\1.ini", "1", "1", "Đất nước Việt Nam", 128)

Func _IniWriteEx($sIniFile, $sSection, $sKey, $sValue, $iUTFMode=0)
    If BitOR($iUTFMode, 16, 32, 64, 128) <> Number(16+32+64+128) Then $iUTFMode = 128
    Local $sReadFile = FileRead($sIniFile)
    Local $hFile = FileOpen($sIniFile, 10+$iUTFMode)
    If $hFile = -1 Then Return IniWrite($sIniFile, $sSection, $sKey, $sValue)
    Local $aFileArr = StringSplit(StringStripCR($sReadFile), @LF)
    
    If @error Then
        If $sReadFile <> "" Then $sReadFile &= @LF
        FileWrite($hFile, $sReadFile & "[" & $sSection & "]" & @LF)
        FileWrite($hFile, $sKey & "=" & $sValue)
        FileClose($hFile)
        Return SetError(0, 0, 1)
    EndIf
    
    Local $sLF = @LF, $aSplitKeyValue, $iValueWasWritten = False
    
    For $i = 1 To $aFileArr[0]
        If $i = $aFileArr[0] Then $sLF = ""
        FileWrite($hFile, $aFileArr[$i] & $sLF)
        
        If $aFileArr[$i] = "[" & $sSection & "]" Then
            For $j = $i+1 To $aFileArr[0]
                If $j = $aFileArr[0] Then $sLF = ""
                
                If Not $iValueWasWritten Then
                    If StringRegExp(StringRegExpReplace($aFileArr[$j], '\s+=', '='), $sKey & '=') Then
                        $aSplitKeyValue = StringSplit($aFileArr[$j], "=")
                        FileWrite($hFile, $aSplitKeyValue[1] & "=" & $sValue & $sLF)
                        $iValueWasWritten = True
                    ElseIf $aFileArr[$j] = "" Then
                        FileWrite($hFile, $sKey & "=" & $sValue & $sLF)
                    ElseIf StringLeft($aFileArr[$j], 1) = "[" Or $j = $aFileArr[0] Then
                        FileWrite($hFile, $aFileArr[$j] & @LF & $sKey & "=" & $sValue & $sLF)
                    Else
                        FileWrite($hFile, $aFileArr[$j] & $sLF)
                    EndIf
                Else
                    FileWrite($hFile, $aFileArr[$j] & $sLF)
                EndIf
            Next
            
            ExitLoop
        ElseIf $i = $aFileArr[0] Then
            FileWrite($hFile, @LF & "[" & $sSection & "]" & @LF)
            FileWrite($hFile, $sKey & "=" & $sValue)
        EndIf
    Next
    
    FileClose($hFile)
    Return SetError(0, 0, 1)
EndFunc

[zxzxzx]

expandcollapse popup

_IniWriteEx("C:\1.ini", "1", "1", "Đất nước Việt Nam", 128)

Func _IniWriteEx($sIniFile, $sSection, $sKey, $sValue, $iUTFMode=0)
    If BitOR($iUTFMode, 16, 32, 64, 128) <> Number(16+32+64+128) Then $iUTFMode = 128
    Local $sReadFile = FileRead($sIniFile)
    Local $hFile = FileOpen($sIniFile, 10+$iUTFMode)
    If $hFile = -1 Then Return IniWrite($sIniFile, $sSection, $sKey, $sValue)
    Local $aFileArr = StringSplit(StringStripCR($sReadFile), @LF)
    
    If @error Then
        If $sReadFile <> "" Then $sReadFile &= @LF
        FileWrite($hFile, $sReadFile & "[" & $sSection & "]" & @LF)
        FileWrite($hFile, $sKey & "=" & $sValue)
        FileClose($hFile)
        Return SetError(0, 0, 1)
    EndIf
    
    Local $sLF = @LF, $aSplitKeyValue, $iValueWasWritten = False
    
    For $i = 1 To $aFileArr[0]
        If $i = $aFileArr[0] Then $sLF = ""
        FileWrite($hFile, $aFileArr[$i] & $sLF)
        
        If $aFileArr[$i] = "[" & $sSection & "]" Then
            For $j = $i+1 To $aFileArr[0]
                If $j = $aFileArr[0] Then $sLF = ""
                
                If Not $iValueWasWritten Then
                    If StringRegExp(StringRegExpReplace($aFileArr[$j], '\s+=', '='), $sKey & '=') Then
                        $aSplitKeyValue = StringSplit($aFileArr[$j], "=")
                        FileWrite($hFile, $aSplitKeyValue[1] & "=" & $sValue & $sLF)
                        $iValueWasWritten = True
                    ElseIf $aFileArr[$j] = "" Then
                        FileWrite($hFile, $sKey & "=" & $sValue & $sLF)
                    ElseIf StringLeft($aFileArr[$j], 1) = "[" Or $j = $aFileArr[0] Then
                        FileWrite($hFile, $aFileArr[$j] & @LF & $sKey & "=" & $sValue & $sLF)
                    Else
                        FileWrite($hFile, $aFileArr[$j] & $sLF)
                    EndIf
                Else
                    FileWrite($hFile, $aFileArr[$j] & $sLF)
                EndIf
            Next
            
            ExitLoop
        ElseIf $i = $aFileArr[0] Then
            FileWrite($hFile, @LF & "[" & $sSection & "]" & @LF)
            FileWrite($hFile, $sKey & "=" & $sValue)
        EndIf
    Next
    
    FileClose($hFile)
    Return SetError(0, 0, 1)
EndFunc

Oh yeah thank MrCreatoR. I'm going to make a function same above function