Need to convert entire Directory contents into one string

[phatzilla]

Hey, so heres what i'm trying to do here:

I have a directory; say C:\dir

I want to be able to read all the files in the directory, while retaining the ENTIRE path

#Include <File.au3>
#Include <Array.au3>
$FileList=_FileListToArray("c:\dir", "*.*" , 1)
If (Not IsArray($FileList)) and (@Error=1) Then
    MsgBox (0,"","No Files\Folders Found.")
    Exit
EndIf

_ArrayDisplay($FileList,"$FileList")

This code just returns the filename, not the c:\dir\ path so i'd like that included

Now, i would like to be able to transform the entire directory listing into one string, with a ";" seperator between every file

So if i have:

file1.jpg

file2.jpg

file3.jpg

in the directory, i want the string to read:

c:\dir\file1.jpg;c:\dir\file2.jpg;c:\dir\file3.jpg

I assume i would have to use some concatenate feature, but im not sure how to do that

[JohnOne]

try this

or maybe just add @ScriptDIR

[BrewManNH]

Try this and see if it's what you're looking for.

#include <recfilelisttoarray.au3>
#include <Array.au3>
Global $Path = "C:\Windows"
Global $aFileList = _RecFileListToArray($Path, "*", 1, 0,  0, 2)
_ArrayDisplay($aFileList)
Global $Text = ""
For $I = 1 To $aFileList[0]
    $Text &= $aFileList[$I] & ";"
Next
ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $Text = ' & $Text & @crlf & '>Error code: ' & @error & @crlf) ;### Debug Console

It will display the variable $Text in the console window of scite if rum from there.

[phatzilla]

Hey brew i got it to work with _arraytostring function. However, it only returns the filenames, i want the full directory to precede each file

I get : file1.jpg;file2.jpg;file3.jpg

I want : c:\dir\file1.jpg;c:\dir\file2.jpg;c:\dir\file3.jpg

[BrewManNH]

I forgot, you'll need to add the UDF which makes this easier to get what you need.

[Malkey]

....

I assume i would have to use some concatenate feature, but im not sure how to do that

The concatenate feature is using "&" between strings.

Try this.

#include <File.au3>
#include <Array.au3>

Local $sDir = "C:\Documents and Settings\All Users\Desktop"
Local $FileList = _FileListToArray($sDir, "*.*", 1)
If @error Then   ; or  IsArray($FileList) = 0 then ;
    MsgBox(0, "", "No Files\Folders Found.")
    Exit
EndIf

_ArrayDisplay($FileList, "$FileList")

Local $sFileListString = ""
For $i = 1 To UBound($FileList) - 1
    $sFileListString &= $sDir & "\" & $FileList[$i] & ";" ; <-- Concatenation
Next
$sFileListString = StringTrimRight($sFileListString, 1) ; Remove trailing semicolon.

ConsoleWrite($sFileListString & @CRLF)
MsgBox(0, "File List String", $sFileListString)

[hannes08]

Or, if you only need the first level:

#Include <File.au3>
#Include <Array.au3>

$dir = "C:\dir"

$FileList=_FileListToArray($dir, "*.*" , 1)
If (Not IsArray($FileList)) and (@Error=1) Then
    MsgBox (0,"","No Files\Folders Found.")
    Exit
Else
    $FileListString = _ArrayToString($FileList, ", " & $dir & "\", 1)
EndIf

ConsoleWrite($FileListString & @CRLF)