How to SetScrollPos for ListView?

[MrCreatoR]

Hi,

I am trying to make my app "remember" the last scroll position in ListView control.

I thought that SetScrollPos from User32.dll can help me with that, but any action (in LV control) after the scroll will return the scroll bar to the top, and the items are not visible for a while.

Here is my example, i found a way using GUICtrlSendMsg($ListView, $WM_VSCROLL, $SB_LINEDOWN, 0), but it's slowing down the startup, i need to use loop for it to scroll every line (see commented lines)...

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <ScrollBarConstants.au3>

$iLast_ScrollPos = IniRead("Test.ini", "Scroll", "VPos", 0)

$GUI = GUICreate("Test Script", 300, 200)

$ListView = GUICtrlCreateListView("Col          ", 20, 20, 260, 160)
$hListView = GUICtrlGetHandle($ListView)

For $i = 1 To 80
    GUICtrlCreateListViewItem("Item " & $i, $ListView)
Next

DllCall("user32.dll", "int", "SetScrollPos", "hwnd", $hListView, "int", $SB_VERT, "int", $iLast_ScrollPos, "int", True)

;~ For $i = 1 To $iLast_ScrollPos
;~  GUICtrlSendMsg($ListView, $WM_VSCROLL, $SB_LINEDOWN, 0)
;~ Next

GUISetState(@SW_SHOW, $GUI)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            $aGetScrollPos = DllCall("user32.dll", "int", "GetScrollPos", "hwnd", $hListView, "int", $SB_VERT)
            
            IniWrite("Test.ini", "Scroll", "VPos", $aGetScrollPos[0])
            
            Exit
    EndSwitch
WEnd

[rasim]

MrCreatoR

Hi friend! I think this be easy:

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>

$iLastPos = IniRead("Test.ini", "Scroll", "VPos", 0)

$GUI = GUICreate("Test Script", 300, 200)

$ListView = GUICtrlCreateListView("Col          ", 20, 20, 260, 160)
$hListView = GUICtrlGetHandle($ListView)

For $i = 1 To 80
    GUICtrlCreateListViewItem("Item " & $i, $ListView)
Next

GUISetState(@SW_SHOW, $GUI)

_GUICtrlListView_EnsureVisible($hListView, $iLastPos + 8)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            IniWrite("Test.ini", "Scroll", "VPos", _GUICtrlListView_GetTopIndex($hListView))
            Exit
    EndSwitch
WEnd

[MrCreatoR]

Thanks rasim! >_<

But it's good only for vertical scrollbar, but what we can do with the horizontal one?

expandcollapse popup

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <ListViewConstants.au3>
#include <ScrollBarConstants.au3>
;

$iLast_ScrollHPos = IniRead("Test.ini", "Scroll", "HPos", 6)
$iLast_ScrollVPos = IniRead("Test.ini", "Scroll", "VPos", 19)

$GUI = GUICreate("Remember Scroll Position Demo", 300, 200)

$ListView = GUICtrlCreateListView("Col", 20, 20, 260, 160)
$hListView = GUICtrlGetHandle($ListView)

GUICtrlSendMsg($ListView, $LVM_SETCOLUMNWIDTH, 0, 400)

For $i = 1 To 80
    GUICtrlCreateListViewItem("Item " & $i, $ListView)
Next

;~ DllCall("user32.dll", "int", "SetScrollPos", "hwnd", $hListView, "int", $SB_HORZ, "int", $iLast_ScrollHPos, "int", True)
;~ DllCall("user32.dll", "int", "SetScrollPos", "hwnd", $hListView, "int", $SB_VERT, "int", $iLast_ScrollVPos, "int", True)

For $i = 1 To $iLast_ScrollHPos
    GUICtrlSendMsg($ListView, $WM_HSCROLL, $SB_LINERIGHT, 0)
    ;DllCall("user32.dll", "int", "SendMessage", "hwnd", $hListView, "int", $WM_HSCROLL, "int", $SB_LINERIGHT, "int", 0)
Next

For $i = 1 To $iLast_ScrollVPos
    GUICtrlSendMsg($ListView, $WM_VSCROLL, $SB_LINEDOWN, 0)
    ;DllCall("user32.dll", "int", "SendMessage", "hwnd", $hListView, "int", $WM_VSCROLL, "int", $SB_LINEDOWN, "int", 0)
Next

GUISetState(@SW_SHOW, $GUI)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            $aGetScrollHPos = DllCall("user32.dll", "int", "GetScrollPos", "hwnd", $hListView, "int", $SB_HORZ)
            $aGetScrollVPos = DllCall("user32.dll", "int", "GetScrollPos", "hwnd", $hListView, "int", $SB_VERT)
            
            IniWrite("Test.ini", "Scroll", "HPos", Int($aGetScrollHPos[0] / 5))
            IniWrite("Test.ini", "Scroll", "VPos", $aGetScrollVPos[0])
            
            Exit
    EndSwitch
WEnd

Why the «SetScrollPos» doesn't work?

Edited October 3, 2008 by MrCreatoR

[rasim]

MrCreatoR

Why the «SetScrollPos» doesn't work?

Hmm...

MSDN

Note. The SetScrollPos function is provided for backward compatibility. New applications should use the SetScrollInfo function.

[MrCreatoR]

Hmm...

I read that thanks... so, it should work, doesn't? Otherwise it is not backward compatible

[rasim]

MrCreatoR

You know, i searched in the Google and seems your solution is correct. Anyway i saw examples like your

For $i = 1 To $iLast_ScrollVPos
    GUICtrlSendMsg($ListView, $WM_VSCROLL, $SB_LINEDOWN, 0)
Next