How to count repeated number of words in text

[lsakizada]

hi,

Any one can help count repeated number of words in a text?

For example: my text is

Hello there? anybothy is out there?

Hello there? anybothy is out there?

Hello there? anybothy is out there?

Hello there? anybothy is out there?

The keyword search is:

there

The answer should be: 8

Here is my program, i need to fill up the case "Start" with appropriate logic.

#include <GUIConstants.au3>
#include<Array.au3>
$MainGui = GuiCreate('Count number of objects', 600, 400)
$edit = GUICtrlCreateEdit('', 10, 10, 580, 330)
$start = GUICtrlCreateButton('Find', 10, 360, 60, 30)
$Sclear2 = GUICtrlCreateButton('Clear', 80, 360, 60, 30)
global $InputWord = GuiCtrlCreateInput("",150,360,440,20)
GUISetState()

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Sclear2
            GUICtrlSetData($edit,"")
        Case  $start
 
        
    EndSwitch
WEnd

[KaFu]

expandcollapse popup

#include<GUIConstants.au3>

$var = "Hello there? anybothy is out there?" & @CRLF _
         & "Hello there? anybothy is out there?" & @CRLF _
         & "Hello there? anybothy is out there?" & @CRLF _
         & "Hello there? anybothy is out there?"

$MainGui = GUICreate('Count number of objects', 600, 400)
$edit = GUICtrlCreateEdit('', 10, 10, 580, 330)
$start = GUICtrlCreateButton('Find', 10, 360, 60, 30)
$Sclear2 = GUICtrlCreateButton('Clear', 80, 360, 60, 30)
Global $InputWord = GUICtrlCreateInput("", 150, 360, 440, 20)

GUICtrlSetData($edit, $var)

GUISetState()

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Sclear2
            GUICtrlSetData($edit, "")
        Case $start
            $string_found = 0
            $string_position = StringInStr(GUICtrlRead($edit), GUICtrlRead($InputWord), 0, 1)

            While $string_position > 0
                $string_found += 1
                $string_position = StringInStr(GUICtrlRead($edit), GUICtrlRead($InputWord), 0, 1, $string_position + 1)
            WEnd

            MsgBox(0, "String count result", $string_found)
           
    EndSwitch
WEnd

Edited January 8, 2009 by KaFu

[lsakizada]

Hi KafU, This looks working well!

I will test it more to figure out whether some cases are not covered...but I would not expected more then that.

great! and thank you very much for the help. regards!

expandcollapse popup

#include<GUIConstants.au3>

$var = "Hello there? anybothy is out there?" & @CRLF _
         & "Hello there? anybothy is out there?" & @CRLF _
         & "Hello there? anybothy is out there?" & @CRLF _
         & "Hello there? anybothy is out there?"

$MainGui = GUICreate('Count number of objects', 600, 400)
$edit = GUICtrlCreateEdit('', 10, 10, 580, 330)
$start = GUICtrlCreateButton('Find', 10, 360, 60, 30)
$Sclear2 = GUICtrlCreateButton('Clear', 80, 360, 60, 30)
Global $InputWord = GUICtrlCreateInput("", 150, 360, 440, 20)

GUICtrlSetData($edit, $var)

GUISetState()

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Sclear2
            GUICtrlSetData($edit, "")
        Case $start
            $string_found = 0
            $string_position = StringInStr(GUICtrlRead($edit), GUICtrlRead($InputWord), 0, 1)

            While $string_position > 0
                $string_found += 1
                $string_position = StringInStr(GUICtrlRead($edit), GUICtrlRead($InputWord), 0, 1, $string_position + 1)
            WEnd

            MsgBox(0, "String count result", $string_found)
           
    EndSwitch
WEnd

[MrCreatoR]

No need in loops, since we can use @extended that is returned by StringReplace():

#include <GUIConstants.au3>

$Var = _
    "Hello there? anybothy is out there?" & @CRLF & _
    "Hello there? anybothy is out there?" & @CRLF & _
    "Hello there? anybothy is out there?" & @CRLF & _
    "Hello there? anybothy is out there?"

$MainGui = GUICreate('Count number of objects', 600, 400)
$Edit = GUICtrlCreateEdit($Var, 10, 10, 580, 330)
$Start = GUICtrlCreateButton('Find', 10, 360, 60, 30)
$Sclear2 = GUICtrlCreateButton('Clear', 80, 360, 60, 30)
Global $InputWord = GUICtrlCreateInput("there", 150, 360, 440, 20)

GUISetState()

While 1
    $nMsg = GUIGetMsg()

    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Sclear2
            GUICtrlSetData($Edit, "")
        Case $Start
            StringReplace(GUICtrlRead($Edit), GUICtrlRead($InputWord), "")
            MsgBox(0, "Results", "String count result: " & @extended, 0, $MainGui)
    EndSwitch
WEnd

Edited January 8, 2009 by MrCreatoR

[KaFu]

Yeah, thought that i saw this somewhere, but couldn't remember that it's in stringreplace , nice and more simple solution...