Jump to content
InunoTaishou

Parent window always above child window

Recommended Posts

I'm essentially trying to create a pop-out window from the Parent GUI by using a child gui (So the child always stays aligned with the parent and I don't have to track the position of the parent and update the child myself). I've got it tracking and got the pop-out window working (pretty smoothly) but I need the child to always be below the parent.

I tried using GUISetOnTop and using a variant of different styles and exStyles but none seemed to work as needed. Is this possible?

And here's some code. (Hovering over the right side of the Parent window will slide the child to the right, when the cursor goes out of bounds the child goes back to the start.)

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>
#include <WinAPIGdi.au3>

AutoItSetOption("GuiOnEventMode", 1)

$frmMain = GUICreate("Parent", 400, 400, -1, -1, -1, $WS_EX_TOPMOST)
GUISetBkColor(0x000000, $frmMain)
GUISetOnEvent($GUI_EVENT_MOUSEMOVE, "MyFunc")
GUISetOnEvent($GUI_EVENT_CLOSE, "Close")

$frmChild = GuiCreate("Child", 200, 395, 195, -1, $WS_POPUP, BITOR($WS_EX_MDICHILD, $WS_EX_DLGMODALFRAME), $frmMain)
GUISetOnEvent($GUI_EVENT_MOUSEMOVE, "MyFunc")
GUISetOnEvent($GUI_EVENT_CLOSE, "Close")

$btnButton = GUICtrlCreateButton("Test", 50, 10, 140, 20)
GUICtrlSetFont(-1, 10, 300, "", "Segoe UI")
GUICtrlSetOnEvent(-1, "DoStuff")

$lblLabel = GUICtrlCreateLabel("Press the button to do stuff", 50, 35, 140, 40)
GUICtrlSetFont(-1, 10, 300, "", "Segoe UI")

GUISetState(@SW_SHOW, $frmMain)
GUISetState(@SW_SHOW, $frmChild)

While 1
    Sleep(250)
WEnd

Func Close()
    Exit
EndFunc

Func DoStuff()
    GUICtrlSetData($lblLabel, "Stuff happened! :D")
    Sleep(1000)
    GUICtrlSetData($lblLabel, "Press the button to do stuff")
EndFunc

Func MyFunc()
    Local $gui_coords = WinGetPos("Parent")
    Local $mouse_coords = MouseGetPos()
    Local static $displayed = False
    Local Static $x_offset = 0
    
    If ((Not _WinAPI_PtInRectEx($mouse_coords[0], $mouse_coords[1], $gui_coords[0] + 325, $gui_coords[1] + 10, $gui_coords[0] + 585, $gui_coords[1] + 450)) and $displayed) Then
        While ((Not _WinAPI_PtInRectEx($mouse_coords[0], $mouse_coords[1], $gui_coords[0] + 350, $gui_coords[1] + 10, $gui_coords[0] + 350 + $x_offset, $gui_coords[1] + 450)) and $x_offset <> 0)
            $gui_coords = WinGetPos("Parent")
            $mouse_coords = MouseGetPos()
            
            WinMove("Child", "", $gui_coords[0] + 194 + $x_offset, $gui_coords[1] + 24)
            $x_offset -= 6
            Sleep(1)
        Wend
        
        If ($x_offset <> 0) Then
            For $i = $x_offset to 0 Step -3
                WinMove("Child", "", $gui_coords[0] + 194 + $i, $gui_coords[1] + 24)
            Next
            $x_offset = 0
        Else
            $displayed = False
        EndIf
    ElseIf (_WinAPI_PtInRectEx($mouse_coords[0], $mouse_coords[1], $gui_coords[0] + 325, $gui_coords[1] + 24, $gui_coords[0] + 400, $gui_coords[1] + 450) and Not $displayed) Then
        While (_WinAPI_PtInRectEx($mouse_coords[0], $mouse_coords[1], $gui_coords[0] + 325, $gui_coords[1] + 24, $gui_coords[0] + 400 + $x_offset, $gui_coords[1] + 450) and $x_offset <> 180)
            $gui_coords = WinGetPos("Parent")
            $mouse_coords = MouseGetPos()
            
            WinMove("Child", "", $gui_coords[0] + 194 + $x_offset, $gui_coords[1] + 24)
            $x_offset += 10
            Sleep(1)
        Wend
        
        If ($x_offset <> 180) Then
            For $i = $x_offset to 180 Step 3
                WinMove("Child", "", $gui_coords[0] + 194 + $i, $gui_coords[1] + 24)
            Next
            $x_offset = 180
        Else
            $displayed = True
        EndIf
    EndIf
