Reverse string by two letter

[Ptifou78]

Hi all today i would like to reverse a hex string(not really reverse) I just want a function tu translate 1 CD EA 29 into 29 EA CD 01

Thanks in advance

Edited November 4, 2011 by Ptifou78

[JohnOne]

You can hone your logic here.

[trancexx]

Hm. This works.

ConsoleWrite(_Not_Really_Reverse("1 CD EA 29") & @CRLF)

Func _Not_Really_Reverse($sHex)
    If $sHex = "1 CD EA 29" Then Return BinaryToString("0x31204344204541203239")
    Return $sHex
EndFunc

[UEZ]

Try this:

ConsoleWrite(HexStringReverse("1 CD EA 29") & @LF & @error & @LF)
ConsoleWrite(HexStringReverse("FF A 3 CA") & @LF & @error & @LF)
ConsoleWrite(HexStringReverse("1abcdef") & @LF & @error & @LF)

Func HexStringReverse($HexString, $delim= " ") ;coded by UEZ 2011
    If Not IsString($HexString) Then Return SetError(1, 0, 0) ;not a string
    If StringRegExpReplace($HexString, "(?i)[0-9a-fs]", "") Then Return SetError(2, 0, 0) ;not a hex string
    Local $aResult = StringSplit($HexString, " ")
    If Not @error Then
        $aResult = StringSplit(StringRegExpReplace($HexString, "b([w])b", "0$1"), " ", 2)
    Else
         If Mod(StringLen($HexString), 2) Then $HexString = "0" & $HexString
         $aResult = StringRegExp($HexString, ".{2}", 3)
    EndIf
     _ArrayReverse($aResult)
    Return _ArrayToString($aResult, $delim)
EndFunc

Br,

UEZ

Edited November 7, 2011 by UEZ

[Ptifou78]

thanks a lot UEZ it's work perfectly

[Malkey]

Here are other methods.

#include<Array.au3>

Local $string = "1 c8 D A"

ConsoleWrite(HexReverse($string) & @LF)
; or
ConsoleWrite(HexReverse1($string) & @LF)

; #include<Array.au3> required
Func HexReverse($HexString)
    If Not String($HexString) Then Return SetError(1, 0, 0)
    Local $aResult = StringSplit(StringStripWS(StringRegExpReplace(StringUpper($HexString), "\b([[:xdigit:]])\b", "0\1"), 7), " ", 2)
    _ArrayReverse($aResult)
    Return _ArrayToString($aResult, " ")
EndFunc   ;==>HexReverse

; No includes needed
Func HexReverse1($HexString)
    If Not String($HexString) Then Return SetError(1, 0, 0)
    Local $aResult
    $HexString = StringStripWS(StringRegExpReplace($HexString, "\b([[:xdigit:]])\b", "0\1"), 8)
    For $i = 1 To StringLen($HexString) Step 2
        $aResult = StringMid($HexString, $i, 2) & " " & $aResult
    Next
    Return StringUpper($aResult)
EndFunc   ;==>HexReverse1