Jump to content
Sign in to follow this  
grimmlock

AutoScroll and return values

Recommended Posts

Hello,

I have a gui that includes a list which pulls it data from a txt file. What I was hoping for, is to get some help with getting a auto scroller that will highlight the line and then perform an action and display the results in a seperate readonly input box. In this case I have a list of computers (by name) that I would like to have ping every couple of seconds (one at a time) and display the results (either ping time or request timed out) in a seperate (read only) input box.

Here is what I have so far ...

GUICreate("Am I Asleep?", 500, 235)
GUISetState(@SW_SHOW)
$List = FileRead("C:\List.txt")
Local $Input1 = GUICtrlCreateList("", 20, 20, 150, 150, BitOr($ES_READONLY, $WS_BORDER, $WS_VSCROLL))
GUICtrlSetLimit(-1, 200) ; to limit horizontal scrolling
GUICtrlSetData(-1, $List)
Local $Button_1 = GUICtrlCreateButton("Ping", 20, 200, 75)
Local $Button_2 = GUICtrlCreateButton("Wake Up", 100, 200, 75)
Local $Display1 = GUICtrlCreateInput("", 200, 20, 115, 20, $ES_READONLY)


While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
Exit


Case $Button_1

local $var = Ping(GUICtrlRead($Input1), 250)

If $var <> 0 Then
GUICtrlSetData($Display1, $var & " ms", "")
GUICtrlSetBkColor($Display1, 0x00ff00)
GUICtrlSetColor ($Display1, 0x000000)

Else
;SplashTextOn("Error", @error, 100, 50)
;Sleep(1000)
;SplashOff()
GUICtrlSetData($Display1, " Request Timed Out ")
GUICtrlSetBkColor($Display1, 0)
GUICtrlSetColor ($Display1, 0xffffff)
; GUICtrlSetData($Input1, "")

EndIf

Case $Button_2
MsgBox(0, "Test", "Test")

EndSwitch

WEnd

Thanks

Grimm

Edited by grimmlock

Thanks

Grimm

Share this post


Link to post
Share on other sites

grimmlock,

Do you mean something like this: :huh:

#include <GUIConstantsEx.au3> ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
#include <WindowsConstants.au3> ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
#include <GUIListBox.au3>
#include <EditConstants.au3> ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<

GUICreate("Am I Asleep?", 500, 235)

$List = "Comp 1|Comp 2|Comp 3|Comp 4|Comp 5"
Local $Input1 = GUICtrlCreateList("", 20, 20, 150, 150, BitOR($ES_READONLY, $WS_BORDER, $WS_VSCROLL))
GUICtrlSetLimit(-1, 200) ; to limit horizontal scrolling
GUICtrlSetData(-1, $List)
Local $Button_1 = GUICtrlCreateButton("Ping", 20, 200, 75)
Local $Button_2 = GUICtrlCreateButton("Wake Up", 100, 200, 75)
Local $Display1 = GUICtrlCreateInput("", 200, 20, 115, 20, $ES_READONLY)

GUISetState(@SW_SHOW)

; The index of the current item in the list
$iIndex = 0
; The number of items
$iCount = _GUICtrlListBox_GetCount($Input1)

; Click the top item
_GUICtrlListBox_ClickItem($Input1, $iIndex)


While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
        Case $Button_1
            ; Simulate a Ping
            $var = Random(0, 1, 1)
            If $var <> 0 Then
                GUICtrlSetData($Display1, $var & " ms")
                GUICtrlSetBkColor($Display1, 0x00FF00)
                GUICtrlSetColor($Display1, 0x000000)
            Else
                GUICtrlSetData($Display1, " Request Timed Out ")
                GUICtrlSetBkColor($Display1, 0)
                GUICtrlSetColor($Display1, 0xFFFFFF)
            EndIf
            ; Increase the index and loop if necessary
            $iIndex = Mod($iIndex + 1, $iCount)
            ; Click the next item
            _GUICtrlListBox_ClickItem($Input1, $iIndex)
        Case $Button_2
            MsgBox(0, "Test", "Test")
    EndSwitch

WEnd

By the way, take note of the lines I had to add (<<<<<<<<<<<<<<) to get the basic posted script to even run. If you post an example, please make sure it runs - not everyone will take the time to add all the required includes, etc. ;)

M23


Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

Yes that is so close, let me apologize, I meant to copy and paste the #includes :(

Is there a way to set a timer? so that it waits 1 or 2 seconds and then moves onto the next line?

Thanks,

Grimm


Thanks

Grimm

Share this post


Link to post
Share on other sites

grimmlock,

A timer like that is very easy to implement - use TimerInit/Diff and increase the index each time they fire. :)

