IE problem

[offtopic]

Hello, might i enquire how i would go about clicking or submiting this submit button with the IE functions. I do not have access to name or id.

   

<input type="submit" class="input_submit" value="Post" />

[JohnOne]

You could start with looking at the example code for _IEFormGetCollection.

[SmOke_N]

I have not tested this, but this may work.

;Global $go_Submit = _IEGetObjByClass($oIE, "input_submit", "submit", "Post")

Func _IEGetObjByClass(ByRef $o_obj, $s_class, $s_type = "", $s_value = "")

    If Not IsObj($o_obj) Then
        Return SetError(1, 0, 0)
    EndIf

    Local $o_items = _IETagNameAllGetCollection($o_obj)
    If Not IsObj($o_items) Then
        Return SetError(2, 0, 0)
    EndIf

    For $o_item In $o_items
        If String(Execute("$o_item.classname")) <> $s_class Then
            ContinueLoop
        EndIf

        If StringLen($s_type) Then
            If String(Execute("$o_item.type")) <> $s_type Then
                ContinueLoop
            EndIf
        EndIf

        If StringLen($s_value) Then
            If String(Execute("$o_item.value")) <> $s_value Then
                ContinueLoop
            EndIf
        EndIf

        Return $o_item
    Next

    Return SetError(3, 0, 0)
EndFunc

Edited November 20, 2014 by SmOke_N

[mikell]

'?do=embed' frameborder='0' data-embedContent>>