HighLight Syntax HELP !!

[Geirolz]

Hello everyone I want to create a syntax for an input in my Sw

I wish if I write the word BIND colors BIND of blue for example

I'm really desperate and I'm looking for weeks for the network but have not found anything

thank you very much

Edited April 8, 2011 by Geirolz

[nitekram]

Hello everyone I want to create a syntax for an input in my Sw

I wish if I write the word BIND colors BIND of blue for example

I'm really desperate and I'm looking for weeks for the network but have not found anything

thank you very much

not really sure what you are asking, but you could read the input and based upon what it says change the color of the background?

$read = guictrlread($yourinput)

If $read = 'BIND' Then GUICtrlSetBkColor($yourinput, 0x00ff00) ; changes the background to green (could not find blue fast enough)

[somdcomputerguy]

0x0000FF -> blue

[Geirolz]

i don't HighLight all input but only "Bind"

[nitekram]

i don't HighLight all input but only "Bind"

Look up the function - GUICtrlSetColor() from the help file, should be what you want.

[smartee]

Interesting, try this

expandcollapse popup

#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Color.au3>

$hGui = GUICreate("Example (" & @ScriptName & ")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "", 10, 10, 300, 330, _
        BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
GUISetState()

_GUICtrlRichEdit_SetText($hRichEdit, "The bind function associates a local address with a socket.")
_highlightWords()
$updateWords = _GUICtrlRichEdit_GetText($hRichEdit)

While True
    $iMsg = GUIGetMsg()
    Select
        Case $iMsg = $GUI_EVENT_CLOSE
            GUIDelete()
            Exit
    EndSelect
    $updateWords = _update($updateWords)
WEnd

Func _highlightWords($defcolor = 0x000000)
    _GUICtrlRichEdit_SetCharColor($hRichEdit, $defcolor)
    _highlight("bind", 0xff0000)
    _highlight("socket", 0x0000ff)
EndFunc   ;==>_highlightWords

Func _update($last)
    $new = _GUICtrlRichEdit_GetText($hRichEdit)
    If ($new <> $last) Then
        _highlightWords()
        Return $new
    EndIf
    Return $last
EndFunc   ;==>_update

Func _highlight($word, $color)
    $prevsel = _GUICtrlRichEdit_GetSel($hRichEdit)
    $range = _GUICtrlRichEdit_FindTextInRange($hRichEdit, $word)
    While Not (@error) And ($range[0] <> -1)
        _GUICtrlRichEdit_SetSel($hRichEdit, $range[0], $range[1])
        _GUICtrlRichEdit_SetCharColor($hRichEdit, $color)
        $range = _GUICtrlRichEdit_FindTextInRange($hRichEdit, $word, $range[1])
    WEnd
    _GUICtrlRichEdit_SetSel($hRichEdit, $prevsel[0], $prevsel[1])
EndFunc   ;==>_highlight

[Geirolz]

u have the link for download GuiRichEdit.au3 ??? thanks

[smartee]

Its included in Autoit 3.3.6.1 by default

[Geirolz]

ahah =) thanks !!

[Geirolz]

can i create _GUICtrlRichEdit_Create in Tab ????

[smartee]

Nice question, its not as straightforward as it should be, but there a few workarounds available if you search the forum.

[Melba23]

Geirolz,

I recommend starting with the Tabs tutorial in the Wiki.

M23