Have a go yourself and see how you get on - you know where I am if you get stuck. ;)

M23


Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

So now is scrolls but does not return the correct results. Could you take a look at this and show me where I went wrong please?

If $var <> 0 Then
GUICtrlSetData($Display1, $var & " ms", "")
GUICtrlSetBkColor($Display1, 0x00ff00)
GUICtrlSetColor ($Display1, 0x000000)
;Sleep(1000)
Do
$iIndex = Mod($iIndex + 1, $iCount)
_GUICtrlListBox_ClickItem($Input1, $iIndex)
Local $Begin = TimerInit()
Sleep(3000)
Local $dif = TimerDiff($Begin)
Until @error

Thanks

Grimm


Thanks

Grimm

Share this post


Link to post
Share on other sites

grimmlock,

Rather than critique your code, I did it like this: ;)

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GUIListBox.au3>
#include <EditConstants.au3>

; Declare a flag
Global $fPing = False

GUICreate("Am I Asleep?", 500, 235)
GUISetState(@SW_SHOW)
$List = "Comp 1|Comp 2|Comp 3|Comp 4|Comp 5"
Local $Input1 = GUICtrlCreateList("", 20, 20, 150, 150, BitOR($ES_READONLY, $WS_BORDER, $WS_VSCROLL))
GUICtrlSetLimit(-1, 200) ; to limit horizontal scrolling
GUICtrlSetData(-1, $List)
Local $Button_1 = GUICtrlCreateButton("Ping", 20, 200, 75)
Local $Button_2 = GUICtrlCreateButton("Wake Up", 100, 200, 75)
Local $Display1 = GUICtrlCreateInput("", 200, 20, 115, 20, $ES_READONLY)

$iIndex = 0
_GUICtrlListBox_ClickItem($Input1, $iIndex)
$iCount = _GUICtrlListBox_GetCount($Input1)

; Get a timestamp
$iBegin = TimerInit()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button_1
            Switch GUICtrlRead($Button_1)
                ; What does the button tell us we are going to do?
                Case "Ping"
                    ; We need to ping
                    $fPing = True
                    ; And set the button text accordingly
                    GUICtrlSetData($Button_1, "Stop")
                Case Else
                    ; Now we need to stop pinging
                    $fPing = False
                ; And again change the button text
                    GUICtrlSetData($Button_1, "Ping")
            EndSwitch
        Case $Button_2
            MsgBox(0, "Test", "Test")
    EndSwitch

    ; Are we pinging?
    If $fPing Then
        ; Have we waited long enough since the last ping?
        If TimerDiff($iBegin) > 1000 Then ; 1 sec delay
            ; Click the current item
            _GUICtrlListBox_ClickItem($Input1, $iIndex)
            ; Read the current item
            $sItem = GUICtrlRead($Input1)
            ; Simulate a Ping
            $var = Random(0, 1, 1)
            If $var <> 0 Then
                GUICtrlSetData($Display1, $sItem & " - " & $var & " ms")
                GUICtrlSetBkColor($Display1, 0x00FF00)
                GUICtrlSetColor($Display1, 0x000000)
            Else
                GUICtrlSetData($Display1, $sItem & " - " & " Timed Out ")
                GUICtrlSetBkColor($Display1, 0)
                GUICtrlSetColor($Display1, 0xFFFFFF)
            EndIf
            ; Reset the timestamp for the next ping
            $iBegin = TimerInit()
            ; Increase the index to select the next item
            $iIndex = Mod($iIndex + 1, $iCount)

        EndIf
    EndIf

WEnd

All clear? :)

M23


Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

I think so :) Thank you for teaching me, for only knowing this program for a week or so, I think I am doing pretty well :)

Thanks M23

Grimm


Thanks

Grimm

Share this post


Link to post
Share on other sites

grimmlock,

My pleasure - that is why I come here. ;)

M23


Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

I know, I know....I am going to post another question about this

What I want to do is have a drop down box containing several (subnets) and each time someone chooses one of the items it displays a different list

Here is what I have (could you please take a look at it :))

#include <File.au3>
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <Constants.au3>
#include <GUIConstantsEx.au3>
#include <GUIConstants.au3>
#include <GUIListBox.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <Array.au3>

; Declare a flag
Global $fPing = False

