is it available? FileGetOnlyName()

[SmOke_N]

$explorer = "C:\WINDOWS\explorer.exe"
ConsoleWrite($explorer&@CRLF&"FileName:  "&getFileName($explorer)&@CRLF&"ParentDir: "&getParentDir($explorer)&@CRLF&"Extension: "&getExtension($explorer)&@CRLF)

Func getFileName($fpath)
    Return StringMid($fpath,StringInStr($fpath,"\",0,-1)+1)
EndFunc

Func getParentDir($fpath)
    Return StringMid($fpath,1,StringInStr($fpath,"\",0,-1))
EndFunc

Func getExtension($fpath)
    Return StringMid($fpath,StringInStr($fpath,".",0,-1)+1)
EndFunc

another way

That's just a sloooooooooooow way of doing a _PathSplit().

[bluelamp]

ahhhhm... look at file.au3 in the includedirectory.. i don´t think this is faster, it uses the same functions

expandcollapse popup

Func _PathSplit($szPath, ByRef $szDrive, ByRef $szDir, ByRef $szFName, ByRef $szExt)
    ; Set local strings to null (We use local strings in case one of the arguments is the same variable)
    Local $drive = ""
    Local $dir = ""
    Local $fname = ""
    Local $ext = ""
    Local $pos

    ; Create an array which will be filled and returned later
    Local $array[5]
    $array[0] = $szPath; $szPath can get destroyed, so it needs set now

    ; Get drive letter if present (Can be a UNC server)
    If StringMid($szPath, 2, 1) = ":" Then
        $drive = StringLeft($szPath, 2)
        $szPath = StringTrimLeft($szPath, 2)
    ElseIf StringLeft($szPath, 2) = "\\" Then
        $szPath = StringTrimLeft($szPath, 2) ; Trim the \\
        $pos = StringInStr($szPath, "\")
        If $pos = 0 Then $pos = StringInStr($szPath, "/")
        If $pos = 0 Then
            $drive = "\\" & $szPath; Prepend the \\ we stripped earlier
            $szPath = ""; Set to null because the whole path was just the UNC server name
        Else
            $drive = "\\" & StringLeft($szPath, $pos - 1) ; Prepend the \\ we stripped earlier
            $szPath = StringTrimLeft($szPath, $pos - 1)
        EndIf
    EndIf

    ; Set the directory and file name if present
    Local $nPosForward = StringInStr($szPath, "/", 0, -1)
    Local $nPosBackward = StringInStr($szPath, "\", 0, -1)
    If $nPosForward >= $nPosBackward Then
        $pos = $nPosForward
    Else
        $pos = $nPosBackward
    EndIf
    $dir = StringLeft($szPath, $pos)
    $fname = StringRight($szPath, StringLen($szPath) - $pos)

    ; If $szDir wasn't set, then the whole path must just be a file, so set the filename
    If StringLen($dir) = 0 Then $fname = $szPath

    $pos = StringInStr($fname, ".", 0, -1)
    If $pos Then
        $ext = StringRight($fname, StringLen($fname) - ($pos - 1))
        $fname = StringLeft($fname, $pos - 1)
    EndIf

    ; Set the strings and array to what we found
    $szDrive = $drive
    $szDir = $dir
    $szFName = $fname
    $szExt = $ext
    $array[1] = $drive
    $array[2] = $dir
    $array[3] = $fname
    $array[4] = $ext
    Return $array
EndFunc   ;==>_PathSplit

[SmOke_N]

I used _PathSplit(), I meant to Say StringRegExp's ... however, now that we are on the subject... _PathSplit() does do much more and has been tested to be proficient.

I have my own _PathSplit() function using nothing but RegEx that's much faster than that even ... but it's always safe to use something that's been used and trusted over the years.

[bluelamp]

I used _PathSplit(), I meant to Say StringRegExp's ... however, now that we are on the subject... _PathSplit() does do much more and has been tested to be proficient.

It does things that sometimes aren´t needed

I have my own _PathSplit() function using nothing but RegEx that's much faster than that even ... but it's always safe to use something that's been used and trusted over the years.

Cdma1X asked for alternatives, I gave him one

[Cdma1X]

I have my own _PathSplit() function using nothing but RegEx that's much faster than that even ... but it's always safe to use something that's been used and trusted over the years.

SmOke_N, can i see your function?

[SmOke_N]

SmOke_N, can i see your function?

Func _SplitPath($s_path, ByRef $s_drive, ByRef $s_dir, ByRef $s_fname, ByRef $s_ext)
    If $s_path = "" Or StringInStr($s_path, '<>"|?*') Then Return SetError(1, 0, 0)
    
    Local $a_split = StringRegExp($s_path, "^(\w*:*)([\w\W]*[\\/]+)([\w\W]*)(\.[\w\W]*)\z", 1)
    
    If @error Then
        $a_split = StringRegExp($s_path, "^(\w*:*)([\w\W]*[\\/]+)([\w\W]*)(\.*[\w\W]*)\z", 1)
        If @error Then
            $a_split = StringRegExp($s_path, "^(\w*:*)\z", 1)
            If @error Then Return SetError(2, 0, 0)
        EndIf
    EndIf
    
    If UBound($a_split) = 1 Then
        $s_drive = $a_split[0]
        $s_dir = ""
        $s_fname = ""
        $s_ext = ""
    Else
        $s_drive = $a_split[0]
        $s_dir = $a_split[1]
        $s_fname = $a_split[2]
        $s_ext = $a_split[3]
    EndIf
    
    Local $avArray[5] = [$s_path, $s_drive, $s_dir, $s_fname, $s_ext]
    Return $avArray
EndFunc

Edit:

Removed emoticons

Edited October 7, 2008 by SmOke_N

[Cdma1X]

Thanks smOke_N, bluelamp Edited October 7, 2008 by Cdma1X

[MrCreatoR]

I have one of my own to: _PathSplitByRegExp()

Edited October 7, 2008 by MrCreatoR

[SmOke_N]

I have one of my own to: _PathSplitByRegExp()

That's funny, I forgot about that one ...