EndFunc

 

Share this post


Link to post
Share on other sites

Realized I didn't need to use child because the child window would have been hidden anyway so the user would never know if it was behind the main GUI or not. Ended up just moving it off the screen. Created a $frmDummy GUI and made the $frmChild a child of that one just so there was no toolbar icon. Once the mouse goes out of bounds the $frmChild starts to go back to hiding behind the $frmMain GUI. Once the $x_offset is at 0 the $frmChild is moved out of the screen. (Also have an extra if statement after each while loop that moves the $frmChild to see if the user maybe moved the mouse back into, or out of, the bounding area, depending on the state of $displayed.)

 

(Hopefully all of that made sense)

 

Came out pretty smooth.

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>
#include <WinAPIGdi.au3>

AutoItSetOption("GuiOnEventMode", 1)

$frmMain = GUICreate("Parent", 400, 400, -1, -1, -1, $WS_EX_TOPMOST)
GUISetOnEvent($GUI_EVENT_MOUSEMOVE, "MyFunc")
GUISetOnEvent($GUI_EVENT_CLOSE, "Close")

$lblScrollMenu = GUICtrlCreateLabel("", 375, 0, 25, 400)
GUICtrlSetBkColor(-1, 0x000000)

$frmDummy = GUICreate("Dummy", 0, 0)
$frmChild = GuiCreate("Child", 250, 395, @DesktopWidth * 2, -1, $WS_POPUP, -1, $frmDummy)
GUISetOnEvent($GUI_EVENT_MOUSEMOVE, "MyFunc")

$btnButton = GUICtrlCreateButton("Stuff", 20, 10, 220, 20)
GUICtrlSetFont(-1, 10, 300, "", "Segoe UI")
GUICtrlSetOnEvent(-1, "DoStuff")

$lblLabel = GUICtrlCreateLabel("Press the button to do stuff", 20, 35, 220, 25)
GUICtrlSetFont(-1, 10, 300, "", "Segoe UI")

GUICtrlCreateGroup("Colors", 20, 65, 220, 100)
GUICtrlCreateRadio("Red", 30, 80, 50, 20)
GUICtrlSetOnEvent(-1, "SetColor")
GUICtrlCreateRadio("Green", 90, 80, 50, 20)
GUICtrlSetOnEvent(-1, "SetColor")
GUICtrlCreateRadio("Blue", 160, 80, 50, 20)
GUICtrlSetOnEvent(-1, "SetColor")
GUICtrlCreateRadio("Cyan", 30, 105, 50, 20)
GUICtrlSetOnEvent(-1, "SetColor")
GUICtrlCreateRadio("Magenta", 90, 105, 60, 20)
GUICtrlSetOnEvent(-1, "SetColor")
GUICtrlCreateRadio("Yellow", 160, 105, 50, 20)
GUICtrlSetOnEvent(-1, "SetColor")
GUICtrlCreateRadio("Black", 30, 130, 50, 20)
GUICtrlSetOnEvent(-1, "SetColor")
GUICtrlSetState(-1, $GUI_CHECKED)

GUISetState(@SW_SHOW, $frmMain)
GUISetState(@SW_SHOW, $frmChild)

While 1
    Sleep(250)
WEnd

Func DoStuff()
    GUICtrlSetData($lblLabel, "Stuff happened! :D")
    Sleep(500)
    GUICtrlSetData($lblLabel, "Press the button to do stuff")
EndFunc

Func SetColor()
    Local const $color = GUICtrlRead(@GUI_CtrlId, 1)
    
    If ($color = "Red") Then
        GUICtrlSetBkColor($lblScrollMenu, 0xFF0000)
    ElseIf ($color = "Green") Then
        GUICtrlSetBkColor($lblScrollMenu, 0x00FF00)
    ElseIf ($color = "Blue") Then
        GUICtrlSetBkColor($lblScrollMenu, 0x0000FF)
    ElseIf ($color = "Cyan") Then
        GUICtrlSetBkColor($lblScrollMenu, 0x00FFFF)
    ElseIf ($color = "Yellow") Then
        GUICtrlSetBkColor($lblScrollMenu, 0xFFFF00)
    ElseIf ($color = "Magenta") Then
        GUICtrlSetBkColor($lblScrollMenu, 0xFF00FF)
    Else
        GUICtrlSetBkColor($lblScrollMenu, 0x000000)
    EndIf