GUICreate("Am I Asleep?", 450, 900)
GUISetState(@SW_SHOW)
$List1 =  ("Test1111|Comp2|Comp3")
$List2 = ("Testing1234|Testing54321")
$List3 = ("Tst1234|Tst4321")
$List4 = ("Choose a Branch")
Local $Combo1 = GUICtrlCreateCombo("", 10, 20, 100, 10)
GUICtrlSetData(-1, "Pick One|Branch1|Branch2|Branch3", "Pick One")
Local $Input1 = GUICtrlCreateList("", 120, 20, 150, 815, BitOr($ES_READONLY, $WS_BORDER, $WS_VSCROLL))
GUICtrlSetLimit(-1, 200) ; to limit horizontal scrolling
GUICtrlSetData(-1, $List4)
Local $Button_1 = GUICtrlCreateButton("Ping", 20, 840, 75)
Local $Display1 = GUICtrlCreateInput("", 300, 20, 115, 20, $ES_READONLY)

$iIndex = 0
_GUICtrlListBox_ClickItem($Input1, $iIndex)
$iCount = _GUICtrlListBox_GetCount($Input1)

; Get a timestamp
$iBegin = TimerInit()

While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
Exit

Case $Button_1
            Switch GUICtrlRead($Button_1)
                ; What does the button tell us we are going to do?
                Case "Ping"
                    ; We need to ping
                    $fPing = True
                    ; And set the button text accordingly
                    GUICtrlSetData($Button_1, "Stop")
                Case Else
                    ; Now we need to stop pinging
                    $fPing = False
                ; And again change the button text
                    GUICtrlSetData($Button_1, "Ping")
            EndSwitch

If $fPing Then
        ; Have we waited long enough since the last ping?
        If TimerDiff($iBegin) > 1000 Then ; 1 sec delay
            ; Click the current item
            _GUICtrlListBox_ClickItem($Input1, $iIndex)
            ; Read the current item
            $sItem = GUICtrlRead($Input1)
            ; Simulate a Ping
            $var = Ping(GUICtrlRead($Input1), 999)
            If $var <> 0 Then
                GUICtrlSetData($Display1, $sItem & " - " & $var & " ms")
                GUICtrlSetBkColor($Display1, 0x00FF00)
                GUICtrlSetColor($Display1, 0x000000)
            Else
                GUICtrlSetData($Display1, $sItem & " - " & " Timed Out ")
                GUICtrlSetBkColor($Display1, 0)
                GUICtrlSetColor($Display1, 0xFFFFFF)
            EndIf
            ; Reset the timestamp for the next ping
            $iBegin = TimerInit()
            ; Increase the index to select the next item
            $iIndex = Mod($iIndex + 1, $iCount)

        EndIf
    EndIf

Case $Combo1
Switch GUICtrlRead($Combo1)
Case "Branch1"
GUICTRLSetData($Input1, "")
GUICTRLSetData($Input1, $List1)

Case "Branch2"
GUICTRLSetData($Input1, "")
GUICtrlSetData($Input1, $List2)

Case Else
GUICTRLSetData($Input1, "")
GUICTRLSetData($Input1, $List3)

EndSwitch

EndSwitch

WEnd

It seems to want to ping the first item on each of the list (so the selection of the "list" from the drop down box works) however it only wants to ping the top item and not scroll and ping like it used to.

Thanks

Grimm


Thanks

Grimm

Share this post


Link to post
Share on other sites

grimmlock,

You need to have the elements of the script in the correct place - you had the "If $fPing" line inside the $sButton1 Case structure so it only fired once as the button was pressed. :(

Take a look at this version: ;)

#include <File.au3>
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <Constants.au3>
#include <GUIConstantsEx.au3>
#include <GUIConstants.au3>
#include <GUIListBox.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <Array.au3>
#include <WinAPI.au3>
#include <GUIComboBox.au3>
#include <Constants.au3>

; Declare a flag
Global $fPing = False

GUICreate("Am I Asleep?", 450, 900)
GUISetState(@SW_SHOW)
$List1 = ("Test1111|Comp2|Comp3")
$List2 = ("Testing1234|Testing54321")
$List3 = ("Tst1234|Tst4321")

Local $Combo1 = GUICtrlCreateCombo("", 10, 20, 100, 10)
GUICtrlSetData(-1, "Branch1|Branch2|Branch3")

; Set Cuebanner rather than add an extra element to the combo  <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
; Get handle of combo edit
$tInfo = $tagCOMBOBOXINFO
_GUICtrlComboBox_GetComboBoxInfo($Combo1, $tInfo)
$hComboEdit = DllStructGetData($tInfo, "hEdit")
; Write CueBanner
$tText = _WinAPI_MultiByteToWideChar("Select one")
_SendMessage($hComboEdit, $EM_SETCUEBANNER, False, $tText, 0, "wparam", "struct*")

