Detecting state change of checkbox using of GUIRegisterMsg

[PartyPooper]

Is there an easier (proper) way of detecting a change in the state of a checkbox other than comparing the checkbox text like I have done below?  Is there a way of using and comparing the checkbox handle rather than its text?

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Gui = GUICreate("WM_COMMAND", 390, 220)
$Checkbox1 = GUICtrlCreateCheckbox("Checkbox1", 10, 40, 90, 17)
$Checkbox2 = GUICtrlCreateCheckbox("Checkbox2", 10, 60, 90, 17)
GUISetState()

GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

Do
Until GUIGetMsg() = -3

Func WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
    Local $nID = BitAND($wParam, 0x0000FFFF) ; _WinAPI_LoWord
    Local $nNotifyCode = BitShift($wParam, 16) ; _WinAPI_HiWord
    If GUICtrlRead($nID, 1) = "Checkbox1" Then MsgBox(0, '', 'Checkbox1 has been modified') ; do some non-blocking code here
    If GUICtrlRead($nID, 1) = "Checkbox2" Then MsgBox(0, '', 'Checkbox2 has been modified') ; do some non-blocking code here
    Return $GUI_RUNDEFMSG
EndFunc

[Melba23]

PartyPooper,

Just look for the relevant event in the GUIGetMsg idle loop:

#include <GUIConstantsEx.au3>

$Gui = GUICreate("Native", 390, 220)
$Checkbox1 = GUICtrlCreateCheckbox("Checkbox1", 10, 40, 90, 17)
$Checkbox2 = GUICtrlCreateCheckbox("Checkbox2", 10, 60, 90, 17)
GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Checkbox1
            MsgBox(0, "", "Checkbox1 has been modified" & @CRLF & "It is now " & ( (GUICtrlRead($Checkbox1) = 1) ? ("Checked") : ("Unchecked") ))
        Case $Checkbox2
            MsgBox(0, "", "Checkbox2 has been modified" & @CRLF & "It is now " & ( (GUICtrlRead($Checkbox2) = 1) ? ("Checked") : ("Unchecked") ))
    EndSwitch
WEnd

Let AutoIt do the work for you.

M23

[PartyPooper]

Thanks Melba, but I use the OnEvent method for my programming, hence, the need for the WM_COMMAND.

[BrewManNH]

Thanks Melba, but I use the OnEvent method for my programming, hence, the need for the WM_COMMAND.

There no need to use that as you can detect a status change using OnEvent mode, here's Melba's script modified to do the exact same thing in OnEvent mode.

#include <GUIConstantsEx.au3>
Opt("GUIOnEventMode", 1)
$Gui = GUICreate("Native", 390, 220)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
$Checkbox1 = GUICtrlCreateCheckbox("Checkbox1", 10, 40, 90, 17)
GUICtrlSetOnEvent(-1, "_Checked")
$Checkbox2 = GUICtrlCreateCheckbox("Checkbox2", 10, 60, 90, 17)
GUICtrlSetOnEvent(-1, "_Checked")
GUISetState()

While 1
;~  Switch GUIGetMsg()
;~      Case $GUI_EVENT_CLOSE
;~          Exit
;~      Case $Checkbox1
;~          MsgBox(0, "", "Checkbox1 has been modified" & @CRLF & "It is now " & ((GUICtrlRead($Checkbox1) = 1) ? ("Checked") : ("Unchecked")))
;~      Case $Checkbox2
;~          MsgBox(0, "", "Checkbox2 has been modified" & @CRLF & "It is now " & ((GUICtrlRead($Checkbox2) = 1) ? ("Checked") : ("Unchecked")))
;~  EndSwitch
    Sleep(100)
WEnd
Func _Checked()
    Switch @GUI_CtrlId
        Case $Checkbox1
            MsgBox(0, "", "Checkbox1 has been modified" & @CRLF & "It is now " & ((GUICtrlRead($Checkbox1) = 1) ? ("Checked") : ("Unchecked")))
        Case $Checkbox2
            MsgBox(0, "", "Checkbox2 has been modified" & @CRLF & "It is now " & ((GUICtrlRead($Checkbox2) = 1) ? ("Checked") : ("Unchecked")))
    EndSwitch
EndFunc   ;==>_Checked
Func _Exit()
    Exit
EndFunc   ;==>_Exit

[PartyPooper]

Thanks BrewManNH but that's not what I'm after.  Perhaps, I should have been a little clearer - my bad.

I'm aware I can use Switch and Case or GUICtrlSetOnEvent and trap it that way, however, what I'm after is a means to detect the checkbox handle rather than its text using GUIRegisterMsg and the WM_COMMAND.  The method I have outlined above works but only if each checkbox has a different text.  Currently, I'm trying to find a means of retrieving the unique handle assigned to each control so I don't run into an error situation.  It's a learning thing.

[BrewManNH]

GUICtrlGetHandle($Checkbox1)