EndFunc

Func MyFunc()
    Local $gui_coords = WinGetPos("Parent")
    Local $mouse_coords = MouseGetPos()
    Local static $displayed = False
    Local Static $x_offset = 0
    
    If ($displayed) Then
        If (Not _WinAPI_PtInRectEx($mouse_coords[0], $mouse_coords[1], $gui_coords[0] + 375, $gui_coords[1] + 10, $gui_coords[0] + 675, $gui_coords[1] + 425)) Then
            While ((Not _WinAPI_PtInRectEx($mouse_coords[0], $mouse_coords[1], $gui_coords[0] + 375, $gui_coords[1] + 10, $gui_coords[0] + 350 + $x_offset, $gui_coords[1] + 425)) and $x_offset <> 0)
                $gui_coords = WinGetPos("Parent")
                $mouse_coords = MouseGetPos()
                
                $x_offset -= 10
                WinMove("Child", "", $gui_coords[0] + 140 + $x_offset, $gui_coords[1] + 28)
                Sleep(1)
            Wend
            
            If ($x_offset <> 0) Then
                For $i = $x_offset to 260 Step 5
                    WinMove("Child", "", $gui_coords[0] + 140 + $i, $gui_coords[1] + 28)
                Next
                $displayed = True
            Else
                WinMove("Child", "", @DesktopWidth * 2, 0)
                $displayed = False
            EndIf
        EndIf
    Else
        If (_WinAPI_PtInRectEx($mouse_coords[0], $mouse_coords[1], $gui_coords[0] + 375, $gui_coords[1] + 24, $gui_coords[0] + 400, $gui_coords[1] + 425)) Then
            While (_WinAPI_PtInRectEx($mouse_coords[0], $mouse_coords[1], $gui_coords[0] + 375, $gui_coords[1] + 24, $gui_coords[0] + 425 + $x_offset, $gui_coords[1] + 425) and $x_offset <> 260)
                $gui_coords = WinGetPos("Parent")
                $mouse_coords = MouseGetPos()
                
                $x_offset += 10
                WinMove("Child", "", $gui_coords[0] + 140 + $x_offset, $gui_coords[1] + 28)
                Sleep(1)
            Wend
            
            If ($x_offset <> 260) Then
                For $i = $x_offset to 0 Step -5
                    WinMove("Child", "", $gui_coords[0] + 140 + $i, $gui_coords[1] + 28)
                Next
                WinMove("Child", "", @DesktopWidth * 2, 0)
                $displayed = False
            Else
                $displayed = True
            EndIf
        EndIf
    EndIf
EndFunc

Func Close()
    Exit
EndFunc

 

Share this post


Link to post
Share on other sites

InunoTaishou,

that just resizes the GUI

I would like to point out that the UDF does a bit more than that - but it certainly does not slide as you require.

Have you looked into animating the GUI? Take a look at my Toast or Notify UDFs to see how you can do it. If I find time later (I am about to go out) I will see if I can produce an example based on your code above.

M23


Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

InunoTaishou,

How about this?

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <AutoItConstants.au3>
#include <WinAPISys.au3>

AutoItSetOption("GuiOnEventMode", 1)

Global $iBorder = 50, $bOpen = False

$hGUI = GUICreate("Test", 500, 500, 200, 200)
GUISetOnEvent($GUI_EVENT_MOUSEMOVE, "_MouseMove")
GUISetOnEvent($GUI_EVENT_CLOSE, "_Close")

$cScrollLabel = GUICtrlCreateLabel("", 500 - $iBorder, 0, $iBorder, 500)
GUICtrlSetBkColor($cScrollLabel, 0x000000)

GUISetState()

$aWinPos = WinGetPos($hGUI)

$hChild = GUICreate("Child", 250, $aWinPos[3] - 20, $aWinPos[0] + 506, $aWinPos[1] + 10, $WS_POPUP)
GUISetOnEvent($GUI_EVENT_MOUSEMOVE, "_MouseMove")