Local $Input1 = GUICtrlCreateList("Choose a branch", 120, 20, 150, 815, BitOR($ES_READONLY, $WS_BORDER, $WS_VSCROLL))
GUICtrlSetLimit(-1, 200) ; to limit horizontal scrolling
Local $Button_1 = GUICtrlCreateButton("Ping", 20, 840, 75)
Local $Display1 = GUICtrlCreateInput("", 300, 20, 115, 20, $ES_READONLY)

$iIndex = 0
_GUICtrlListBox_ClickItem($Input1, $iIndex)
$iCount = _GUICtrlListBox_GetCount($Input1)

; Get a timestamp
$iBegin = TimerInit()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit

        Case $Button_1
            Switch GUICtrlRead($Button_1)
                ; What does the button tell us we are going to do?
                Case "Ping"
                    ; We need to ping
                    $fPing = True
                    ; And set the button text accordingly
                    GUICtrlSetData($Button_1, "Stop")
                    ; Disable the combo <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
                    GUICtrlSetState($Combo1, $GUI_DISABLE)
                Case Else
                    ; Now we need to stop pinging
                    $fPing = False
                    ; And again change the button text
                    GUICtrlSetData($Button_1, "Ping")
                    ; Enable the combo <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
                    GUICtrlSetState($Combo1, $GUI_ENABLE)
            EndSwitch

        Case $Combo1
            Switch GUICtrlRead($Combo1)
                Case "Branch1"
                    ;GUICtrlSetData($Input1, "") ; No need - just start the data with "|" <<<<<<<<<<<<<<<<<<<<<<<<<<<<<
                    GUICtrlSetData($Input1, "|" & $List1)
                Case "Branch2"
                    GUICtrlSetData($Input1, "|" & $List2)
                Case Else
                    GUICtrlSetData($Input1, "|" & $List3)
            EndSwitch
            ; Get new count <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
            $iCount = _GUICtrlListBox_GetCount($Input1)
    EndSwitch

    If $fPing Then ; This must be outside the Switch <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
        ; Have we waited long enough since the last ping?
        If TimerDiff($iBegin) > 1000 Then ; 1 sec delay
            ; Click the current item
            _GUICtrlListBox_ClickItem($Input1, $iIndex)
            ; Read the current item
            $sItem = GUICtrlRead($Input1)
            ; Simulate a Ping
            $var = Random(0, 1, 1) ; Ping(GUICtrlRead($Input1), 999)
            If $var <> 0 Then
                GUICtrlSetData($Display1, $sItem & " - " & $var & " ms")
                GUICtrlSetBkColor($Display1, 0x00FF00)
                GUICtrlSetColor($Display1, 0x000000)
            Else
                GUICtrlSetData($Display1, $sItem & " - " & " Timed Out ")
                GUICtrlSetBkColor($Display1, 0)
                GUICtrlSetColor($Display1, 0xFFFFFF)
            EndIf
            ; Reset the timestamp for the next ping
            $iBegin = TimerInit()
            ; Increase the index to select the next item
            $iIndex = Mod($iIndex + 1, $iCount)
        EndIf
    EndIf

WEnd

I have also changed a few other elements. You have a CueBanner in the combo (much nicer than an extra element); the combo is now disabled if you are "Pinging" (try selecting a new value in the combo if you do not do this ;)); recalculated the item count each time you select a new list; and showed how to replace the list in the edit with a single command.

All good now? :)

M23


Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

Can I ask one more question, how do I hide the Listbox at app startup and when no branch is selected, However have the listbox show when a "branch" is selected?

Thanks

Grimm


Thanks

Grimm

Share this post


Link to post
Share on other sites

grimmlock,

Just code exactly as you described: ;)

hide the Listbox at app startup

Local $Input1 = GUICtrlCreateList("Choose a branch", 120, 20, 150, 815, BitOR($ES_READONLY, $WS_BORDER, $WS_VSCROLL))
GUICtrlSetLimit(-1, 200) ; to limit horizontal scrolling
; Hide the list on creation <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
GUICtrlSetState(-1, $GUI_HIDE)

have the listbox show when a "branch" is selected

Case $Combo1
    ; Show the list now there is a selection <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
    GUICtrlSetState($Input1, $GUI_SHOW)
    Switch GUICtrlRead($Combo1)

All clear? :)

M23


Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

This is what I was missing, thank you

; Show the list now there is a selection <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<

GUICtrlSetState($Input1, $GUI_SHOW)

All Clear :)

Thanks

Grimm


Thanks

Grimm

Share this post


Link to post
Share on other sites

Should I start a new post?

Would an array be the best solution (in this case) if I wanted to have a text file (with a computer name, IP address, and mac address) and create a new button that when pressed would use the data in the file to do a wake on lan?

I already have the wake on lan script. It just requires the ip address and mac address (which I have) for the computers in my text file.

