Sign in to follow this  
Followers 0
KarlosTHG

Metro Inspired Login GUI

15 posts in this topic

#1 ·  Posted (edited)

Hi Guys!!

I want to share this Login GUI that I'm working on for my last project... I hope you like it!

Some Features:

  • Metro Style Inspiration.
  • It adjust itself to any screen resolution.
  • With the use of all the screen the software get all the attention of the client
  • Input PlaceHolders
  • Cute Design
Posted Image

But.... I also want you to help me please to solve some problems:

  • How to avoid the flicker in the intro animation (maybe GDI text... but i don't know how yet)
  • Why the GUICtrlSetStyle( $inputPass,0x0020+0x0001, 0) is not working, it is supposed to change the style to password but it doesn't, the only way i have found is to set the style al the time of the input creation but that is not the idea... as you can see, because the placeholder effect would be lost...
  • Any other feedback.
Download Here: sample.zip

Thanks for your help!! and thanks to MrCreatoR for his awesome GUICtrlOnHover UDF

Update:

  • Now using GUICtrlSendMsg(-1, $EM_SETCUEBANNER, True, "Password"), thanks to AlmarM, Melba23 and D4RKON3
  • Everything is in English now
  • Some fixes here and there
  • Some code clean-up

Now! Who is up for making the animation flickerless!!!

Edited by KarlosTHG
1 person likes this

Share this post


Link to post
Share on other sites



Looks great, awesome design!

Why the GUICtrlSetStyle( $inputPass,0x0020+0x0001, 0) is not working, it is supposed to change the style to password but it doesn't, the only way i have found is to set the style al the time of the input creation but that is not the idea... as you can see, because the placeholder effect would be lost...

I had the same problem once.. Last week I think I saw a solution somewhere in the Example Scripts forum.

I'll try to find it, check back this comment later.


Minesweeper

A minesweeper game created in autoit, source available.

_Mouse_UDF

An UDF for registering functions to mouse events, made in pure autoit.

2D Hitbox Editor

A 2D hitbox editor for quick creation of 2D sphere and rectangle hitboxes.

Share this post


Link to post
Share on other sites

#3 ·  Posted (edited)

Try in line 113:

$inputPass = GUICtrlCreateInput("Contraseña...", $wdleft+($wsizew/2)-(300/2)+50, $wdtop+430+7, 300-50, 30, 0x0021);password...

Nice looking GUI! :oops:

Br,

UEZ

Edited by UEZ

Please don't send me any personal message and ask for support! I will not reply!

Selection of finest graphical examples at Codepen.io

The own fart smells best!
Her 'sikim hıyar' diyene bir avuç tuz alıp koşma!
¯\_(ツ)_/¯  ٩(●̮̮̃•̃)۶ ٩(-̮̮̃-̃)۶ૐ

Share this post


Link to post
Share on other sites

KarlosTHG,

I think AlmarM is referring to this CUEBANNER code: :oops:

#include <GUIConstantsEX.au3>
#include <EditConstants.au3>

$hGUO = GUICreate("Test", 500, 500)

$CInput = GUICtrlCreateInput("", 10, 10, 200, 20, $ES_PASSWORD)
GUICtrlSendMsg(-1, $EM_SETCUEBANNER, True, "Password")

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

;Does not work for edit controls with $ES_MULTILINE style.
;In XP, the banner disappears when the edit has focus (cursor in edit)
;In Vista/7 the banner can optionally still appear when the edit has focus (cursor in edit)
;(third parameter = True/False)

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

Actualy, I was looking for a script in which you could change between the password style, since his login screen only needs to draw password characters whenever it has focus.

I could only find this for the moment:


Minesweeper

A minesweeper game created in autoit, source available.

_Mouse_UDF

An UDF for registering functions to mouse events, made in pure autoit.

2D Hitbox Editor

A 2D hitbox editor for quick creation of 2D sphere and rectangle hitboxes.

Share this post


Link to post
Share on other sites

I'm sorry to post another post, but I'm having problems with editing my posts. View here.

The cuebanner is awesome and might even work better then switching between styles.


Minesweeper

A minesweeper game created in autoit, source available.

_Mouse_UDF

An UDF for registering functions to mouse events, made in pure autoit.

2D Hitbox Editor

A 2D hitbox editor for quick creation of 2D sphere and rectangle hitboxes.

Share this post


Link to post
Share on other sites

Nice job, try this out:

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <StaticConstants.au3>
#include "GUICtrlOnHover.au3"
Opt("GUIOnEventMode", 1)
$appTitle = "SoftTitle"
$appSubTitle = "KLSoftware - KLSoftwareco@gmail.com"
;dialog size
$wsizew = 800 + 224 - 334;you can use any size and the content will adapt unless there is no room left, as far as I have tested...
$wsizeh = 600 + 168 - 200
$wdleft = (@DesktopWidth - $wsizew) / 2
$wdtop = (@DesktopHeight - $wsizeh) / 2
HotKeySet("{ESC}", "close")
$gui = GUICreate("fullscreencover", @DesktopWidth, @DesktopHeight, 0, 0, $WS_POPUP)
GUISetBkColor(0X101010)

;018cc1
GUICtrlCreatePic("guigrey.bmp", $wdleft + 10, $wdtop + 10, $wsizew - 20, $wsizeh - 20)
GUICtrlSetState(-1, $GUI_DISABLE)
$title = GUICtrlCreateLabel($appTitle, -430, $wdtop + 15, 370, 150)
GUICtrlSetFont(-1, 84, Default, Default, "Segoe UI Light", 5)
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
$title2 = GUICtrlCreateLabel($appSubTitle, -430, $wdtop + 140, 297, 30)
GUICtrlSetFont(-1, 14, Default, Default, "Segoe UI Light", 5)
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
$fechames = GUICtrlCreateLabel("Enero", $wdleft + $wsizew - 155, $wdtop + 30, 100, 30, 0x0002);+0x1000)
GUICtrlSetFont(-1, 14, Default, Default, "Segoe UI Light", 5)
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
$fechadia = GUICtrlCreateLabel("1", $wdleft + $wsizew - 50, $wdtop + 14, 40, 50);+0x1000)
GUICtrlSetFont(-1, 24, Default, Default, "Segoe UI Light", 5)
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)

