WinActive/Activate bug?

[MrCreatoR]

Hi,

I am not sure if it's a bug or not, so here is what i got:

GUICreate("Test GUI", 300, 200)
;GUISetState(@SW_HIDE)

$sTitle = "Test GUI"
WinActivate($sTitle)

$IsActive_1 = (WinActive($sTitle) = 1)
$IsActive_2 = (BitAND(WinGetState($sTitle), 8) = 8)

ConsoleWrite("Win Is Visible: " & (BitAND(WinGetState($sTitle), 2) = 2) & @CRLF)
ConsoleWrite("Win Is Active (WinActive Method): " & $IsActive_1 & @CRLF)
ConsoleWrite("Win Is Active (WinGetState Method): " & $IsActive_2 & @CRLF)

As you can see in this test, the hidden window is "activated" (not really), and then when we trying to see if it's active we get True, but the window is not visible, how is that can be possible?

I first thought that the problem is in the WinActive() function, but then i checked with WinGetState(), and it's returning the same, window is active. So i gues the problem is in the WinActivate() function, wich is set the state for the window as Active (8) even if it's not visible.

P.S

Just wanted to post here and get some thoughts about it from others, before i submit a Bug Report (if it's a really a bug of course)...

[SmOke_N]

I think active simply means it's brought to the top of the z-order. Hidden windows can be brought to the top even though they are not visible.

$h_main = GUICreate("Test GUI", 300, 200)
$h_other = GUICreate("Look at my title bar when other window is active")
GUISetState(@SW_SHOW, $h_other)

Sleep(3000)
WinActivate($h_main)

$IsActive_1 = (WinActive($h_main) = 1)
$IsActive_2 = (BitAND(WinGetState($h_main), 8) = 8)

ConsoleWrite("Win Is Visible: " & (BitAND(WinGetState($h_main), 2) = 2) & @CRLF)
ConsoleWrite("Win Is Active (WinActive Method): " & $IsActive_1 & @CRLF)
ConsoleWrite("Win Is Active (WinGetState Method): " & $IsActive_2 & @CRLF)

While 1
    $a_msg = GUIGetMsg(1)
    Switch $a_msg[1]
        Case $h_other
            Switch $a_msg[0]
                Case -3
                    Exit
            EndSwitch
    EndSwitch
WEnd

That should show you that when you activate the hidden window, that the window that was active is no longer active (when you look at the title bar it greys out on mine for non-active windows).

[MrCreatoR]

Yes it's brought to the top, but perhaps WinActivate() function should work only for visible windows, and leave the "z-order handling" to WinSetState() function?

Or at least the docs must be update (warn about non visible windows).

P.S

Also in the help file for WinActivate() we can see some reference about the @extended, but no code explenation, here is a few tests that will show them:

If Not ProcessExists("Notepad.exe") Then
    WinActivate("[CLASS:Notepad]")
    ConsoleWrite("@extended = " & @extended & @CRLF) ;@extended = 0, window not exists, therefore it's can not be active :)
    
    Run(@WindowsDir & "\Notepad.exe")
EndIf

WinWait("[CLASS:Notepad]")

WinActivate("[CLASS:Notepad]")
ConsoleWrite("@extended = " & @extended & @CRLF) ;@extended = 1, window was *active*

WinSetState("[CLASS:Notepad]", "", @SW_MINIMIZE)

WinActivate("[CLASS:Notepad]")
ConsoleWrite("@extended = " & @extended & @CRLF) ;@extended = 2, window was *not* active (minimized)