Please let me know if I need to create a new post :)

Thanks

Grimm


Thanks

Grimm

Share this post


Link to post
Share on other sites

grimlock,

With so little information on how exactly you are collating and using the data it is impossible to say whether an array would be the "best" solution. Certainly using an array allows you to use a single index value to access all the information available - which is why they are so useful and an essential part of a preogrammer's toolkit. :)

As to opening a new thread - if the question is not really related to the previous posts, I would recommend a new thread every time. ;)

M23


Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

However my next question which still relates to this post (I think)

Is there a way to associate a display name (TestPC) with a hidden IP, so that when I select the PC TestPC or TestPC2 is automatically knows the IP of those 2 computers?q

If so how would I go about doing this?

Thanks

Grimm


Thanks

Grimm

Share this post


Link to post
Share on other sites

grimmlock,

Assuming you know these "hidden IPs" (see what I mean about giving us more info ;)) then an array would be a good way to link the 2 items as the same index would let you access both items of information. This should show you how to do it. :)

#include <GUIConstantsEx.au3>
#include <Array.au3>

; Declare the array holding the PC names and their IPs
Global $aServers[2][2] = [["PC 1", "test.test1.test1"], ["PC 2", "test1.test1.test1"]]

GUICreate("test", 400, 400)
GUISetState(@SW_SHOW)

Local $Combo1 = GUICtrlCreateCombo("", 10, 10, 100, 20)
GUICtrlSetData(-1, "test|Branch Servers")
Local $Input1 = GUICtrlCreateList("", 10, 50, 100, 50)
Local $button1 = GUICtrlCreateButton("Notepad", 200, 50, 100, 100)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit

        Case $Combo1
            Switch GUICtrlRead($Combo1)
                Case "Branch Servers"
                    ; Create a list of the PC names from the array
                    $list1 = ""
                    For $i = 0 To UBound($aServers) - 1
                        $list1 &= "|" & $aServers[$i][0]
                    Next
                    GUICtrlSetData($Input1, $list1)
                Case "test"

            EndSwitch

        Case $button1
            Local $Input3 = GUICtrlRead($Input1)
            ; Find the PC in the array
            $iIndex = _ArraySearch($aServers, $Input3)
            ; Did we find a match?
            If $iIndex <> -1 Then
                ; Get the associated IP and trim as required
                Local $Input4 = StringTrimRight($aServers[$iIndex][1], 12)
                Run("Notepad.exe")
                Sleep(1000)
                Send($Input4)
                Sleep(1000)
            EndIf

    EndSwitch
WEnd

All clear? :)

M23


Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

Make sense However using this script, if I have multiple text files all of which look like this

192.168.x.202 testpc02.testnet.local 0023ae77bf9d

192.168.x.203 testpc01.testnet.local 0019d1f613c4

192.168.x.204 testpc03.testnet.local 0019d1f613be

192.168.x.205 testpc05.testnet.local b8ac6f25fc46

192.168.x.206 testpc04.testnet.local 0023ae786fbe

How would get this:

#include <GUIConstantsEx.au3>
#include <GUIConstants.au3>
#include <String.au3>

GUICreate("test", 400, 400)
GUISetState(@SW_SHOW)
$list1 = FileRead("C:\test.txt") ; <<<<<< file contains list of PCs listed above
$list2 = FileRead("c:\test2.txt") ; <<<<<<<< file contains just test123

Local $Combo1 = GUICtrlCreateCombo("", 10, 10, 100, 20)
GUICtrlSetData(-1, "test|Branch Servers")
Local $Input1 = GUICtrlCreateList("", 10, 50, 100, 50)
Local $button1 = GUICtrlCreateButton("Notepad", 200, 50, 100, 100)
Local $button2 = GUICtrlCreateButton("Wake On Lan", 200, 200, 100, 100) ; I want to be able to run my Wake On Lan function using the above PC information


While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
Exit

Case $Combo1
Switch GUICtrlRead($Combo1)
Case "Branch Servers"
;~ ConsoleWrite("Hit" & @CRLF)
GUICtrlSetData($Input1, "|" & $list1)
Case "test"
;~ ConsoleWrite("Hit" & @CRLF)
GUICtrlSetData($Input1, "|" & $list2)
EndSwitch

Case $button1
Local $Input3 = GUICtrlRead($Input1)
Local $Input4 = StringTrimRight(GUICtrlRead($Input1), 12)

If StringInStr(GuiCtrlRead($Input1), ".local") Then
Run("Notepad.exe")
Sleep(1000)
Send($Input4)
Sleep(1000)
Else
Run("Notepad.exe")
Sleep(1000)
Send($Input3)
Sleep(1000)
EndIf

