Sign in to follow this  
Followers 0
locar

Run a function when MMB is pressed

5 posts in this topic

Can't seem to find a way to add hotkey for MMB and _IsPressed(04) only seems to work while I hold down the MMB, but I need to recognize every click however short it may be.

Share this post


Link to post
Share on other sites



Not possible?

Share this post


Link to post
Share on other sites

#4 ·  Posted (edited)

1. Don't harass the forum (bump your own thread) for 24 hours after post.

2. Post code.

3. When someone helps you with a problem, its polite to aknowledge their existence.

Edited by JohnOne

AutoIt Absolute Beginners    Require a serial    Pause Script    Video Tutorials by Morthawt   ipify 

Monkey's are, like, natures humans.

Share this post


Link to post
Share on other sites

locar,

Try this - it works for my right and left buttons but I do not have a middle button to test it on: :oops:

#include <WindowsConstants.au3>
#include <WinAPI.au3>

Global Const $tagMSLLHOOKSTRUCT = $tagPOINT & ";dword mouseData;dword flags;dword time;ulong_ptr dwExtraInfo"

HotKeySet("{ESC}", "On_Exit")

$hFunc = DllCallbackRegister("Mouse_Hook", "long", "int;wparam;lparam")
$pFunc = DllCallbackGetPtr($hFunc)
$hHook = _WinAPI_SetWindowsHookEx($WH_MOUSE_LL, $pFunc, _WinAPI_GetModuleHandle(0))

While 1
    Sleep(10)
WEnd

Func On_Exit()

    _WinAPI_UnhookWindowsHookEx($hHook)
    DllCallbackFree($hFunc)
    Exit

EndFunc   ;==>On_Exit

Func Mouse_Hook($iCode, $iwParam, $ilParam)

    Local $tMSLLHOOKSTRUCT = DllStructCreate($tagMSLLHOOKSTRUCT, $ilParam)

    If $iCode < 0 Then
        Return _WinAPI_CallNextHookEx($hHook, $iCode, $iwParam, $ilParam)
    EndIf

    Switch $iwParam
        Case $WM_LBUTTONDOWN
            ConsoleWrite("Left" & @CRLF)
        Case $WM_RBUTTONDOWN
            ConsoleWrite("Right" & @CRLF)
        Case $WM_MBUTTONDOWN
            ConsoleWrite("Middle" & @CRLF)
    EndSwitch

    Return _WinAPI_CallNextHookEx($hHook, $iCode, $iwParam, $ilParam)

EndFunc   ;==>Mouse_Hook

Any use? :D

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0