[Solved]StringRegExp

[Realm 17]

I have been playing with this for 4 hours now, so sorry to bug over something that is probably minor. I'm pulling this text off a website via _IEBodyReadText, there is much more text, but this is a clip as it appears, of the area i need the string from

Who would you like to help?

name1, name2, Name3, 4name, 5name, NaME6, na7me

LostinTranslation

What I need is: name1, name2, Name3, 4name, 5name, NaME6, na7me

This is my StringRegExp, as I thought it would work, but noob as I am, I'm hoping the problem is here:

$rhelpers = StringRegExp($rText, 'help?(.*[A-z0-9\,]?)LostInTranslation', 1, 1)

Thanks ahead of time for any help!

edit: $rText is the string pulled from _IEBodyReadText

Edited May 28, 2010 by Realm

[UEZ 1,077]

If the text above name1, name2, ... is everytime the same you can try this:

$String = "Who would you like to help?" & @CRLF & _
         "name1, name2, Name3, 4name, 5name, NaME6, na7me" & @CRLF & @CRLF & _
         "LostinTranslation"

$aRegExp = StringRegExp($String, "Who would you like to help\?\r\n(.*)\r\n*.", 1)
If IsArray($aRegExp) Then ConsoleWrite($aRegExp[0] & @CRLF)

BR,

UEZ

[GEOSoft 64]

Lets make this multiple choice;

#include<array.au3>
$aRegExp = StringRegExp($String, "(\w+?)(?:,|\z|\v)+", 3)
If NOT @Error Then
    GUICtrlSetData($hSomeComboBox, _ArrayToString($aRegExp))
EndIf

[Realm 17]

Thanks to both of your suggestions.

@UEZ, your example did not work for some reason, don't know if there is not a cursor return after 'help?' or what it had an error on, I also tried something similar earlier with fail.

@GEOSoft, Your example did work, however it pulled a bunch of other arrays from the text as well, some I don't understand why, like the links at the bottom of the web page, they are not delemited by commas like the names are.

So is there a way to just obtain the text from between 'help? (pull names) LostInTranslation' as a solid string, than I could split the string into arrays later?

[JohnOne 1,587]

Im going with _StringBetween()

[sahsanu 28]

It is a dirty code but it works for me

#include <array.au3>
$String = "Who would you like to help?" & @CRLF & _
         "name1, name2, Name3, 4name, 5name, NaME6, na7me" & @CRLF & @CRLF & _
         "LostinTranslation"

$aRegExp = StringRegExpReplace($String, "(.*[\r\n]{1,})(.*,.*[\r\n]{1,})(.*)", "$2")
$aRegExp = StringRegExp($aRegExp, "(\w+)[,|\s]",3)
_ArrayDisplay($aRegExp)

[GEOSoft 64]

$sStr = StringRegExpReplace(FileRead("Somefile.txt"), "(?i)(?s).*Who would you like to help\?\v+(.+?)\v+lostintranslation.*", "$1")

If thi returns the proper string then you can probably just stringspli on the commas to get the array or continue using the SRE I gave you earlier.

Edited May 27, 2010 by GEOSoft

[Realm 17]

You guys all Rock!!!

So many examples, most are great!

sorry I did not see most of them before coming to a final solution!

@JohnOne, Thanks StringBetween was exactly what I needed, though I had a few minor obstacles like spaces before each name, and a few Carriage Returns, but with a little work and now it delivers exactly what I need, Thanks again to everyone and the help, even though I may not have used some of your examples, I sure have gained some well needed knowledge from them. I have been trying to avoid using StringRegExp for so long because it has been very confusing to me, but today your examples have enlightened me on some uses and how they work. Thanks again!

...and before I go, this is what I finally ended up with:

$rText = "Who would you like to help?" & @CRLF & _
    "name1, name2, Name3, 4name, 5name, NaME6, na7me" & @CRLF & @CRLF & _
    "LostinTranslation"

$rArray=_StringBetween($rText, 'help?' & @crlf, @crlf & @crlf & 'LostinTranslation')
$rhelpers=StringSplit(StringReplace($rArray[0], " ", ""), ",")
_ArrayDisplay($rhelpers, 'Default Search')