SQLite: unable to insert value

[COD3369]

#include <SQLite.au3>
#include <SQLite.dll.au3>
$name = "Hacker"
$con = "xxxxxxxxx"
$mob = "HTC One X"
$fult = "Software"
$est = "400"
$time = "192812"
$date = "900902"
Local $hQuery, $aRow, $sMsg
_SQLite_Startup()
_SQLite_Open('customer_database.db')
_SQLite_Exec(-1, "CREATE TABLE Customer (Name,Contact,Mobile,Fult,Estimate,Time,Date);") 
_SQLite_Exec(-1, "INSERT INTO Customer(Name,Contact,Mobile,Fult,Estimate,Time,Date) VALUES" & ($name,$con,$mob,$fult,$est,$time,$date )
_SQLite_Query(-1, "SELECT c FROM aTest ORDER BY a;", $hQuery)
_SQLite_Close()
_SQLite_Shutdown()

Where i am wrong ?

Edited August 8, 2013 by verma123

[jchd]

Probably where the error pops up.

#include <SQLite.au3>
#include <SQLite.dll.au3>
#include <Array.au3>

Local $name = "Hacker"
Local $con = "xxxxxxxxx"
Local $mob = "HTC One X"
Local $fult = "Software"
Local $est = "400"
Local $time = "192812"
Local $date = "900902"
Local $aRows, $iRows, $iCols

_SQLite_Startup()
_SQLite_Open('customer_database.db')

_SQLite_Exec(-1, "CREATE TABLE if not exists Customer (Name TEXT, Contact TEXT, Mobile TEXT, Fult TEXT, Estimate TEXT, Time TEXT, Date TEXT);")
_SQLite_Exec(-1, "INSERT INTO Customer(Name, Contact, Mobile, Fult, Estimate, Time, Date) " & _
                    "VALUES ("& _SQLite_FastEscape($name) & "," & _
                                _SQLite_FastEscape($con) & "," & _
                                _SQLite_FastEscape($mob) & "," & _
                                _SQLite_FastEscape($fult) & "," & _
                                $est & "," & _
                                $time & "," & _
                                $date & ");")
_SQLite_GetTable2d(-1, "SELECT Contact FROM customer;", $aRows, $iRows, $iCols)
_ArrayDisplay($aRows)

_SQLite_Close()
_SQLite_Shutdown()

Keep away from _SQLite_Query. Prefer *_GetTable[2d] or *_QuerySingleRow.

Declare SQLite types. Escape literal strings.

[COD3369]

jchd

 

Thanks bro