Color of GUICtrlCreateGroup

[dost0011]

Hi,

I want to change the color of "GUICtrlCreateGroup". Why doesn't it work ?

Thanks !

; Example

$hGUI1 = GUICreate("Rundengong", 400, 400)

GUISetBkColor (0x000000) ; will change background color

; Label Rundengong

$font="Tiranti Solid LET"

GUICtrlCreateLabel ("Rundengong",10,20,400,70)

GUICtrlSetFont (-1,36, 400, 2, $font) ; will display underlined characters

GUICtrlSetColor(-1,0xff0000) ; Red

; Slider für Lautstärke

GUICtrlCreateGroup("Volume control", 20,280,170,105)

GUICtrlSetColor(-1,0xff0000) ; Red --> doesn't work !!!!!!!!!!!!

$iSlider1 = GUICtrlCreateSlider(25, 300, 160, 40)

GUICtrlSetBkColor (-1,0x000000) ; will change background color

$iSlider2 = GUICtrlCreateSlider(25, 340, 160, 40)

GUICtrlSetBkColor (-1,0x000000) ; will change background color

GUICtrlSetLimit($iSlider1, 100, 0)

GUICtrlSetData ($iSlider1, 50)

GUICtrlSetLimit($iSlider2, 100, 0)

GUICtrlSetData ($iSlider2, 50)

GUISetState()

While 1

Sleep(100)

WEnd

[rasim]

A Group controls are always painted in "Windows Classic style".

You can use this trick:

$hGUI1 = GUICreate("Rundengong", 400, 400)

GUISetBkColor (0x000000) ; will change background color

; Label Rundengong
$font="Tiranti Solid LET"
GUICtrlCreateLabel ("Rundengong",10,20,400,70)
GUICtrlSetFont (-1,36, 400, 2, $font) ; will display underlined characters
GUICtrlSetColor(-1,0xff0000) ; Red

; Slider fur Lautstarke
$Group = GUICtrlCreateGroup("Volume control", 20,280,170,105)
DllCall("UxTheme.dll", "int", "SetWindowTheme", "hwnd", GUICtrlGetHandle($Group), "wstr", "", "wstr", "") ;Set classic style for Group control :)
GUICtrlSetColor(-1,0xff0000)

$iSlider1 = GUICtrlCreateSlider(25, 300, 160, 40)
GUICtrlSetBkColor (-1,0x000000) ; will change background color
$iSlider2 = GUICtrlCreateSlider(25, 340, 160, 40)
GUICtrlSetBkColor (-1,0x000000) ; will change background color
GUICtrlSetLimit($iSlider1, 100, 0)
GUICtrlSetData ($iSlider1, 50)
GUICtrlSetLimit($iSlider2, 100, 0)
GUICtrlSetData ($iSlider2, 50)

GUISetState()

While 1
    Sleep(100)
WEnd

[MrCreatoR]

You can switch off the XP theme for the control:

expandcollapse popup

; Example
$hGUI1 = GUICreate("Rundengong", 400, 400)
GUISetBkColor (0x000000) ; will change background color

; Label Rundengong
$font = "Tiranti Solid LET"
GUICtrlCreateLabel ("Rundengong",10,20,400,70)
GUICtrlSetFont (-1,36, 400, 2, $font) ; will display underlined characters
GUICtrlSetColor(-1,0xff0000) ; Red

$iOldTheme = _SetThemeAppProperties(-1)

; Slider fur Lautstarke
GUICtrlCreateGroup("Volume control", 20,280,170,105)
GUICtrlSetColor(-1,0xff0000) ; Red --> doesn't work !!!!!!!!!!!!

_SetThemeAppProperties($iOldTheme)

$iSlider1 = GUICtrlCreateSlider(25, 300, 160, 40)
GUICtrlSetBkColor (-1,0x000000) ; will change background color
$iSlider2 = GUICtrlCreateSlider(25, 340, 160, 40)
GUICtrlSetBkColor (-1,0x000000) ; will change background color
GUICtrlSetLimit($iSlider1, 100, 0)
GUICtrlSetData ($iSlider1, 50)
GUICtrlSetLimit($iSlider2, 100, 0)
GUICtrlSetData ($iSlider2, 50)
GUISetState()

While GUIGetMsg() <> -3
WEnd

Func _SetThemeAppProperties($iTheme = -1)
    If Not StringInStr(@OSTYPE, "WIN32_NT") Then Return 0
    
    Switch $iTheme
        Case -1
            Local $aOld_ThemeAppProperties = DllCall("Uxtheme.dll", "int", "GetThemeAppProperties")
            DllCall("Uxtheme.dll", "none", "SetThemeAppProperties", "int", 0)
            
            Return $aOld_ThemeAppProperties[0]
        Case Else
            DllCall("Uxtheme.dll", "none", "SetThemeAppProperties", "int", $iTheme)
    EndSwitch
EndFunc