$cButton = GUICtrlCreateButton("Stuff", 20, 10, 220, 20)
GUICtrlSetFont($cButton, 10, 300, "", "Segoe UI")
GUICtrlSetOnEvent($cButton, "_DoStuff")

$cLabel = GUICtrlCreateLabel("Press the button to do stuff", 20, 35, 220, 25)
GUICtrlSetFont($cLabel, 10, 300, "", "Segoe UI")

GUICtrlCreateGroup("Colors", 20, 65, 220, 100)
GUICtrlCreateRadio("Red", 30, 80, 50, 20)
GUICtrlSetOnEvent(-1, "_SetColor")
GUICtrlCreateRadio("Green", 90, 80, 50, 20)
GUICtrlSetOnEvent(-1, "_SetColor")
GUICtrlCreateRadio("Blue", 160, 80, 50, 20)
GUICtrlSetOnEvent(-1, "_SetColor")
GUICtrlCreateRadio("Cyan", 30, 105, 50, 20)
GUICtrlSetOnEvent(-1, "_SetColor")
GUICtrlCreateRadio("Magenta", 90, 105, 60, 20)
GUICtrlSetOnEvent(-1, "_SetColor")
GUICtrlCreateRadio("Yellow", 160, 105, 50, 20)
GUICtrlSetOnEvent(-1, "_SetColor")
GUICtrlCreateRadio("Black", 30, 130, 50, 20)
GUICtrlSetOnEvent(-1, "_SetColor")
GUICtrlSetState(-1, $GUI_CHECKED)

WinSetTrans($hChild, "", 0)
GUISetState()
_WinAPI_SetWindowPos($hChild, $hGUI, 706, 230, 250, 490, $SWP_HIDEWINDOW)
WinSetTrans($hChild, "", 255)

GUIRegisterMsg($WM_MOVE, "_WM_MOVE")

While 1
    Sleep(10)
WEnd



Func _MouseMove()
    If Not $bOpen Then
        $aWinPos = WinGetPos($hGUI)
        $aCInfo = GUIGetCursorInfo($hGUI)
        Switch $aCInfo[1]
            Case 20 To $aWinPos[3] ; Allow space at the top so that moving to the buttons does not opene the child
                Switch $aCInfo[0]
                    Case $aWinPos[2] - $iBorder To $aWinPos[2]
                        If Not $bOpen Then
                            _WinAPI_AnimateWindow($hChild, BitOR($AW_ACTIVATE, $AW_HOR_POSITIVE))
                            $bOpen = True
                            WinActivate($hChild)
                        EndIf



                EndSwitch

        EndSwitch

    Else
        $aWinPos = WinGetPos($hChild)
        $aCInfo = GUIGetCursorInfo($hChild)
        Switch $aCInfo[1]
            Case 0 To $aWinPos[3]
                If $aCInfo[0] < -$iBorder Then
                    If $bOpen Then
                        _WinAPI_AnimateWindow($hChild, BitOR($AW_HIDE, $AW_HOR_NEGATIVE))
                        $bOpen = False
                        WinActivate($hGUI)
                    EndIf

                EndIf

        EndSwitch

    EndIf

EndFunc   ;==>_MouseMove



Func _DoStuff()
    GUICtrlSetData($cLabel, "Stuff happened! :D")
    Sleep(500)
    GUICtrlSetData($cLabel, "Press the button to do stuff")
EndFunc   ;==>_DoStuff



Func _SetColor()
    Switch GUICtrlRead(@GUI_CtrlId, 1)
        Case "Red"
            GUICtrlSetBkColor($cScrollLabel, 0xFF0000)
        Case "Green"
            GUICtrlSetBkColor($cScrollLabel, 0x00FF00)
        Case "Blue"
            GUICtrlSetBkColor($cScrollLabel, 0x0000FF)
        Case "Cyan"
            GUICtrlSetBkColor($cScrollLabel, 0x00FFFF)
        Case "Yellow"
            GUICtrlSetBkColor($cScrollLabel, 0xFFFF00)
        Case "Magenta"
            GUICtrlSetBkColor($cScrollLabel, 0xFF00FF)
        Case Else
            GUICtrlSetBkColor($cScrollLabel, 0x000000)
    EndSwitch

EndFunc   ;==>_SetColor



Func _Close()
    Exit
