Help me! tooltip only on GUI

[giankz]

Hi, I need to know how can I do this:

I have a tooltip moving with the cursor, but it moves across the screen, I want the tooltip only display within the GUI following the cursor. as I can do that?

In short I want the tooltip to be displayed anywhere, but only within the GUI

???

Thanks!

[Melba23]

giankz,

Here is one way to limit the ToolTip to the GUI - but there are many others:

#include <GUIConstantsEx.au3>
#include <WinAPI.au3>

Global $Struct = DllStructCreate($tagPoint), $fTip = False

$hGUI = GUICreate("Test", 500, 500)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

    ; Get mouse position
    $aMPos = MouseGetPos()
    DllStructSetData($Struct, "x", $aMPos[0])
    DllStructSetData($Struct, "y", $aMPos[1])
    ; Are we over the GUI?
    If _WinAPI_WindowFromPoint($Struct) = $hGUI Then
        ; If so, show the tip
        If Not $fTip Then $fTip = True
        ToolTip("Here", $aMPos[0], $aMPos[1] - 20)
    Else
        ; If not, hide the tip
        If $fTip Then
            ToolTip("")
            $fTip = False
        EndIf
    EndIf

WEnd

All clear?

M23

P.S. Please try and post in the correct forum area next time - this had to moved from "Examples".

[martin]

Another way if the tooltip must not go beyong the client area.

expandcollapse popup

; *** Start added by AutoIt3Wrapper ***
#include <StructureConstants.au3>
#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <WinAPI.au3>

opt("MustDeclareVars",1)
Global $lastx, $lasty,$hGUI, $hTT, $th, $tw,$stt,$hdc,$lab,$mp, $res

$hGUI = GUICreate("Test", 500, 500)
;must have at least one component- see below
;components must have clipsiblings style or complete mess can result
GUICtrlCreateButton("gg", 10, 30, 120, 21,$WS_CLIPSIBLINGS)
GUISetState()


$stt = "some text"
;find size of text
$hdc = _WinAPI_GetDC($hGUI)
$res = _WinAPI_GetTextExtentPoint32($hdc, $stt)
$th = DllStructGetData($res, 2) + 4
$tw = DllStructGetData($res, 1)
;create tooltip
$hTT = GUICreate("tooltip", $tw, $th, 0, 0, $WS_POPUP)
GUISetBkColor(0xffff00)
$lab = GUICtrlCreateLabel($stt, 8, 2)
GUISetState()

;if there are no components in the main window then things go wrong - I think this is a bug
;it becomes impossible to activate the main window or close it
DllCall("user32.dll", "int", "SetParent", "hwnd", $hTT, "hwnd", $hGUI)

GUISwitch($hGUI)
winactivate($hGUI)
While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

    ; Get mouse position
    $mp = GUIGetCursorInfo($hGUI)
    If $mp[0] <> $lastx Or $mp[1] <> $lasty Then
        $lastx = $mp[0]
        $lasty = $mp[1]
        WinMove($hTT, "", $lastx - 5, $lasty - $th - 2)
    EndIf

WEnd

[giankz]

thank you both .... is just what I needed. Very helpful

Greetings.

Edited March 5, 2011 by giankz