$lbhora = GUICtrlCreateLabel(@HOUR & ":" & @MIN, $wdleft + $wsizew - 135, $wdtop + 50, 100, 50, 0x0002);+0x1000)
GUICtrlSetFont(-1, 24, Default, Default, "Segoe UI", 5)
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
$lbhoraampm = GUICtrlCreateLabel("p", $wdleft + $wsizew - 30, $wdtop + 50, 35, 40);,0x1000)
GUICtrlSetFont(-1, 14, Default, Default, "Segoe UI", 5)
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
$lbhoraampmfix = GUICtrlCreateLabel("m", $wdleft + $wsizew - 30, $wdtop + 70, 35, 40);+0x1000)
GUICtrlSetFont(-1, 12, Default, Default, "Segoe UI", 5)
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
UpdateTime()
AdlibRegister("UpdateTime", 1000)
GUICtrlCreatePic("guilockpad.bmp", $wdleft + ($wsizew / 2) - (120 / 2), $wdtop + 200, 120, 160)
GUICtrlSetState(-1, $GUI_DISABLE)
GUICtrlCreatePic("guiinput.bmp", $wdleft + ($wsizew / 2) - (332 / 2), $wdtop + 380, 332, 45)
GUICtrlSetState(-1, $GUI_DISABLE)
GUICtrlCreatePic("guiuser.bmp", $wdleft + ($wsizew / 2) - (332 / 2) + 10, $wdtop + 380 + 10, 30, 30)
GUICtrlSetState(-1, $GUI_DISABLE)
$inputUser = GUICtrlCreateInput("", $wdleft + ($wsizew / 2) - (300 / 2) + 30, $wdtop + 380 + 7, 300 - 30, 30, 0x0001, 0);user...
GUICtrlSetFont(-1, 17, 800, Default, "Segoe UI Bold", 5)
GUICtrlSendMsg(-1, $EM_SETCUEBANNER, False, 'Username')
GUICtrlCreatePic("guiinput.bmp", $wdleft + ($wsizew / 2) - (332 / 2), $wdtop + 430, 332, 45)
GUICtrlSetState(-1, $GUI_DISABLE)
GUICtrlCreatePic("guikey.bmp", $wdleft + ($wsizew / 2) - (332 / 2) + 10, $wdtop + 430 + 10, 50, 23)
GUICtrlSetState(-1, $GUI_DISABLE)
$inputPass = GUICtrlCreateInput("", $wdleft + ($wsizew / 2) - (300 / 2) + 50, $wdtop + 430 + 7, 300 - 50, 30, 0x0001 + $ES_PASSWORD, 0);password...
GUICtrlSetFont(-1, 17, 800, Default, "Segoe UI", 5)
GUICtrlSendMsg(-1, $EM_SETCUEBANNER, False, 'Password')
$ButtonNextimg = GUICtrlCreatePic("guiblueb1.bmp", $wdleft + ($wsizew / 2) + 20, $wdtop + 500, 144, 51)
GUICtrlSetState(-1, $GUI_DISABLE)
$ButtonNext = GUICtrlCreateLabel("Entrar", $wdleft + ($wsizew / 2) + 20, $wdtop + 500, 144, 51, 0x0001); enter the system
GUICtrlSetFont(-1, 24, 800, Default, "Segoe UI", 5)
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
_GUICtrl_OnHoverRegister(-1, "_Hover_Proc", "_Leave_Hover_Proc", "PrimaryDown_Proc")
$ButtonExitimg = GUICtrlCreatePic("guiredb1.bmp", $wdleft + ($wsizew / 2) - 184 + 20, $wdtop + 500, 144, 51)
GUICtrlSetState(-1, $GUI_DISABLE)
$ButtonExit = GUICtrlCreateLabel("Salir", $wdleft + ($wsizew / 2) - 184 + 20, $wdtop + 500, 144, 51, 0x0001); enter the system
GUICtrlSetFont(-1, 24, 800, Default, "Segoe UI", 5)
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
_GUICtrl_OnHoverRegister(-1, "_Hover_Proc", "_Leave_Hover_Proc", "PrimaryDown_Proc")
GUISetState(@SW_SHOW)
Sleep(500)
For $lp = -430 To 80 Step 8
GUICtrlSetPos($title, $wdleft + $lp)
Next
For $lp = 80 To 20 Step -4
GUICtrlSetPos($title, $wdleft + $lp)
Sleep(10)
Next
Sleep(500)
For $lp = -430 To 80 Step 8
GUICtrlSetPos($title2, $wdleft + $lp)
Next
For $lp = 80 To 25 Step -4
GUICtrlSetPos($title2, $wdleft + $lp)
Sleep(10)
Next
While 1
Sleep(1000)
WEnd
Func _Hover_Proc($iCtrlID)
Switch $iCtrlID
  Case $ButtonNext
   GUICtrlSetImage($ButtonNextimg, "guiblueb2.bmp")
  Case $ButtonExit
   GUICtrlSetImage($ButtonExitimg, "guiredb2.bmp")
