Splash Image?

[iSeeCream 0]

Hi, im working on a simple script and i found the SplashImageOn function. But now i have a problem, the image wont load. There is just an empty sleep until my actual script starts. This is an example of my script, anyone can use if they want, though its just a altered version of the first tutorial.

$destination = "C:\Users\Daniel\Desktop\Test.jpg"

SplashImageOn("Splash Screen", $destination,250,50)
Sleep(3000)
SplashOff()
$answer = InputBox ("Yes or No?", "Would you like to see automated text? Please Either write Yes or No", "Yes")
If $answer = "No" Then 
    ProcessClose ( "AutoIt3_x64.exe" )
EndIf
#AutoIt3Wrapper_AU3Check_Parameters=-w 1 -w 2 -w 3 -w 4 -w 6 -d

Opt("SendKeyDelay", 75)

ProgressOn("Loading...", "Please wait while it is loading", "0 percent")

For $i = 5 To 100 Step 5

    Sleep(100)

    ProgressSet($i, $i & " percent")
Next

ProgressSet(100, "Done", "Complete")

Sleep(500)

ProgressOff()

Run("Notepad.exe")

WinWaitActive("Untitled - Notepad")

ControlSend("Untitled - Notepad", '', "Edit1", "Hello, thank you for testing my script. This script was made by Daniel Yi. It has no purpose except to be a test for my script. Hallo, danke für den Test mein Skript. Dieses Skript wurde von Daniel Yi gemacht. Es hat keinen Zweck, als eine Prüfung für mein Skript werden")

[jaberwacky 319]

This works for me:

(Don't forget to change back your height and width)

expandcollapse popup

#AutoIt3Wrapper_AU3Check_Parameters=-w 1 -w 2 -w 3 -w 4 -w 6 -d

Global Const $destination = @DesktopDir & "\Test.jpg"
Global Const $width = 500
Global Const $height = 400
Global Const $centerX = (@DesktopWidth - $width) / 2
Global Const $centerY = (@DesktopHeight - $height) / 2

SplashImageOn("Splash Screen", $destination, $width, $height, $centerX, $centerY, 1)

Sleep(3000)

SplashOff()

Global Const $answer = InputBox("Yes or No?", "Would you like to see automated text? Please Either write Yes or No", "Yes")

If $answer = "No" Then
    ProcessClose(@AutoItPID)
EndIf

Opt("SendKeyDelay", 75)

ProgressOn("Loading...", "Please wait while it is loading", "0 percent")

For $i = 5 To 100 Step 5

    Sleep(100)

    ProgressSet($i, $i & " percent")
Next

ProgressSet(100, "Done", "Complete")

Sleep(500)

ProgressOff()

Run("Notepad.exe")

WinWaitActive("Untitled - Notepad")

ControlSend("Untitled - Notepad", '', "Edit1", "Hello, thank you for testing my script. This script was made by Daniel Yi. It has no purpose except to be a test for my script. Hallo, danke für den Test mein Skript. Dieses Skript wurde von Daniel Yi gemacht. Es hat keinen Zweck, als eine Prüfung für mein Skript werden")

Edited August 8, 2010 by jaberwocky6669

[iSeeCream 0]

Hmm, i tried it, but my image still wont load...

[jaberwacky 319]

Then it's your image. That's all I can say. You're sure that it's on the desktop?

[iSeeCream 0]

Yup, its on my desktop, im really confused how its not working. Also, thanks for all your help, you helped me before on my last topic im sure.

[ProgAndy 67]

Is it a real JPG-image? AutoIt can only read bmp, jpg and gif I suppose. png, tiff, ... is not supported

[UEZ 1,071]

You can use GDI+ to simulate the Splash function:

expandcollapse popup

#include <WindowsConstants.au3>
#include <GDIPlus.au3>
Opt("MustDeclareVars", 1)
Opt("GUIOnEventMode", 1)
Global $hWnd, $hGraphic, $file, $hImage
Global $iX, $iY

$file = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\AutoIt v3\AutoIt", "InstallDir") & "\Examples\GUI\torus.png"

If Not FileExists($file) Then Exit MsgBox(16, "Error", $file & " not found!", 10)

_GDIPlus_Startup()

$hImage = _GDIPlus_ImageLoadFromFile($file)

$iX = _GDIPlus_ImageGetWidth($hImage)
$iY = _GDIPlus_ImageGetHeight($hImage)

$hWnd = GUICreate("GDI+: Simple Splash Screen by UEZ", $iX, $iY, -1, -1, $WS_BORDER + $WS_SYSMENU + $WS_POPUP, $WS_EX_TOPMOST)
WinSetTrans($hWnd, "", 0)
GUISetState()

$hGraphic = _GDIPlus_GraphicsCreateFromHWND($hWnd)
_GDIPlus_GraphicsDrawImageRect($hGraphic, $hImage, 0, 0, $iX, $iY)

GUIRegisterMsg(0x000F, "WM_PAINT") ;$WM_PAINT = 0x000F
GUIRegisterMsg(0x0014 , "WM_ERASEBKGND") ;WM_ERASEBKGND = 0x0014

GUISetOnEvent(-3, "_Exit")

For $i = 0 To 255 Step 2
    WinSetTrans($hWnd, "", $i)
    Sleep(10)
Next

Sleep(5000)

For $i = 255 To 0 Step -2
    WinSetTrans($hWnd, "", $i)
    Sleep(5)
Next

GUIDelete($hWnd)

_Exit()

Func _Exit()
    GUIRegisterMsg(0x000F, "")
    GUIRegisterMsg(0x0014, "")
    _GDIPlus_ImageDispose($hImage)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
    Exit
EndFunc

Func WM_PAINT()
    _GDIPlus_GraphicsDrawImageRect($hGraphic, $hImage, 0, 0, $iX, $iY)
    Return "GUI_RUNDEFMSG"
EndFunc ;==>WM_PAINT

Func WM_ERASEBKGND()
    _GDIPlus_GraphicsDrawImageRect($hGraphic, $hImage, 0, 0, $iX, $iY)
    Return "GUI_RUNDEFMSG"
EndFunc

Br,

UEZ

[iSeeCream 0]

ehh, idk why D: Im sure its jpg, on my desktop

[NiVZ 1]

ehh, idk why D: Im sure its jpg, on my desktop

Is it definitely on YOUR desktop and not the ALL USERS desktop?

Right click the .jpg on your desktop and click properties and check the 'Location' line.

NiVZ

[iSeeCream 0]

ok

[iSeeCream 0]

this is the location line

C:\Users\Daniel\Desktop

[AdmiralAlkex 117]

Run this, do the MsgBox say True or False?

MsgBox(0, "", FileExists("C:\Users\Daniel\Desktop\Test.jpg") = True)

Also upload the image somewhere so we can look at it to make sure it's actually a jpg, and not something else named that way (wouldn't be the first time).