Case $button2
WakeonLan()


EndSwitch
WEnd

Func WakeonLan()

$IPAddress = ; IP address of selected item in list box
$MACAddress = ; MAC address of selected item in list box


UDPStartUp()

$connexion = UDPOpen($IPAddress, 7)
$res = UDPSend($connexion, GenerateMagicPacket($MACAddress))
MsgBox(0, "", $res)

UDPCloseSocket($connexion)
UDPShutdown()

EndFunc

; ===================================================================
; Functions
; ===================================================================


; This function convert a MAC Address Byte (e.g. "1f") to a char
Func HexToChar($strHex)

Return Chr(Dec($strHex))

EndFunc

; This function generate the "Magic Packet"
Func GenerateMagicPacket($strMACAddress)

$MagicPacket = ""
$MACData = ""

For $p = 1 To 11 Step 2
$MACData = $MACData & HexToChar(StringMid($strMACAddress, $p, 2))
Next

For $p = 1 To 6
$MagicPacket = HexToChar("ff") & $MagicPacket
Next

For $p = 1 To 16
$MagicPacket = $MagicPacket & $MACData
Next

Return $MagicPacket

EndFunc

The end script will have 18 lists :

Thanks

Grimm

Edited by grimmlock

Thanks

Grimm

Share this post


Link to post
Share on other sites

grimmlock,

Just who is writing this script - you or me? :D

I would solve your problem like this:

- Save all the lists as "List_1.txt", etc.

- Then amend the script so that you read the relevant list when selected in the combo like this:

#include <GUIConstantsEx.au3>
#include <GUIConstants.au3>
#include <File.au3>
#include <Array.au3>

; Declare a Global array to hold the data for the currently selected list
Global $aPCData

GUICreate("test", 400, 400)
GUISetState(@SW_SHOW)

Local $cCombo = GUICtrlCreateCombo("", 10, 10, 100, 20)
GUICtrlSetData(-1, "List_1|List_2|List_3") ; So you have all the lists able to be selected from the combo
Local $cList = GUICtrlCreateList("", 10, 50, 100, 50)
Local $cButton_1 = GUICtrlCreateButton("Notepad", 200, 50, 100, 100)
Local $cButton_2 = GUICtrlCreateButton("Wake On Lan", 200, 200, 100, 100)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit

        Case $cCombo
            ; Read the selection
            $sSelection = GUICtrlRead($cCombo)
            ; Open the file and get back a a list
            $sList = _ReadFile($sSelection)
            ; Fill the List with that data
            GUICtrlSetData($cList, $sList)

        Case $cButton_1

        Case $cButton_2

    EndSwitch
WEnd

Func _ReadFile($sFileName)

    ConsoleWrite(@ScriptDir & "\" & $sFileName & ".txt" & @CRLF)

    ; Read the required file into an array
    Local $aFileContents
    _FileReadToArray(@ScriptDir & "\" & $sFileName & ".txt", $aFileContents)
    ConsoleWrite(@error & @CRLF)
    ; Now transfer the data in that array into one we can use

    ; Firstly resize the global array which we use elsewhere
    Global $aPCData[$aFileContents[0] + 1][3]
    ; And reset the list contents
    Local $sList = ""

    ; Now loop through the data transferring it to the new array and to to the list we display
    For $i = 1 To $aFileContents[0]
        ; Split the line on the spaces
        $aSplit = StringSplit($aFileContents[$i], " ")
        ; And add the 3 parts to the larger array
        $aPCData[$i][0] = $aSplit[2]
        $aPCData[$i][1] = $aSplit[1]
        $aPCData[$i][2] = $aSplit[3]
        ; Then add the name to the list
        $sList &= "|" & $aSplit[2]
    Next

    ; And just for interest, this is what we get in the array
    _ArrayDisplay($aPCData)

    ; Finally return the list to be added to the control in the GUI
    Return $sList

EndFunc

- Use the technique of searching the array to find the other associated data you need as I showed you a few posts above - it is now all in the $aPCData array. :)

All clear? ;)

