Removing a dimension from an array

[JohnOne]

It still takes 0 ms to just not reference array[n][0]

[Mechaflash]

Unfortunately

ReDim $aArray[5]

doesn't work. As soon as you change the number of dimensions the complete content of the array is dropped.

According to the help file: "The number of dimensions must remain the same, or the old array will be forgotten during the ReDim."

omg ur right... XD. Just checked the output, and all the data was cleared from the array after the ReDim. First method out the window then.

[Mechaflash]

Is .007 seconds really that much of a difference?

It's actually .07 seconds =P. 7/100ths of a second doesn't mean much, however the margin is 35%, which is significant if the array was huge and/or if the system is running low-end hardware (think Pentium II/III/IV Single-Cores @ < 2.2GHz, and 512mb RAM)

Edited June 26, 2012 by mechaflash213

[BrewManNH]

It's actually .07 seconds =P. 7/100ths of a second doesn't mean much, however the margin is 35%, which is significant if the array was huge and/or if the system is running low-end hardware (think Pentium II/III/IV Single-Cores @ < 2.6GHz, and 512mb RAM)

It's actually 0.006303 seconds (0.018022 - 0.011719), your figures from your post copied verbatim. Yes, the difference is 35%, but in numbers too small to matter. You're doing this on an array with almost 4000 "rows", that's pretty substantial. Plus, if you're running it on $hit hardware, you should expect EVERYTHING to run slower.

I still say, if they both worked the same, and the difference was 0.006303, you could reasonably use either one.

[Mechaflash]

It's actually 0.006303 seconds (0.018022 - 0.011719)

Whoops... I'm trippin'

[czardas]

I got a bit confused by some of the posts in this thread yesterday. Anyway I decided to see how much slower using _ArraySwap would be, The difference is just over 5 times slower. So mechaflash213 - it does make quite a difference

#include <Array.au3>

Dim $aArray[1][2] = [[0,0]]
$iTimer = TimerInit()

; Swapping Elements
For $i = 1 To 10000
    _ArraySwap($aArray[0][0], $aArray[0][1])
Next
ConsoleWrite(TimerDiff($iTimer) & @LF)

$iTimer = TimerInit()

; Overwriting Elements
For $i = 1 To 10000
    $aArray[0][0] = $aArray[0][1]
Next
ConsoleWrite(TimerDiff($iTimer) & @LF)

swapping 2 columns ... 55.981137267446

overwriting 1 column .. 10.0557473086663

Edited June 27, 2012 by czardas

[UEZ]

Here a crazy and ineffective idea:

expandcollapse popup

#include <Array.au3>
Global $aTest[4][2] = [ [1, 2], _
                                        [4, 5], _
                                        [7, 8], _
                                        [10, 11]]

$aRot = ArrayRotate($aTest, -180)
ReDim $aRot[UBound($aRot)][1]
$aRot = ArrayRotate($aRot, -180)
_ArrayDisplay($aRot)

Func ArrayRotate($aArray, $iDeg) ;coded by UEZ 2012 build 2012-02-15
    If Not IsArray($aArray) Then Return SetError(1, 0, 0) ;not an array
    If Not UBound($aArray, 0) = 2 Then Return SetError(2, 0, 0) ;not a 2D array
    If Mod($iDeg, 90) Then Return SetError(3, 0, 0) ;only 90° rotations allowed
    Local $i, $j, $k = 0, $l = 0
    Switch $iDeg
        Case 90, -270
            Local $aRotated[UBound($aArray, 2)][UBound($aArray)]
            For $i = 0 To UBound($aArray, 2) - 1
                For $j = UBound($aArray) -1 To 0 Step - 1
                    $aRotated[$i][$k] = $aArray[$j][$i]
                    $k += 1
                Next
                $k = 0
            Next
            Return $aRotated
        Case 270, -90
            Local $aRotated[UBound($aArray, 2)][UBound($aArray)]
            For $i = UBound($aArray, 2) - 1 To 0 Step - 1
                For $j = 0 To UBound($aArray) - 1
                    $aRotated[$l][$k] = $aArray[$j][$i]
                    $k += 1
                Next
                $l += 1
                $k = 0
            Next
            Return $aRotated
        Case 180, -180
            Local $aRotated[UBound($aArray)][UBound($aArray, 2)]
            For $i = UBound($aArray) - 1 To 0 Step - 1
                For $j = UBound($aArray, 2) - 1 To 0 Step - 1
                    $aRotated[$l][$k] = $aArray[$i][$j]
                    $k += 1
                Next
                $l += 1
                $k = 0
            Next
            Return $aRotated
    EndSwitch
EndFunc

Br,

UEZ

Edited June 27, 2012 by UEZ

[czardas]

UEZ - Crazy or not, I very much like it. Especially the 90 rotation.

I have in mind a project to do this with multiline text (adding trailing white spaces to form a rectangle of characters). Should be fun to play with.

I now have it working, but my first attempt contained a stupid error, and the days of the week rotated 90 degrees clockwise returned.

dardum
dardum
dardum
dardum
dardum
dardum

I thought it was trying to tell me something. .

Edited June 27, 2012 by czardas