Creating and closing a window?

[flxfxp]

Hi,

I would like to spawn a new window from a button (a about window)

I have the following code:

expandcollapse popup

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button1
                   ;will fill later
            Exit
        
        Case $Button2
            $AboutForm = GUICreate("About", 360, 194, 193, 125)
                $ButtonClose = GUICtrlCreateButton("Close", 128, 144, 75, 25, 0)
                $Label1 = GUICtrlCreateLabel("Test", 112, 16, 131, 17)
                $Label2 = GUICtrlCreateLabel("Test", 112, 32, 77, 17)
                $Label3 = GUICtrlCreateLabel("Test:", 112, 48, 131, 17)
                $Label4 = GUICtrlCreateLabel("Test", 104, 80, 360, 170)
                GUISetState(@SW_SHOW)

                    While 1
                        $nMsg = GUIGetMsg()
                        Switch $nMsg
                            Case $GUI_EVENT_CLOSE
                                GUISwitch($AboutForm)
                                GUIDelete()
                                GUISwitch($gui)
                                                        Case $Button3
                                                          ;close about window
                                               GUISwitch($AboutForm)
                                GUIDelete()
                                GUISwitch($gui)
                        EndSwitch
                    WEnd

        Case $Button3
            Exit
    EndSwitch
WEnd

It closes the about window, but the controls on the original window stop working!

How do I fix this?

Thank you in advance,

FLX

Edited December 5, 2008 by flxfxp

[MrCreatoR]

Your GUI is been deleted, but what about exiting the second loop?

expandcollapse popup

#include <GuiConstantsEx.au3>

$GUI = GUICreate("Test Script", 300, 200)

$Button1 = GUICtrlCreateButton("Button1", 20, 20, 60, 20)
$Button2 = GUICtrlCreateButton("About", 20, 60, 60, 20)
$Button3 = GUICtrlCreateButton("Button2", 20, 100, 60, 20)

GUISetState(@SW_SHOW, $GUI)

While 1
    $nMsg = GUIGetMsg()
    
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button1
                   ;will fill later
            Exit
        
        Case $Button2
            GUISetState(@SW_DISABLE, $GUI)
            
            $AboutForm = GUICreate("About", 360, 194, 193, 125, -1, -1, $GUI)
            $ButtonClose = GUICtrlCreateButton("Close", 128, 144, 75, 25, 0)
            $Label1 = GUICtrlCreateLabel("Test", 112, 16, 131, 17)
            $Label2 = GUICtrlCreateLabel("Test", 112, 32, 77, 17)
            $Label3 = GUICtrlCreateLabel("Test:", 112, 48, 131, 17)
            $Label4 = GUICtrlCreateLabel("Test", 104, 80, 360, 170)
            
            GUISetState(@SW_SHOW)
            
            While 1
                $nMsg = GUIGetMsg()
                Switch $nMsg
                    Case $GUI_EVENT_CLOSE, $Button3
                        ExitLoop
                EndSwitch
            WEnd
            
            GUISetState(@SW_ENABLE, $GUI)
            GUIDelete($AboutForm)
        Case $Button3
            Exit
    EndSwitch
WEnd

P.S

Also you might want to check the Cool "About" Box example from my signature .

Edited December 5, 2008 by MrCreatoR

[flxfxp]

Thanks MrCreatoR! I owe you one!

However, the "Close" button in the about window doesnt show up until I hover over it, do you know how to fix this?

Thanks,

FLX

[MrCreatoR]

Thanks MrCreatoR! I owe you one!

However, the "Close" button in the about window doesnt show up until I hover over it, do you know how to fix this?

Thanks,

FLX

It's because the label is covering the button, replace in $Label4 the last parameter (170) to 20 for example.

P.S

To make the button actualy close the child GUI, just replace Case $GUI_EVENT_CLOSE, $Button3 with Case $GUI_EVENT_CLOSE, $ButtonClose.

[flxfxp]

I'm once again baffled by my own stupidity. I did figure out the button3/buttonclose problem earlier, but didn't consider the label size. Thanks for you excellent and swift help!

Regards,

FLX