EndSwitch
EndFunc   ;==>_Hover_Proc
Func _Leave_Hover_Proc($iCtrlID)
Switch $iCtrlID
  Case $ButtonNext
   GUICtrlSetImage($ButtonNextimg, "guiblueb1.bmp")
  Case $ButtonExit
   GUICtrlSetImage($ButtonExitimg, "guiredb1.bmp")
EndSwitch
EndFunc   ;==>_Leave_Hover_Proc
Func PrimaryDown_Proc($iCtrlID)
Switch $iCtrlID
  Case $ButtonNext
   GUICtrlSetImage($ButtonNextimg, "guiblueb1.bmp")
   MsgBox(0, "Listo", "Bienvenido al sistema")
  Case $ButtonExit
   GUICtrlSetImage($ButtonExitimg, "guiredb1.bmp")
   Exit
EndSwitch
EndFunc   ;==>PrimaryDown_Proc
Func UpdateTime()
Local $hora = @HOUR
Local $ampm = "a"
If $hora > 12 Then
  $hora = "0" & $hora - 12
  $ampm = "p"
EndIf
If $hora = "00" Then $hora = 12
If GUICtrlRead($lbhora) <> $hora & ":" & @MIN Then
  GUICtrlSetData($lbhora, $hora & ":" & @MIN)
  GUICtrlSetData($lbhoraampm, $ampm)
EndIf
Local $month
Switch @MON
  Case 1
   $month = "Enero";january
  Case 2
   $month = "Febrero";february
  Case 3
   $month = "Marzo"
  Case 4
   $month = "Abril"
  Case 5
   $month = "Mayo"
  Case 6
   $month = "Junio"
  Case 7
   $month = "Julio"
  Case 8
   $month = "Agosto"
  Case 9
   $month = "Septiembre"
  Case 10
   $month = "Octubre"
  Case 11
   $month = "Noviembre"
  Case 12
   $month = "Diciembre"
EndSwitch
If GUICtrlRead($fechames) <> $month Then
  GUICtrlSetData($fechames, $month)
EndIf
If GUICtrlRead($fechadia) <> @MDAY Then
  GUICtrlSetData($fechadia, @MDAY)
EndIf
EndFunc   ;==>UpdateTime
Func close()
Exit
EndFunc   ;==>close

Share this post


Link to post
Share on other sites

First Post Updated!!

Share this post


Link to post
Share on other sites

Try this.

LoginGUI.au3

#region INCLUDES
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>
#include <StaticConstants.au3>
#include "GUICtrlOnHover.au3"
#endregion INCLUDES

#region RUNTIME OPTIONS
Opt("GUIOnEventMode", 1)
HotKeySet("{ESC}", "close")
#endregion RUNTIME OPTIONS

#region GLOBAL VARIABLES
Global $appTitle = "SoftTitle"
Global $appSubTitle = "Awesome Subtitle - Awesome@mail.com"

;month names strings
Global $monthNames[13]
$monthNames[1] = "January"
$monthNames[2] = "February"
$monthNames[3] = "March"
$monthNames[4] = "April"
$monthNames[5] = "May"
$monthNames[6] = "June"
$monthNames[7] = "July"
$monthNames[8] = "August"
$monthNames[9] = "September"
$monthNames[10] = "October"
$monthNames[11] = "November"
$monthNames[12] = "December"

;username and password strings
Global $usernametxt = "Username...";"Usuario..."
Global $passwordtxt = "Password...";"Contraseña..."


;enter and exit strings
Global $nexttxt = "Enter";"Entrar"
Global $exittxt = "Exit";"Salir"

;dialog size, this is the gray area.
Global $wsizew = 800 + 224 - 334;you can use any size and the content will adapt unless there is no room left, as far as I have tested...
Global $wsizeh = 600 + 168 - 200

;New [0,0] coordinates, the top left corner of the gray area.
$wdleft = (@DesktopWidth - $wsizew) / 2
$wdtop = (@DesktopHeight - $wsizeh) / 2
#endregion GLOBAL VARIABLES

#region GUI
$gui = GUICreate($appTitle, @DesktopWidth, @DesktopHeight, 0, 0, $WS_POPUP)
GUISetBkColor(0x101010)


;Dialog Background
GUICtrlCreatePic("guigrey.bmp", $wdleft + 10, $wdtop + 10, $wsizew - 20, $wsizeh - 20)
GUICtrlSetState(-1, $GUI_DISABLE)

;Date and Clock
$datemonth = GUICtrlCreateLabel("Enero", $wdleft + $wsizew - 155, $wdtop + 30, 100, 30, 0x0002);+0x1000)
GUICtrlSetFont(-1, 14, Default, Default, "Segoe UI Light", 5)
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)

$dateday = GUICtrlCreateLabel("1", $wdleft + $wsizew - 50, $wdtop + 14, 40, 50);+0x1000)
GUICtrlSetFont(-1, 24, Default, Default, "Segoe UI Light", 5)
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)

$lbhour = GUICtrlCreateLabel("", $wdleft + $wsizew - 135, $wdtop + 50, 100, 50, 0x0002);+0x1000)
GUICtrlSetFont(-1, 24, Default, Default, "Segoe UI", 5)
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)

