Checkbox to activate an input

[houseonfire]

I'm trying to make a checkbox activate an input box when the checkbox is checked, and then when it is unchecked, I want to box to be inactive.

I've been trying this part of my script off and on for a few days, and can't seem to get it. Can someone help me out please?

$f = 1
Case $Checkbox0
    If $checkbox0 = 1 Then
        $f = 2
    If $f =2 Then
        GUICtrlSetState ($id1, $GUI_ENABLE)
    EndIf
EndIf

[Valuater]

Maybe...

Case $Checkbox0
    If _IsChecked($Checkbox0) Then
        GUICtrlSetState ($id1, $GUI_DISABLE)
    Else
        GUICtrlSetState ($id1, $GUI_ENABLE)
    EndIf
EndIf

Func _IsChecked($control)
    Return BitAnd(GUICtrlRead($control),$GUI_CHECKED) = $GUI_CHECKED
EndFunc

8)

[Melba23]

houseonfire,

Try this:

#include <GUIConstantsEx.au3>

GUICreate("Test", 300, 300)

$hCheck = GUICtrlCreateCheckbox("Toggle Input", 10, 10, 100, 20)
$hInput = GUICtrlCreateInput("Input here", 10, 50, 100, 20)
    GUICtrlSetState(-1, $GUI_DISABLE)

GUISetState()

$iFlag = 0

While 1
    
    If GUIGetMsg() = -3 Then Exit
; Interaction checkbox and input
        If BitAnd(GUICtrlRead($hCheck),$GUI_CHECKED) <>  $iFlag Then
            $iFlag = Not $iFlag
            If $iFlag = $GUI_UNCHECKED Then
                GUICtrlSetState($hInput, $GUI_ENABLE)
            Else
                GUICtrlSetState($hInput, $GUI_DISABLE)
            EndIf
        EndIf
WEnd

M23

[KaFu]

Use WM_COMMAND to switch states of a control. Advantage, this will also work if your loop is busy (try and add sleep(5000) to the main loop).

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Local $checkCN, $msg
GUICreate("My GUI Checkbox"); will create a dialog box that when displayed is centered

$checkCN = GUICtrlCreateCheckbox("Input Enabled", 10, 10, 120, 20)

$input = GUICtrlCreateInput("", 10, 40, 120, 20)
GUICtrlSetState(-1, $GUI_DISABLE)

GUIRegisterMsg($WM_COMMAND, "My_WM_COMMAND")

GUISetState(); will display an  dialog box with 1 checkbox

; Run the GUI until the dialog is closed
While 1
    $msg = GUIGetMsg()

    If $msg = $GUI_EVENT_CLOSE Then ExitLoop
WEnd

Func My_WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
    Local $iIDFrom = BitAND($wParam, 0xFFFF);LoWord
    Local $iCode = BitShift($wParam, 16);HiWord

    Switch $iIDFrom
        Case $checkCN
            If GUICtrlRead($checkCN) = 1 Then
                GUICtrlSetState($input, $GUI_ENABLE)
            Else
                GUICtrlSetState($input, $GUI_DISABLE)
            EndIf
    EndSwitch
EndFunc

Edited February 5, 2009 by KaFu

[houseonfire]

Thank you for the help everyone.

Its working.