Sign in to follow this  
Followers 0
giankz

Help me! tooltip only on GUI

4 posts in this topic

Hi, I need to know how can I do this:

I have a tooltip moving with the cursor, but it moves across the screen, I want the tooltip only display within the GUI following the cursor. as I can do that?

In short I want the tooltip to be displayed anywhere, but only within the GUI

???

Thanks!

Share this post


Link to post
Share on other sites



giankz,

Here is one way to limit the ToolTip to the GUI - but there are many others: :)

#include <GUIConstantsEx.au3>
#include <WinAPI.au3>

Global $Struct = DllStructCreate($tagPoint), $fTip = False

$hGUI = GUICreate("Test", 500, 500)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

    ; Get mouse position
    $aMPos = MouseGetPos()
    DllStructSetData($Struct, "x", $aMPos[0])
    DllStructSetData($Struct, "y", $aMPos[1])
    ; Are we over the GUI?
    If _WinAPI_WindowFromPoint($Struct) = $hGUI Then
        ; If so, show the tip
        If Not $fTip Then $fTip = True
        ToolTip("Here", $aMPos[0], $aMPos[1] - 20)
    Else
        ; If not, hide the tip
        If $fTip Then
            ToolTip("")
            $fTip = False
        EndIf
    EndIf

WEnd

All clear? :)

M23

P.S. Please try and post in the correct forum area next time - this had to moved from "Examples". :P


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

Another way if the tooltip must not go beyong the client area.

; *** Start added by AutoIt3Wrapper ***
#include <StructureConstants.au3>
#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <WinAPI.au3>

opt("MustDeclareVars",1)
Global $lastx, $lasty,$hGUI, $hTT, $th, $tw,$stt,$hdc,$lab,$mp, $res

$hGUI = GUICreate("Test", 500, 500)
;must have at least one component- see below
;components must have clipsiblings style or complete mess can result
GUICtrlCreateButton("gg", 10, 30, 120, 21,$WS_CLIPSIBLINGS)
GUISetState()


$stt = "some text"
;find size of text
$hdc = _WinAPI_GetDC($hGUI)
$res = _WinAPI_GetTextExtentPoint32($hdc, $stt)
$th = DllStructGetData($res, 2) + 4
$tw = DllStructGetData($res, 1)
;create tooltip
$hTT = GUICreate("tooltip", $tw, $th, 0, 0, $WS_POPUP)
GUISetBkColor(0xffff00)
$lab = GUICtrlCreateLabel($stt, 8, 2)
GUISetState()

;if there are no components in the main window then things go wrong - I think this is a bug
;it becomes impossible to activate the main window or close it
DllCall("user32.dll", "int", "SetParent", "hwnd", $hTT, "hwnd", $hGUI)

GUISwitch($hGUI)
winactivate($hGUI)
While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

    ; Get mouse position
    $mp = GUIGetCursorInfo($hGUI)
    If $mp[0] <> $lastx Or $mp[1] <> $lasty Then
        $lastx = $mp[0]
        $lasty = $mp[1]
        WinMove($hTT, "", $lastx - 5, $lasty - $th - 2)
    EndIf

WEnd

Serial port communications UDF Includes functions for binary transmission and reception.printing UDF Useful for graphs, forms, labels, reports etc.Add User Call Tips to SciTE for functions in UDFs not included with AutoIt and for your own scripts.Functions with parameters in OnEvent mode and for Hot Keys One function replaces GuiSetOnEvent, GuiCtrlSetOnEvent and HotKeySet.UDF IsConnected2 for notification of status of connected state of many urls or IPs, without slowing the script.

Share this post


Link to post
Share on other sites

#4 ·  Posted (edited)

thank you both .... is just what I needed. Very helpful

Greetings.

Edited by giankz

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0