$lbhourampm = GUICtrlCreateLabel("a", $wdleft + $wsizew - 30, $wdtop + 50, 35, 40);,0x1000)
GUICtrlSetFont(-1, 14, Default, Default, "Segoe UI", 5)
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)

$lbhourampmfix = GUICtrlCreateLabel("m", $wdleft + $wsizew - 30, $wdtop + 70, 35, 40);+0x1000)
GUICtrlSetFont(-1, 12, Default, Default, "Segoe UI", 5)
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)

UpdateTime()
AdlibRegister("UpdateTime", 1000)


;lockpad picture
GUICtrlCreatePic("guilockpad.bmp", $wdleft + ($wsizew / 2) - (120 / 2), $wdtop + 200, 120, 160)
GUICtrlSetState(-1, $GUI_DISABLE)


;Username Input
GUICtrlCreatePic("guiinput.bmp", $wdleft + ($wsizew / 2) - (332 / 2), $wdtop + 380, 332, 45)
GUICtrlSetState(-1, $GUI_DISABLE)

GUICtrlCreatePic("guiuser.bmp", $wdleft + ($wsizew / 2) - (332 / 2) + 10, $wdtop + 380 + 10, 30, 30)
GUICtrlSetState(-1, $GUI_DISABLE)

$inputUsername = GUICtrlCreateInput("", $wdleft + ($wsizew / 2) - (300 / 2) + 30, $wdtop + 380 + 7, 300 - 30, 30, 0x0001, 0);username...
GUICtrlSetFont(-1, 17, 800, Default, "Segoe UI Bold", 5)
GUICtrlSendMsg(-1, $EM_SETCUEBANNER, False, $usernametxt)


;Password Input
GUICtrlCreatePic("guiinput.bmp", $wdleft + ($wsizew / 2) - (332 / 2), $wdtop + 430, 332, 45)
GUICtrlSetState(-1, $GUI_DISABLE)

GUICtrlCreatePic("guikey.bmp", $wdleft + ($wsizew / 2) - (332 / 2) + 10, $wdtop + 430 + 10, 50, 23)
GUICtrlSetState(-1, $GUI_DISABLE)

$inputPassword = GUICtrlCreateInput("", $wdleft + ($wsizew / 2) - (300 / 2) + 50, $wdtop + 430 + 7, 300 - 50, 30, 0x0001 + $ES_PASSWORD, 0);password...
GUICtrlSetFont(-1, 17, 800, Default, "Segoe UI", 5)
GUICtrlSendMsg(-1, $EM_SETCUEBANNER, False, $passwordtxt)

;Button Next
$ButtonNextimg = GUICtrlCreatePic("guiblueb1.bmp", $wdleft + ($wsizew / 2) + 20, $wdtop + 500, 144, 51)
GUICtrlSetState(-1, $GUI_DISABLE)

$ButtonNext = GUICtrlCreateLabel($nexttxt, $wdleft + ($wsizew / 2) + 20, $wdtop + 500, 144, 51, 0x0001); enter the system
GUICtrlSetFont(-1, 24, 800, Default, "Segoe UI", 5)
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)

_GUICtrl_OnHoverRegister(-1, "_Hover_Proc", "_Leave_Hover_Proc", "PrimaryDown_Proc")


;Button Exit
$ButtonExitimg = GUICtrlCreatePic("guiredb1.bmp", $wdleft + ($wsizew / 2) - 184 + 20, $wdtop + 500, 144, 51)
GUICtrlSetState(-1, $GUI_DISABLE)

$ButtonExit = GUICtrlCreateLabel($exittxt, $wdleft + ($wsizew / 2) - 184 + 20, $wdtop + 500, 144, 51, 0x0001); enter the system
GUICtrlSetFont(-1, 24, 800, Default, "Segoe UI", 5)
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)

_GUICtrl_OnHoverRegister(-1, "_Hover_Proc", "_Leave_Hover_Proc", "PrimaryDown_Proc")

ControlFocus($gui, "", $ButtonExit)

;Title and Subtitle
$gui_child1 = GUICreate("", 375, 150, -430, $wdtop + 15, $WS_POPUP, $WS_EX_MDICHILD + $WS_EX_LAYERED, $gui)
$title = GUICtrlCreateLabel($appTitle, 0, 0, 375, 150)
GUICtrlSetFont(-1, 84, Default, Default, "Segoe UI Light", 5)
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, 0xabcdef)
_WinAPI_SetLayeredWindowAttributes($gui_child1, 0xabcdef)

$gui_child2 = GUICreate("", 317, 30, -430, $wdtop + 140, $WS_POPUP, $WS_EX_MDICHILD + $WS_EX_LAYERED, $gui)
$subtitle = GUICtrlCreateLabel($appSubTitle, 0, 0, 330, 30);297
GUICtrlSetFont(-1, 14, Default, Default, "Segoe UI Light", 3)
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, 0xfedcba)
_WinAPI_SetLayeredWindowAttributes($gui_child2, 0xfedcba)

GUISetState(@SW_SHOW, $gui)
GUISetState(@SW_SHOW, $gui_child1)
GUISetState(@SW_SHOW, $gui_child2)
Sleep(500)
#endregion GUI


#region INTRO ANIMATION
For $lp = -430 To 80 Step 0.85
    WinMove($gui_child1, "", $wdleft + $lp, $wdtop + 15)
Next

For $lp = 80 To 20 Step -0.009
    WinMove($gui_child1, "", $wdleft + $lp, $wdtop + 15)