EndFunc   ;==>_Close

Func _WM_MOVE($hWnd, $iMsg, $wParam, $lParam)
    #forceref $iMsg, $wParam, $lParam

    If $hWnd = $hGUI Then
        Local $aWinPos = WinGetPos($hGUI)
        WinMove($hChild, "", $aWinPos[0] + 506, $aWinPos[1] + 30)
    EndIf

EndFunc   ;==>_WM_MOVE

Please ask if you have any questions.

M23


Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

My god, I didn't realize there was a WinAPI function that could do what I needed!

Yours is pretty nice, looks like a rolling window, I was looking for a sliding window and $AW_SLIDE does exactly that. Thank you very much!

It looks like the GUI becomes disabled while the API function is moving the child though. It does what I need in less code but it doesn't work as well as what I was wanting it for, still really nice function to make some pretty GUIs.

 

And by what I was wanting I mean that if the use moves away from the area that causes the window to move out, it starts to go back into retracted. If the user goes back into the area that causes the window to move out again it starts to move the window out again. The _WinAPI_AnimateWindow looks extremely useful though.

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now

  • Similar Content

    • By coronatuss
      Hello eveyone,
      I installed the latest version of Autoit (x86 - for greater compatibility) and SciTE.
      Every time I want to generate the GUI code designed in Koda, the program freezes (only Koda, not SciTE).
      Have you ever had this problem? Do you know how to fix it?
      Thanks!
    • By nacerbaaziz
      hello sirs, i've created a tool to the blind users, this tool helps the blind to listen to a audio effect when moving between the GUIs controls on they computers
      where this tool can get the class for the current focus control and play a sound from a folder
      i've added all the knowne classes, but i found some problems i hope any one can help me.
      this is the code that i created

      #include <WinAPISys.au3> Global $h_CurrentHWNDFocus = "", $h_CurrentControlHWNDFocus = "" AdlibRegister("WindowAudioFocus", 50) Func WindowAudioFocus()     Local $h_NewHWNDFocus = WinGetHandle("[active]", "")     Local $h_NewControlHWNDFocus = ControlGetFocus($h_NewHWNDFocus, "")     If ($h_NewHWNDFocus = $h_CurrentHWNDFocus) And ($h_NewControlHWNDFocus = $h_CurrentControlHWNDFocus) Then Return 0     AdlibUnRegister("WindowAudioFocus")     If Not ($h_NewHWNDFocus = $h_CurrentHWNDFocus) Then         SoundPlay(@ScriptDir & "\focus_Audio\WindowChanged.wav")     Else         Switch _WinAPI_GetClassName(ControlGetHandle($h_NewHWNDFocus, "", $h_NewControlHWNDFocus))             Case "Button", "Start", "TrayButton", "TrayShowDesktopButtonWClass", "sbutton", "CirrussButton", "ODbcButton", "ThunderRTCommandButton", "ThunderSSOption", "ThunderSSCommand", "ThunderCommandButton", "ThunderRT6CommandButton", "ThunderRT5CommandButton", "TButton", "TBitBtn", "TAdvGlowButton", "ButtonWndClass", "afx:0:376:baa946", "_AOL_Button"                 If _IsCheckBox(ControlGetHandle($h_NewHWNDFocus, "", $h_NewControlHWNDFocus)) Then                     SoundPlay(@ScriptDir & "\focus_Audio\checkBox.wav")                 ElseIf _IsRadio(ControlGetHandle($h_NewHWNDFocus, "", $h_NewControlHWNDFocus)) Then                     SoundPlay(@ScriptDir & "\focus_Audio\radio.wav")                 Else                     SoundPlay(@ScriptDir & "\focus_Audio\button.wav")                 EndIf             Case "ComboBox", "ComboBoxEx32", "MSOBALLOONREComboBox20W", "REComboBox20W", "ThunderComboBox", "ThunderDriveListBox", "ThunderRT6ComboBox", "TORComboEdit", "TCombobox", "TComboBoxEx", "TORComboBox", "TColorBox", "TNFComboBox", "Internet Explorer_TridentCmbobx", "ComboWndClass", "_AOL_ComboBox", "ThunderRT5ComboBox", "ComboLBox"                 SoundPlay(@ScriptDir & "\focus_Audio\list.wav")             Case "Edit", "SearchBox", "TChatRichEdit", "_WwN", "_WwO", "RichEdit20A", "RichEdit20WPT", "RICHEDIT60W", "OKttbx", "RichEditA", "ThunderTextBox", "ThunderRT6TextBox", "ThunderRT5TextBox", "TEdit", "TRichEdit", "TRichEditViewer", "TMemo", "TInplaceEditList", "TLabeledEdit", "TMaskEdit", "TDateTimePicker", "TRichEdit", "TCaptionMemo", "TAddictRichEdit", "TCaptionEdit", "RichTextWndClass", "TextWndClass", "PasswordWndClass", "TextAreaWndClass", "MSWorksDoc", "_AOL_Edit", "SysDateTimePick32"                 SoundPlay(@ScriptDir & "\focus_Audio\edit.wav")             Case "ListBox", "ComboLBox", "REListBox20W", "SUPERGRID", "OUTEXVLB", "WMSUIVLB", "SchdmapiVLB", "VLBClass", "ThunderDirListBox", "ThunderFileListBox", "ThunderListBox", "ThunderRT6ListBox", "ThunderRT5ListBox", "TListbox", "TValueListEditor", "TORCalendar", "TColorListBox", "TCheckListBox", "Internet Explorer_TridentLstBox", "ListBoxWndClass", "ListWndClass", "hh_kwd_vlist", "afx:8:376:0:946", "_AOL_ListBox", "_AOL_Tree", ""                 SoundPlay(@ScriptDir & "\focus_Audio\List.wav")             Case "SysListView32", "OpenListView", "wuDuiListView", "ListView20WndClass", "TcxGridSite", "TListView", "TSystemListView", "ListViewWndClass", ""                 SoundPlay(@ScriptDir & "\focus_Audio\ListView.wav")             Case "SysTreeView32", "SearchTreeList", "FeatureTree", "TreeView20WndClass", "TSystemTreeView", "TTreeView", ""                 SoundPlay(@ScriptDir & "\focus_Audio\TreeView.wav")             Case Else                 SoundPlay(@ScriptDir & "\focus_Audio\focus.wav")         EndSwitch     EndIf     $h_CurrentHWNDFocus = $h_NewHWNDFocus     $h_CurrentControlHWNDFocus = $h_NewControlHWNDFocus     AdlibRegister("WindowAudioFocus", 50)     Return 1 EndFunc   ;==>WindowAudioFocus Func _IsCheckBox($ctrl_hwnd)     $Style = _WinAPI_GetWindowLong($ctrl_hwnd, $GWL_STYLE)     Return BitAND($Style, $BS_CHECKBOX) = $BS_CHECKBOX EndFunc   ;==>_IsCheckBox Func _IsRadio($ctrl_hwnd)     $Style = _WinAPI_GetWindowLong($ctrl_hwnd, $GWL_STYLE)     Return BitAND($Style, $BS_AUTORADIOBUTTON) = $BS_AUTORADIOBUTTON EndFunc   ;==>_IsRadio
      what i need from you is :
      play a sound when a menu item focus, that sound named menu.wav
      play a sound named items.wav when the users move on list box items or list view or treeview items or a combobox items
      please if can any one help me i'll very happy
      thanks on advance
    • By nacerbaaziz
      hello sirs, please i created a tool witch get the focused control in a window and play a audio file linked with this controls
      e.g buttons, checkBoxes, radios, comboboxes, and others
      i know that their is a function that give us the control focus but it return the classNN
      i want to get the class name to use it with a switch and
      because their are more than class e.g button tbutton timagebutton tnewButton...
      please can any one help me to get the class name not the classnn
      thanks in advance
    • By CarlD
      Update: Download the latest version here.
      As my first stab at GUI scripting, I'm trying to write a simple graphical interface for Grep for Windows. I have a basic GUI, but I'm stuck on one point and nothing I've tried so far works. The sticking point is that while the Tab key works to move focus from one input control to the next, clicking the mouse on any but the first input does nothing. This seems like a basic feature of GUI functionality that should work out of the box (like Tab), but clearly I'm missing something. I tried (among many other things) Melba23's technique in the post below, but this doesn't do what I'm after -- getting the left click to set the insertion point for user input. Would greatly appreciate a pointer or two. 😉
      Here's my code so far:
      ; Grep for Windows -- GUI [CLD] #include <AutoItConstants.au3> #include <GUIConstantsEx.au3> #include <StaticConstants.au3> #include <WinAPI.au3> #include <WindowsConstants.au3> Opt("WinTitleMatchMode", -2) #cs FileInstall("X:\nix\search1.ico", @TempDir & "\search1.ico") FileInstall("X:\nix\grep.exe", @TempDir & "\grep.exe") FileInstall("X:\nix\sed.exe", @TempDir & "\sed.exe") FileInstall("X:\nix\libiconv2.dll", @TempDir & "\libiconv2.dll") FileInstall("X:\nix\libintl3.dll", @TempDir & "\libintl3.dll") FileInstall("X:\nix\pcre3.dll", @TempDir & "\pcre3.dll") FileInstall("X:\nix\regex2.dll", @TempDir & "\regex2.dll") #ce ; $sDefFs = @ScriptDir & "\.txt" $sOut = "" $iX = 20 $iY = 20 $hgGGrep = GUICreate("Grep for Windows: Simple TeXT search", 600, 600) GUISetState(@SW_SHOW, $hgGGrep) ; Obtain value of control: GUICtrlRead() ; left, top, width, height ; $iX, $iY, $iX + n, $iY + m ; $hgIco = GUICtrlCreateIcon(@ScriptDir & "\search1.ico", $iX, $iY, 10) $hgGL0 = GUICtrlCreateLabel("Enter a string or regular expression" & @CRLF & "(space between words means ""OR"")", $iX + 50, $iY, 250, 30) $hgSch = GUICtrlCreateInput("", $iX + 50, $iY + 40, 325, 20, $GUI_SS_DEFAULT_INPUT, -1) $hgXyZ = GUICtrlCreateCheckbox("cAsE-sEnSiTiVe", $iX + 50, $iY + 65, -1, -1) $hgExe = GUICtrlCreateButton("Search", 400, $iY + 40, -1, -1) $hgFL1 = GUICtrlCreateLabel("Filespec", $iX + 50, $iY + 100, 250, 20) $hgFs1 = GUICtrlCreateInput("d:\path\*.txt", $iX + 110, $iY + 100, 250, 20, $GUI_SS_DEFAULT_INPUT, -1) $hgFL2 = GUICtrlCreateLabel("Filespec", $iX + 50, $iY + 120, 250, 20) $hgFs2 = GUICtrlCreateInput("", $iX + 110, $iY + 120, 250, 20, $GUI_SS_DEFAULT_INPUT, -1) $hgFL3 = GUICtrlCreateLabel("Filespec", $iX + 50, $iY + 140, 250, 20) $hgFs3 = GUICtrlCreateInput("", $iX + 110, $iY + 140, 250, 20, $GUI_SS_DEFAULT_INPUT,-1) $hgOut = GUICtrlCreateEdit($sOut, 25, 190, 550, 400, $ES_LEFT, -1) GUICtrlSetState($hgSch, $GUI_FOCUS) While 1 $nMsg = GUIGetMsg() Switch $nMsg Case $GUI_EVENT_CLOSE Exit EndSwitch WEnd ; #cs _WinAPI_SetFocus(ControlGetHandle("Grep for Windows", "", $hgSch)) _WinAPI_SetFocus(ControlGetHandle("Grep for Windows", "", $hgFs1)) _WinAPI_SetFocus(ControlGetHandle("Grep for Windows", "", $hgFs2)) _WinAPI_SetFocus(ControlGetHandle("Grep for Windows", "", $hgFs3)) #ce Thanks in advance.
    • By Elizabeth
      Buttons on GUI to perform different tasks. SETUP is a task that involves displaying another GUI, doing calculations, writing lines to 2 external files, displaying information on GUI labels.  The info from the displayed GUI (quantity made and job completed YES or NO) must be included on the written lines. I cannot get the script to run synchronously (waterfall execution 1st one ends before 2nd one starts.) That means lines written to the files do not contain the required data.  I have read through FORUM and thought by inserting a boolean value and changing TRUE FALSE that I could solve this issue. I would have to set/reset the boolean before every function call to make it work. I've tried using Sleep but that just slows everything down and makes main GUI look unresponsive
      Is there a trick or tip someone can provide that forces synchronous execution?
      I am using OPT GUIOnEventMode
      Thank you for any insight into this issue.
×
×
  • Create New...