Force FileOpenDialog to show "init dir" always

[GordonFreeman]

The Function FileOpenDialog only show init dir when i not select a file, when i select a file the folder of this file is the init dir. Theres an way to force FileOpenDialog to "respect" always the "Init Dir" parameter?

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiListBox.au3>
#include <Array.au3>
#include <File.au3>


$hGUI = GUICreate("Form1",500,500,-1,-1)

$hBtnGet = GUICtrlCreateButton("Test",400,400,100,25)

GUISetState(@SW_SHOW)


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hBtnGet
            $File = FileOpenDialog("Selecione um Arquivo",@ScriptDir,"All (*.*)",1)
            FileChangeDir(@ScriptDir)
            MsgBox(0,"",$File)

    EndSwitch
WEnd

[Jfish]

I am not sure I follow you. The initial directory is always what appears for me even if I select a file from a sub folder.  Can you explain the problem a bit more?

[GordonFreeman]

The initial dir is @scriptdir = D: Then i selected a file in D:Music. When i close and click again the init dir will be D:Music instead of D:. And i can re-run script and will happens the same think

Thanks for attention

Edited June 9, 2014 by GordonFreeman

[Jfish]

You need to use a fixed path not a macro and it will work.  You can make it a relative path to your script - try that.  Because the successful return changes the @workingdir

 

@WorkingDir is changed on successful return. - the help file

Edited June 9, 2014 by Jfish

[GordonFreeman]

Lol. Same code and now working properly. I just put the same code on a script in Desktop works, then i moved to D: and also works. Anyway, thanks.

[Jfish]

worked for me on win 7 with the original code but not win 8 - from the desktop ...

[KaFu]

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$hGUI = GUICreate("Form1", 100, 100, -1, -1)
$hBtnGet = GUICtrlCreateButton("Test", 10, 35, 80, 25)
GUISetState(@SW_SHOW)

Global $sInitDir = @ScriptDir

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $hBtnGet

            ; http://msdn.microsoft.com/en-us/library/windows/desktop/ms646839%28v=vs.85%29.aspx
            ; OPENFILENAME structure
            ; lpstrInitialDir
            ; Windows 7: If lpstrInitialDir has the same value as was passed the first time the application used an Open or Save As dialog box, the path most recently selected by the user is used as the initial directory.

            If StringRight($sInitDir, 1) = "\" Then
                $sInitDir = StringTrimRight($sInitDir, 1)
            Else
                $sInitDir &= "\"
            EndIf
            ConsoleWrite($sInitDir & @CRLF)

            $File = FileOpenDialog("Selecione um Arquivo", $sInitDir, "All (*.*)", 1)
            
            MsgBox(0, "", $File)
            
    EndSwitch
WEnd

Edited June 16, 2014 by KaFu