Next

Sleep(500)
For $lp = -430 To 80 Step 0.85
    WinMove($gui_child2, "", $wdleft + $lp, $wdtop + 140)
Next

For $lp = 80 To 25 Step -0.009
    WinMove($gui_child2, "", $wdleft + $lp, $wdtop + 140)
Next
ControlFocus($gui, "", $inputUsername)

#endregion INTRO ANIMATION

#region LOOP
While 1
    Sleep(1000)
WEnd
#endregion LOOP
#region ON HOVER FUNCTIONS
Func _Hover_Proc($iCtrlID)
    Switch $iCtrlID
        Case $ButtonNext
            GUICtrlSetImage($ButtonNextimg, "guiblueb2.bmp")
        Case $ButtonExit
            GUICtrlSetImage($ButtonExitimg, "guiredb2.bmp")
    EndSwitch
EndFunc   ;==>_Hover_Proc

Func _Leave_Hover_Proc($iCtrlID)
    Switch $iCtrlID
        Case $ButtonNext
            GUICtrlSetImage($ButtonNextimg, "guiblueb1.bmp")
        Case $ButtonExit
            GUICtrlSetImage($ButtonExitimg, "guiredb1.bmp")
    EndSwitch
EndFunc   ;==>_Leave_Hover_Proc

Func PrimaryDown_Proc($iCtrlID)
    Switch $iCtrlID
        Case $ButtonNext
            GUICtrlSetImage($ButtonNextimg, "guiblueb1.bmp")
            MsgBox(0, "Ok", "Welcome")
        Case $ButtonExit
            GUICtrlSetImage($ButtonExitimg, "guiredb1.bmp")
            Exit
    EndSwitch
EndFunc   ;==>PrimaryDown_Proc

#endregion ON HOVER FUNCTIONS

#region TIME FUNCTION
Func UpdateTime()
    Local $hour = @HOUR
    Local $ampm = "a"

    If Number($hour) > 12 Then
        $hour = "0" & $hour - 12
        $ampm = "p"
    EndIf

    If $hour = "00" Then $hour = 12

    If GUICtrlRead($lbhour) <> $hour & ":" & @MIN Then
        GUICtrlSetData($lbhour, $hour & ":" & @MIN)
        GUICtrlSetData($lbhourampm, $ampm)
    EndIf

    If GUICtrlRead($lbhourampm) <> $ampm Then
        GUICtrlSetData($lbhourampm, $ampm)
    EndIf

    Local $month = $monthNames[Number(@MON)]

    If GUICtrlRead($datemonth) <> $month Then
        GUICtrlSetData($datemonth, $month)
    EndIf

    If GUICtrlRead($dateday) <> @MDAY Then
        GUICtrlSetData($dateday, @MDAY)
    EndIf
EndFunc   ;==>UpdateTime
#endregion TIME FUNCTION

#region OTHER FUNCTIONS
Func close()
    Exit
EndFunc   ;==>close
#endregion OTHER FUNCTIONS

Br,

UEZ


Please don't send me any personal message and ask for support! I will not reply!

Selection of finest graphical examples at Codepen.io

The own fart smells best!
Her 'sikim hıyar' diyene bir avuç tuz alıp koşma!
¯\_(ツ)_/¯  ٩(●̮̮̃•̃)۶ ٩(-̮̮̃-̃)۶ૐ

Share this post


Link to post
Share on other sites

You might want to add some protections against moving the Window and other stuff.

Here's a link to the Protection UDFs I've made and use in some of my scripts: http://mirror.fcofix.org/URSafe/Protections.zip


My UDFs are generally for me. If they aren't updated for a while, it means I'm not using them myself. As soon as I start using them again, they'll get updated.

MY PROJECTS


Active: IRC UDF, WindowEx UDF
Discontinued: GithubBubbleSort UDF

Share this post


Link to post
Share on other sites

@KarlosTHG

your sample.zip in your first post is corrupt - please fix it - Thanks...

Share this post


Link to post
Share on other sites

Getting a corrupt ZIP here too.

Share this post


Link to post
Share on other sites

Try this link: http://www.mediafire.com/download.php?2cedy3xoc8i57vb or http://www.4shared.com/archive/clAfjE3h/LoginGUI.html

Br,

UEZ


Please don't send me any personal message and ask for support! I will not reply!

Selection of finest graphical examples at Codepen.io

The own fart smells best!
Her 'sikim hıyar' diyene bir avuç tuz alıp koşma!
¯\_(ツ)_/¯  ٩(●̮̮̃•̃)۶ ٩(-̮̮̃-̃)۶ૐ

Share this post


Link to post
Share on other sites

Func PrimaryDown_Proc($iCtrlID)
Switch $iCtrlID
Case $ButtonNext
GUICtrlSetImage($ButtonNextimg, "guilogin1.bmp")
_Start()
Case $ButtonExit
GUICtrlSetImage($ButtonExitimg, "guiExitButton.bmp")
Exit
EndSwitch
EndFunc ;==>PrimaryDown_Proc

#endregion ON HOVER FUNCTIONS

#region TIME FUNCTION
Func UpdateTime()
Local $hour = @HOUR
Local $ampm = "a"

If Number($hour) > 12 Then
$hour = "0" & $hour - 12
$ampm = "p"
EndIf

If $hour = "00" Then $hour = 12

If GUICtrlRead($lbhour) <> $hour & ":" & @MIN Then
GUICtrlSetData($lbhour, $hour & ":" & @MIN)
GUICtrlSetData($lbhourampm, $ampm)
EndIf