M23


Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
Sign in to follow this  

  • Recently Browsing   0 members

    No registered users viewing this page.

  • Similar Content

    • By paw
      I use SetSoundDevice to control my audio devices but the UI was either
       
      blurry like this:
      or unusable like this:

      so I made this horrible thing to add scaling to the GUI:
      #Region ;**** Directives created by AutoIt3Wrapper_GUI **** #AutoIt3Wrapper_Change2CUI=y #AutoIt3Wrapper_Res_HiDpi=y #AutoIt3Wrapper_AU3Check_Parameters=-w 3 -w 4 -w 5 #AutoIt3Wrapper_Run_Au3Stripper=y #Au3Stripper_Parameters=/sf /sv /rm #EndRegion ;**** Directives created by AutoIt3Wrapper_GUI **** #include <File.au3> ;~ _convertGUI("") If $CmdLine[0] <> 0 Then _convertGUI($CmdLine[1]) Func _convertGUI($sFilePath) If $sFilePath <> "" Then Local $aArray = FileReadToArray($sFilePath) Else ;TEST DATA Local $aArray[6] = ['$H_Res_Language = GUICtrlCreateProgress(5, 120, 210 + 25, 480, 20, BitOR($GUI_SS_DEFAULT_COMBO, $CBS_SIMPLE)) ; $CBS_DROPDOWNLIST)', _ 'Local $h_Ok = GUICtrlCreateButton("Ok", 72, 224, 81, 33, 0)', _ 'GUICreate($Warning_TiTle, 700, 310, -1, -1, $WS_SIZEBOX + $WS_SYSMENU + $WS_MINIMIZEBOX)', _ 'GUICtrlCreateLabel("Output type: ", 30, 130, 65, 20) ;, $SS_RIGHT)', _ '$H_FieldNameEdit = GUICtrlCreateEdit($INP_FieldNameEdit, 100,260+25, 500, 150 - 25) ;comment', 'Local $H_CANCEL = GUICtrlCreateGraphic("Cancel", 224, 224, 97, 33, 0)'] EndIf Local $hTimer = TimerInit(), $iGUIElementCount = 0, $sResult = "", $sFileName = "", $sDrive = "", $sDir = "", $sExtension = "" If @Compiled Then _PathSplit($sFilePath, $sDrive, $sDir, $sFileName, $sExtension) $sFileName = StringRegExpReplace($sFilePath, "^.*\\", "") EndIf For $i = 0 To (UBound($aArray) - 1) If StringRegExp($aArray[$i], "GUICtrlCreate|GUICreate") Then $sResult = _splitComma($aArray[$i]) If Not @error Then $aArray[$i] = $sResult $iGUIElementCount += 1 EndIf Next ConsoleWrite("t = " & TimerDiff($hTimer) & " GUI elements = " & $iGUIElementCount & " lines = " & (UBound($aArray) - 1) & @CRLF) If $sFileName <> "" Then Local $hFile = FileOpen("edited." & $sFileName, 2) _FileWriteFromArray("edited." & $sFileName, $aArray) FileClose($hFile) EndIf Exit EndFunc ;==>_convertGUI Func _splitComma($sString) Local $sSplitResult = "", $sTrimmedR = "", $sTrimmedL = "" Local $aSplit = StringSplit($sString, ',') If Not @error Then $sTrimmedR = "" $sTrimmedL = "" For $j = 1 To $aSplit[0] If StringRegExp($aSplit[1], "(?:.GUICtrlCreateGraphic|GUICtrlCreateProgress|GUICtrlCreateSlider|GUICtrlCreateTab|GUICtrlCreateTreeView)") Then If $j = 1 Then While StringLeft($aSplit[$j], 1) <> '(' $sTrimmedL &= StringLeft($aSplit[$j], 1) $aSplit[$j] = StringTrimLeft($aSplit[$j], 1) WEnd $aSplit[$j] = StringTrimLeft($aSplit[$j], 1) EndIf EndIf If $j = $aSplit[0] Then While StringRight($aSplit[$j], 1) <> ')' $sTrimmedR &= StringRight($aSplit[$j], 1) $aSplit[$j] = StringTrimRight($aSplit[$j], 1) WEnd $aSplit[$j] = StringTrimRight($aSplit[$j], 1) EndIf If StringRegExp($aSplit[$j], "[0-9]") And $aSplit[$j] <> -1 And $aSplit[$j] <> 0 And $aSplit[$j] <> 1 And Not StringInStr($aSplit[$j], ')') Then If StringRegExp($aSplit[$j], "\-|\+") Then ;put parenthesis around + or - $aSplit[$j] = '(' & $aSplit[$j] & ")*$g_DPI" Else $aSplit[$j] = $aSplit[$j] & "*$g_DPI" EndIf EndIf If $j < $aSplit[0] Then $sSplitResult &= $aSplit[$j] & ',' ElseIf $j = $aSplit[0] Then $sSplitResult &= $aSplit[$j] & ')' Else $sSplitResult &= $aSplit[$j] EndIf Next If $sTrimmedR <> "" Then $sSplitResult &= StringReverse($sTrimmedR) If $sTrimmedL <> "" Then $sSplitResult = $sTrimmedL & '(' & $sSplitResult Else SetError(1) Return EndIf ConsoleWrite($sSplitResult & @CRLF) Return $sSplitResult EndFunc ;==>_splitComma
      And now it looks good: 
      but it doesn't work on everything, for example the "GUICtrlCreateLabel("Output type: ", 30, 130, 65, 20) ;, $SS_RIGHT)" (from the autoit3wrapper gui)
      because the comment contains a parenthesis and it would break completely if there were variables as parameters..
      Is there some kind of parser around that I could use instead or maybe someone who has already done something like this?
    • By TXTechie
      Hello Everyone,
      I've developed my own GUI using AutoIt and I'm allowing users to minimize the GUI, but I also want to include some kind of timer so that it will automatically restore the GUI after something like 30 minutes or an hour. However, I also want them to be able to manually restore the GUI by clicking the application's icon in the taskbar.
      I've searched through the forums, but I'm not sure how to get started.
      Any ideas or functions to research are appreciated!
      Regards,
      TX Techie
    • By Rskm
      Hi, recently i created a GUI for some calculations in AutoIT.  The GUI has 2 tabs and on the first tab, it has few inputboxes where i use to click with mouse and start entering the inputs. i recently made some changes in the position of these textboxes. I made this by changing the autoit code file instead of making changes in KODA. Now i cannot click inside these textboxes with mouse. However, i can use TAB key to cycle through/enter input in these input boxes. what could have made the inputboxes not responding to mouseclicks. thanks
    • By TheDcoder
      Hi everyone,
      I am bit stumped as to why I am not able to set the time in the Date control
      #include <DateTimeConstants.au3> #include <GUIConstantsEx.au3> #include <MsgBoxConstants.au3> Example() Func Example() GUICreate("My GUI get date", 200, 200, 800, 200) Local $idDate = GUICtrlCreateDate("1953/04/25", 10, 10, 185, 20, $DTS_TIMEFORMAT) ; to select a specific default format Local $sStyle = "HH:mm:ss" GUICtrlSendMsg($idDate, $DTM_SETFORMATW, 0, $sStyle) ; Set time Local $iRet = GUICtrlSetData($idDate, '13:33:37') ConsoleWrite('GUICtrlSetData returned ' & ($iRet = 1 ? 'success' : 'failure') & @CRLF) GUISetState(@SW_SHOW) ; Loop until the user exits. While GUIGetMsg() <> $GUI_EVENT_CLOSE WEnd MsgBox($MB_SYSTEMMODAL, "Time", GUICtrlRead($idDate)) EndFunc ;==>Example The documentation for GUICtrlSetData clearly mentions that it uses the same format as GUICtrlRead:
      But I get failure
      What gives?
      Thanks for the help in advance!
    • By thedemons
      Introduction
      ImGui is a popular library written by ocornut, it can make awesome user interface based on directx. It is being used by many big apps/games.  The UI is nice and flexible, easy to use because of frame-by-frame drawing. So I decided to convert the entire ImGui library to AutoIt
      At first it's just an experiment, i converted some basic draw functions of imgui, compile to a dll, then using DllCall in autoit to call the functions. I was testing to see how much FPS i can get in autoit, and i was expected a low FPS, since autoit is slow. Suprisingly, the FPS turned out to be so high, it works really fast, even when drawing 1000 buttons at the same time. Features
      More than +270 functions converted from ImGui (compiled dll). Has 90% of the capability of what you can do in C++; Usable ImGuiIO and ImGuiStyle, so you can set whatever configurations you like. Preview
          
      Usage
      #include <WinAPI.au3> #include "ImGui.au3" ; Create a window Local $hwnd = _ImGui_GUICreate("AutoIt ImGui", 1024, 768) _WinAPI_ShowWindow($hwnd) ; Set style color _ImGui_StyleColorsLight() ;~ _ImGui_StyleColorsDark() Local $f_value = 5 While 1 ; when the user click close button on the window, this will return false if Not _ImGui_PeekMsg() Then Exit ; must call _ImGui_BeginFrame() _ImGui_Begin("Another window") _ImGui_Text("Hello there..") If _ImGui_Button("click me") Then $f_value = 5 _ImGui_SliderFloat("slider", $f_value, 2, 20) If _ImGui_IsItemHovered() Then _ImGui_ToolTip("what r u doing?") _ImGui_End() ; must call _ImGui_EndFrame() Wend  
      Remark
      Most of the functions were converted automatically. I haven't tested all of them yet, if some function doesn't work for you, please tell me. Still missing some features of ImGui, please tell me if you needed any. Run \tools\imgui-au3-setup.au3 to add _ImGui functions to SciTE auto-complete. Source Code
      Require: DirectX GitHub: imgui-autoit
×
×
  • Create New...