12 replies to this topic

[RazerM]

I have made an RC4 Text Encryption UDF. I know RC4 isn't the strongest encryption but anyway here it is:

AutoIt        expandcollapse  popup

;===============================================================================
;
; Function Name:   _StringEncryptRC4
; Description::    Encrypts text using RC4 Encryption
; Parameter(s):    $text, $encryptkey
; Requirement(s):  AutoIt
; Return Value(s): Encrypted String
; Author(s):       RazerM
;
;===============================================================================
;
Func _StringEncryptRC4($text, $encryptkey)
    Local $sbox[256]
    Local $key[256]
    Local $temp
    Local $a
    Local $i
    Local $j
    Local $k
    Local $cipherby
    Local $cipher
    
    $i = 0
    $j = 0
    
    __RC4Initialize($encryptkey, $key, $sbox)
    
    For $a = 1 To StringLen($text)
        $i = Mod(($i + 1),256)
        $j = Mod(($j + $sbox[$i]),256)
        $temp = $sbox[$i]
        $sbox[$i] = $sbox[$j]
        $sbox[$j] = $temp
        
        $k = $sbox[Mod(($sbox[$i] + $sbox[$j]),256)]
        
        $cipherby = BitXOR(Asc(StringMid($text, $a, 1)),$k)
        $cipher = $cipher & Chr($cipherby)
    Next
    
    Return _StringToHexEx($cipher)
EndFunc   ;==>_StringEncryptRC4

;===============================================================================
;
; Function Name:   _StringDecryptRC4
; Description::    Decrypts text using RC4 Encryption
; Parameter(s):    $text, $encryptkey
; Requirement(s):  AutoIt
; Return Value(s): Decrypted String
; Author(s):       RazerM
; Note(s):         RC4 uses the same algorithm to encrypt and decrypt
;
;===============================================================================
;

Func _StringDecryptRC4($text, $encryptkey)
    Local $sbox[256]
    Local $key[256]
    Local $temp
    Local $a
    Local $i
    Local $j
    Local $k
    Local $cipherby
    Local $cipher
    $text = _HexToStringEx($text)
    
    $i = 0
    $j = 0
    
    __RC4Initialize($encryptkey, $key, $sbox)
    
    For $a = 1 To StringLen($text)
        $i = Mod(($i + 1),256)
        $j = Mod(($j + $sbox[$i]),256)
        $temp = $sbox[$i]
        $sbox[$i] = $sbox[$j]
        $sbox[$j] = $temp
        
        $k = $sbox[Mod(($sbox[$i] + $sbox[$j]),256)]
        
        $cipherby = BitXOR(Asc(StringMid($text, $a, 1)),$k)
        $cipher = $cipher & Chr($cipherby)
    Next
    Return $cipher
EndFunc   ;==>_StringDecryptRC4


; Helper function
Func __RC4Initialize($strPwd, ByRef $key, ByRef $sbox)
    Dim $tempSwap
    Dim $a
    Dim $b
    
    $intLength = StringLen($strPwd)
    For $a = 0 To 255
        $key[$a] = Asc(StringMid($strPwd, (Mod($a,$intLength))+1, 1))
        $sbox[$a] = $a
    Next
    
    $b = 0
    For $a = 0 To 255
        $b = Mod($b + $sbox[$a] + $key[$a],256)
        $tempSwap = $sbox[$a]
        $sbox[$a] = $sbox[$b]
        $sbox[$b] = $tempSwap
    Next
EndFunc   ;==>__RC4Initialize

Func _HexToStringEx($strHex)
    Return BinaryToString("0x" & $strHex)
EndFunc   ;==>_HexToStringEx

Func _StringToHexEx($strChar)
    Return Hex(StringToBinary($strChar))
EndFunc   ;==>_StringToHexEx ƒo݊÷ Øw«z+-…ç±jjey«­¢+؍¥¹±Õ‘”€™ÅÕ½ÐíIй…Ô̙ÅÕ½Ðì(˜ŒÀÌØíѕáЀô%¹ÁÕÑ    ½à ™ÅÕ½ÐíQ•áЙÅÕ½Ð찀™ÅÕ½Ðí¹Ñ•ÈÑ•áЁѼ•¹ÉåÁЙÅÕ½Ðì¤(˜ŒÀÌØ핹ÉåÁÑ­•ä€ô%¹ÁÕÑ ½à ™ÅÕ½Ðí-•ä™ÅÕ½Ð찀™ÅÕ½Ðí¹Ñ•È­•äÑ¼•¹ÉåÁЁѡ”Ñ•áЙÅÕ½Ðì¤(˜ŒÀÌØíɌЀôQ¥µ•É%¹¥Ð ¤(˜ŒÀÌØ핹ÉåÁѕ€ô}MÑÉ¥¹¹ÉåÁÑIÐ ˜ŒÀÌØíѕáа€˜ŒÀÌØ핹ÉåÁÑ­•ä¤)5͝    ½à À°™ÅÕ½Ðí¹ÉåÁÑ¥½¸Q½½¬è™ÅÕ½Ð찁Q¥µ•É¥™˜ ˜ŒÀÌØíɌФ€™…µÀ쀙ÅÕ½Ð쁵̙ÅÕ½Ðì¤)5͝    ½à À°™ÅÕ½Ðí¹ÉåÁѕ™ÅÕ½Ð찙ÅÕ½Ðí¹ÉåÁѕÑ•áЁ¥Ì耙ÅÕ½Ð쀙…µÀ쀘ŒÀÌØ핹ÉåÁѕ¤)5͝   ½à À°™ÅÕ½Ð핍ÉåÁѕ™ÅÕ½Ð찙ÅÕ½Ð핍ÉåÁѕÑ•áЁ¥Ì耙ÅÕ½Ð쀙…µÀì}MÑÉ¥¹•ÉåÁÑIÐ ˜ŒÀÌØ핹ÉåÁѕ°€˜ŒÀÌØ핹ÉåÁÑ­•ä¤¤((

Edited by RazerM, 04 June 2007 - 03:36 PM.

[dash007]

Very nice and fast RazorM!

[RazerM]

Thanks. It is about half the time of the built in _StringEncrypt function.

[vikingnor]

really nice!

[M a k a v e l !]

Nicely done RazerM.

[SmOke_N]

Very nice indeed, nice job Razer.

Edit:
A suggestion though, since you're not using unique vars, is to keep them in a local scope.

Edited by SmOke_N, 12 August 2006 - 05:52 PM.

[RazerM]

I updated it. Thanks SmOke_N

[erifash]

Faster string->hex functions:

Func _HexToStringEX($strHex)
   Return BinaryString("0x" & $strHex)
EndFunc

Func _StringToHexEx($strChar)
   Return Hex(BinaryString($strChar))
EndFunc

[RazerM]

I would never have thought of doing that! Im implementing it now

[lyledg]

Hey Razerm

It seems this script no longer works with the latest released version of the Autoit??

   Return [b]BinaryString[/b]("0x" & $strHex)

The BinaryString function no longer works??

Any ideas?

[RazerM]

I'll update in a few minutes.

Edit: Updated

Edited by RazerM, 04 June 2007 - 03:37 PM.

[AngelSL]

Gonna make a GUI for this as well.

[RazerM]

It doesn't need one, but if you do, don't post it in this topic.