If GUICtrlRead($lbhourampm) <> $ampm Then
GUICtrlSetData($lbhourampm, $ampm)
EndIf

Local $month = $monthNames[Number(@MON)]

If GUICtrlRead($datemonth) <> $month Then
GUICtrlSetData($datemonth, $month)
EndIf

If GUICtrlRead($dateday) <> @MDAY Then
GUICtrlSetData($dateday, @MDAY)
EndIf
EndFunc ;==>UpdateTime
#endregion TIME FUNCTION

#region OTHER FUNCTIONS
Func close()
Exit
EndFunc ;==>close
#endregion OTHER FUNCTIONS

Func _Start()

GUISetState(@SW_HIDE, $gui)
GUIDelete($gui_child1)
GUIDelete($gui_child2)
MsgBox(0, "Success", "YOUR IN!", 1)
_NewGUI()
EndFunc

Func _NewGUI()
GUISetState(@SW_HIDE, $gui)
GUIDelete($gui_child1)
GUIDelete($gui_child2)
#region ###
$NewGUI = GUICreate("New GUI", 300, 275, -1, -1, $WS_DLGFRAME)
GUICtrlCreateLabel("Test Label:", 5, 10, 600, 17)

Hi

Firstly I love this logon script.

I am having a slight issue moving onto the new GUI after logging in is successful in that the new GUI has the date and time showing all the time. The only way to stop it from showing on a new GUI is to insert a msgbox.

QAny ideas how to solve this?

Share this post


Link to post
Share on other sites

hey guys:) how can i get this to work into a mysql database?

So member from my website can login? [ONLY VIP members]

Please help a little. Thank you

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0

  • Similar Content

    • tcurran
      By tcurran
      Here are two functions to provide pixel-accurate height and width dimensions for a given string.
      The more commonly-used _GDIPlus_GraphicsMeasureString built-in UDF is problematic because it returns the width padded by roughly one en-space (for reasons related to the various ways Windows produces anti-aliased fonts).
      These are AutoIt translations of Pierre Arnaud's C# functions, described in his CodeProject article "Bypass Graphics.MeasureString limitations"
      The first is an all-purpose version that takes a window handle, string, font family, font size (in points), style, and (optionally) width of the layout column (in pixels) as parameters.
      The second, more efficient version is intended for applications where GDI+ fonts are already in use, and takes handles to the existing graphics context, string, font, layout and format as parameters.
      Both functions return a two-row array with the exact width [0] and height [1] of the string (in pixels).
      #include <GDIPlus.au3> #include <GUIConstantsEx.au3> ; #FUNCTION# ==================================================================================================================== ; Name ..........: _StringInPixels ; Description ...: Returns a pixel-accurate height and width for a given string using a given font, style and size. ; Syntax ........: _StringInPixels($hGUI, $sString, $sFontFamily, $fSize, $iStyle[, $iColWidth = 0]) ; Parameters ....: $hGUI - Handle to the window. ; $sString - The string to be measured. ; $sFontFamily - Full name of the font to use. ; $fSize - Font size in points (half-point increments). ; $iStyle - Combination of 0-normal, 1-bold, 2-italic, 4-underline, 8-strikethrough ; $iColWidth - [optional] If word-wrap is desired, column width in pixels ; Return values .: 2-row array. [0] is width in pixels; [1] is height in pixels. ; Author ........: Tim Curran; adapted from Pierre Arnaud's C# function ; Modified ......: ; Remarks .......: This version is longer and less efficient but works for all purposes. ; Related .......: <https://www.codeproject.com/Articles/2118/Bypass-Graphics-MeasureString-limitations> ; Link ..........: ; Example .......: Example-StringInPixels.au3 ; =============================================================================================================================== #include <GDIPlus.au3> #include <GUIConstantsEx.au3> Func _StringInPixels($hGUI, $sString, $sFontFamily, $fSize, $iStyle, $iColWidth = 0) _GDIPlus_Startup() Local $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI) ;Create a graphics object from a window handle Local $aRanges[2][2] = [[1]] $aRanges[1][0] = 0 ;Measure first char (0-based) $aRanges[1][1] = StringLen($sString) ;Region = String length Local $hFormat = _GDIPlus_StringFormatCreate() Local $hFamily = _GDIPlus_FontFamilyCreate($sFontFamily) Local $hFont = _GDIPlus_FontCreate($hFamily, $fSize, $iStyle) _GDIPlus_GraphicsSetTextRenderingHint($hGraphic, $GDIP_TEXTRENDERINGHINT_ANTIALIASGRIDFIT) _GDIPlus_StringFormatSetMeasurableCharacterRanges($hFormat, $aRanges) ;Set ranges Local $aWinClient = WinGetClientSize($hGUI) If $iColWidth = 0 Then $iColWidth = $aWinClient[0] Local $tLayout = _GDIPlus_RectFCreate(10, 10, $iColWidth, $aWinClient[1]) Local $aRegions = _GDIPlus_GraphicsMeasureCharacterRanges($hGraphic, $sString, $hFont, $tLayout, $hFormat) ;get array of regions Local $aBounds = _GDIPlus_RegionGetBounds($aRegions[1], $hGraphic) Local $aWidthHeight[2] = [$aBounds[2], $aBounds[3]] ; Clean up resources _GDIPlus_FontDispose($hFont) _GDIPlus_RegionDispose($aRegions[1]) _GDIPlus_FontFamilyDispose($hFamily) _GDIPlus_StringFormatDispose($hFormat) _GDIPlus_GraphicsDispose($hGraphic) _GDIPlus_Shutdown() Return $aWidthHeight EndFunc ;==>_StringInPixels ; #FUNCTION# ==================================================================================================================== ; Name ..........: _StringInPixels_gdip ; Description ...: Returns a pixel-accurate height and width for a given string using a GDI+ font, layout and format ; Syntax ........: _StringInPixels_gdip($hGraphic, $sString, $hFont, $tLayout, $hFormat) ; Parameters ....: $hGraphic - Handle to a GDI+ graphics object. ; $sString - The string to be measured. ; $hFont - Handle to a GDI+ font. ; $tLayout - A $tagGDIPRECTF structure that bounds the string. ; $hFormat - Handle to a GDI+ string format. ; Return values .: 2-row array. [0] is width in pixels; [1] is height in pixels. ; Author ........: Tim Curran; adapted from Pierre Arnaud's C# function ; Modified ......: ; Remarks .......: This much more efficient version is for use with GDI+ fonts ; Related .......: ; Link ..........: <https://www.codeproject.com/Articles/2118/Bypass-Graphics-MeasureString-limitations> ; Example .......: Example-StringInPixels.au3 ; =============================================================================================================================== #include <GDIPlus.au3> #include <GUIConstantsEx.au3> Func _StringInPixels_gdip($hGraphic, $sString, $hFont, $tLayout, $hFormat) Local $aRanges[2][2] = [[1]] $aRanges[1][0] = 0 ;Measure first char (0-based) $aRanges[1][1] = StringLen($sString) ;Region = String length _GDIPlus_GraphicsSetTextRenderingHint($hGraphic, $GDIP_TEXTRENDERINGHINT_CLEARTYPEGRIDFIT) _GDIPlus_StringFormatSetMeasurableCharacterRanges($hFormat, $aRanges) ;Set ranges Local $aRegions = _GDIPlus_GraphicsMeasureCharacterRanges($hGraphic, $sString, $hFont, $tLayout, $hFormat) ;get array of regions Local $aBounds = _GDIPlus_RegionGetBounds($aRegions[1], $hGraphic) Local $aWidthHeight[2] = [$aBounds[2], $aBounds[3]] _GDIPlus_RegionDispose($aRegions[1]) Return $aWidthHeight EndFunc ;==>_StringInPixels_gdip  
      _StringInPixels.au3
      Example-StringInPixels.au3
    • anusha
      By anusha
      Hi I have jus started using auto-it . Please correct me if I'm wrong.
      I need to read data from an input in text box and search in excel file and return value in next column of matched cell on GUI.
      I have written below code but i cannot use variable which has data stored. it works only when search string is hard coded.
      Please help out.
       
      Example()
      Func Example()
      Local $GuiMain = GUICreate("EXCEL TEST", 399, 180) ;creates main GUI
      ;~ Local $idOK = GUISetOnEvent($GUI_EVENT_CLOSE, "Close")
      Local $iWidthCell = 70
      Local $idLabel = GUICtrlCreateLabel("PART NUMBER", 10, 30, $iWidthCell,50)
      Local $RUN_1 = GUICtrlCreateButton("OK", 70, 70, 85, 25)
      Local $Input_1 = GUICtrlCreateInput("PART NUMBER", 100, 20, 120, 20)
      Local $sMenutext = GUICtrlRead($Input_1, 1)
      GUISetState(@SW_SHOW, $GuiMain)

          While 1
          $MSG = GUIGetMsg()
          Select
              Case $MSG = $GUI_EVENT_CLOSE
                  Exit
              Case $MSG = $RUN_1
                  Local $oAppl = _Excel_Open()

      Local $sFilePath1 = "D:\Anu_WorkFolder\Components.xlsx"
      Local $oWorkbook = _Excel_BookOpen($oAppl, $sFilePath1, Default, Default, True)
      Local $aResult = _Excel_RangeFind($oWorkbook, $sMenutext , Default, Default, $xlWhole)
    • Miliardsto
      By Miliardsto
      Hello.
      Drag option works only on parent window but as we can see on the parent gui is showed up child gui (on the right side with the color).
      Desired action is when we want to drag whole program we can also drag child gui and child gui will drag with parent gui.
      How to do this?
       
      #include <GUIConstantsEx.au3> #include <WindowsConstants.au3> #include <Array.au3> GUIRegisterMsg($WM_NCHITTEST, "_NCHITTEST") $hGUI = GUICreate("Test", 500, 500, -1, -1) $cButton_0 = GUICtrlCreateButton("Child 0", 10, 10, 80, 30) $cButton_1 = GUICtrlCreateButton("Child 1", 10, 50, 80, 30) $cButton_2 = GUICtrlCreateButton("Child 2", 10, 90, 80, 30) GUISetState(@SW_SHOW, $hGUI) ; guis Global $hChild_[3] Global $countGUI = UBound($hChild_) - 1 ;MsgBox("","",$countGUI) ; licznik dla GUI Global $gui = 0 $hChild_[0] = GUICreate("Child 0", 350, 300, 150, 0, $WS_POPUP, $WS_EX_MDICHILD, $hGUI) GUISetBkColor(0xFF0000) GUISetState(@SW_SHOW, $hChild_[0]) $hChild_[1] = GUICreate("Child 1", 350, 300, 150, 0, $WS_POPUP, $WS_EX_MDICHILD, $hGUI) GUISetBkColor(0x00FF00) GUISetState(@SW_HIDE, $hChild_[1]) $hChild_[2] = GUICreate("Child 2", 350, 300, 150, 0, $WS_POPUP, $WS_EX_MDICHILD, $hGUI) GUISetBkColor(0x0000FF) GUISetState(@SW_HIDE, $hChild_[2]) While 1 Switch GUIGetMsg() Case $GUI_EVENT_CLOSE Exit Case $cButton_0 _All_Hide() GUISetState(@SW_SHOW, $hChild_[0]) $gui = 0 Case $cButton_1 _All_Hide() GUISetState(@SW_SHOW, $hChild_[1]) $gui = 1 Case $cButton_2 _All_Hide() GUISetState(@SW_SHOW, $hChild_[2]) $gui = 2 EndSwitch WEnd Func _All_Hide() GUISetState(@SW_HIDE, $hChild_[0]) GUISetState(@SW_HIDE, $hChild_[1]) GUISetState(@SW_HIDE, $hChild_[2]) EndFunc Func _NCHITTEST($hWnd, $uMsg, $wParam, $lParam) If $hWnd = $hGUI Then Local $aPos = WinGetPos($hWnd) If Abs(BitAND(BitShift($lParam, 16),0xFFFF)- $aPos[1]) < 500 Then Return $HTCAPTION EndIf Return $GUI_RUNDEFMSG EndFunc  
    • IAMK
      By IAMK
      Hello,
       
      I have a script which uses a GUI with two buttons. It gets shown and hidden., and pressing the buttons (including their hotkeys) highlights the button, making you able to press enter the next time.
      However, I don't want that.
       
      I've tried using WinActivate() to make enter do things on another program, but the enter is still tied to the AutoIT GUI (which still has the button highlighted).
       
      Here's the important part of my code:
      $MY_GUI = GUICreate("Check.exe", 400, 300, ((@DesktopWidth / 2) - 200), -500) WinSetOnTop($MY_GUI, "", 1) ;Keeps the window on the top. $Button1 = GUICtrlCreateButton("Pass (Ctrl+P)", 40, 250, 120, 40, $WS_GROUP) GUICtrlSetFont(-1, 12, 400, 0, "MS Sans Serif") $Button2 = GUICtrlCreateButton("Fail (Ctrl+F)", 240, 250, 120, 40, $WS_GROUP) GUICtrlSetFont(-1, 12, 400, 0, "MS Sans Serif") $GUIText = GUICtrlCreateLabel("", 20, 10, 360, 230) GUICtrlSetFont(-1, 13, 400, 0, "MS Sans Serif") GUICtrlSetData($GUIText, Execute($stepMessage[$step])) $showGUI = "True" GUISetState(@SW_SHOW) While($showGUI = "True") $buttonPressed = GUIGetMsg() Switch $buttonPressed Case $Button1 ;Pass $pass = "True" $buttonPressed = 0 $showGUI = "False" GUISetState(@SW_HIDE) Case $Button2 ;Fail $buttonPressed = 0 $showGUI = "False" GUISetState(@SW_HIDE) While($message = "") $message = InputBox("Check.exe", "Please enter the reason the step failed." & @CRLF, "", "", 300, 200, ((@DesktopWidth / 2) - 150), -400) WEnd Return $message EndSwitch WEnd Local $pass = "False" ;Whether "Pass" or "Fail" was pressed. Local $failLog = xxxfunc($pass) ;Returns a message to log if the step failed. ##THIS CALLS THE CODE SNIPPET ABOVE## FileWrite($file, _Now() & ": Step " & $step & getStatus($pass) & "and took " & Ceiling(TimerDiff($timer) / 1000) & " seconds." & @CRLF) If($failLog <> "") Then FileWrite($file, "Logged comment: " & $failLog & @CRLF) EndIf WinActivate("[TITLE:ProgramName]") ;Hotkeys: HotKeySet("^{p}", "pressPass") HotKeySet("^{f}", "pressFail") Func pressPass() $buttonPressed = $Button1 EndFunc Func pressFail() $buttonPressed = $Button2 EndFunc  
      The GUI's button/hotkey pressing works correctly.
      The same WinActivate code works in another script of mine.
      Together, WinActivate is not take "Active" away from the GUI's last-pressed button. How do I fix this?
       
      Thank you in advance.
    • fatpig
      By fatpig
      Dear AutoIT Community.
      I am currently working on a program that will display lots of images in a scroll down GUI.
      I create the GUI based on the number of images, which works fine.
      But all images I place using GuiCtrlCreatePic above a threshold of around 32000 pixels (cant say exactly) are placed at negative locations and finally will reach 0 again
      and will then populate on top of the images placed there before.
      For $i = 1 To $Images[0] ; Get picture dimensions $hImage = _GDIPlus_ImageLoadFromFile($ImgRep & $Images[$i]) $iX = _GDIPlus_ImageGetWidth($hImage) $iY = _GDIPlus_ImageGetHeight($hImage) _GDIPlus_ImageDispose($hImage) ; Resize & place images in GUI $Pic[$i] = GUICtrlCreatePic($ImgRep & $Images[$i], $Spacer, Round($yPos, 0), $MaxImgWidth, $MaxImgWidth * ($iY / $iX)) $yPos = $yPos + $MaxImgWidth * ($iY / $iX) + $Spacer $log = $log & "|" & $yPos $currentlut = $Images[1] Next I have found a limit at 32767 pixels for some GUI elements when googling around.
      Can someone tell me how to circumvent that?
      thanks!
      cheers
      Felix