If GUISetAccelerators() for a GUI then, what is for a specific control ?

[kcvinu]

Hi all,

I know GUISetAccelerators() function is helpful to set a hotkey for my GUI. But which function should i use for setting a hotkey for a specific control only. Say, i have 3 Textboxes and a button in my form. I want to display a msg box when i press the enter key while keyboard focus is in the first textbox. When i used GUISetAccelerators function, it is firing the event regardless the focuds of the control.

[Melba23]

kcvinu,

Just check which control has focus when the Accelerator key is actioned and only proceed if the correct one is focused.

M23

[TheDcoder]

@kcvinu You can use a dummy control for the purpose M23 mentioned

[kcvinu]

@Melba23 I have tried, but not succeeded. What is worng with this code ?

#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiButton.au3>

Local $hGUI = GUICreate("Window", 381, 237, -1, -1)
Local $hButton = GUICtrlCreateButton("Button", 97, 145, 192, 77)
Local $hInput = GUICtrlCreateInput("", 60, 37, 267, 35)
Local $hInput2 = GUICtrlCreateInput("", 60, 97, 267, 35)
Local $Accle = [["{ENTER}",$hButton]]
GUISetAccelerators($Accle)

GUISetState()

While 1
    $hMsg = GUIGetMsg()
    Switch $hMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hInput

        Case $hButton
            If GUICtrlGetState($hInput) = $GUI_FOCUS Then
                BClick()
            EndIf
    EndSwitch
WEnd


Func BClick()
    MsgBox(0,"","Button is Clicked")
EndFunc

 

Edited November 6, 2015 by kcvinu

[TheDcoder]

@kcvinu Because Case $hInput is empty

[kcvinu]

@TheDcoder , I am learing about dummy controls. 

[TheDcoder]

@kcvinu $hInput is a input control, not a dummy control... They are created using:

GUICtrlCreateDummy

[Melba23]

kcvinu,

I always use _WinAPI_GetFocus to test which control has it:

Case $hButton

            If _WinAPI_GetFocus() = GUICtrlGetHandle($hInput) Then
                BClick()
            EndIf

and that works for me.

M23

[TheDcoder]

Here is a live example which I use in my program:

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Global $g_hMainGUI = GUICreate("Test")

Global $g_idMainGUI_YesDummy = GUICtrlCreateDummy()
Global $g_idMainGUI_NoDummy = GUICtrlCreateDummy()
Global $g_idMainGUI_TryAgainDummy = GUICtrlCreateDummy()
Global $g_idMainGUI_AbortDummy = GUICtrlCreateDummy()

Local $aAccelKeys[4][2] = [["y", $g_idMainGUI_YesDummy], ["n", $g_idMainGUI_NoDummy], ["t", $g_idMainGUI_TryAgainDummy], ["a", $g_idMainGUI_AbortDummy]]
GUISetAccelerators($aAccelKeys, $g_hMainGUI)

GUISetState()

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $g_idMainGUI_YesDummy
            MsgBox($MB_OK, "Test", "You pressed 'y' which means Yes!")

        Case $g_idMainGUI_NoDummy
            MsgBox($MB_OK, "Test", "You pressed 'n' which means No!")

        Case $g_idMainGUI_TryAgainDummy
            MsgBox($MB_OK, "Test", "You pressed 't' which means Try Again!")

        Case $g_idMainGUI_AbortDummy
            MsgBox($MB_OK, "Test", "You pressed 'a' which means Abort!")
    EndSwitch
WEnd

TD

Edited November 6, 2015 by TheDcoder

[kcvinu]

@TheDcoder , Thanks for the example. 

@Melba23 , What i was planned is to display the MsgBox in 2 conditions.

1. when user presses enter after typing in text box

2. when user clicks the button with mouse. 

So this is the way i solved this problem. Please look this and tell me if there is any better way.

Case $hButton
        If _WinAPI_GetFocus() = GUICtrlGetHandle($hInput) Or _WinAPI_GetFocus() = GUICtrlGetHandle($hButton) Then
            BClick()
        EndIf

 

[TheDcoder]

@kcvinu My pleasure

[Melba23]

kcvinu,

I would use a dummy control like this:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WinAPI.au3>

Local $hGUI = GUICreate("Window", 381, 237, -1, -1)
Local $hButton = GUICtrlCreateButton("Button", 97, 145, 192, 77)
Local $hInput = GUICtrlCreateInput("", 60, 37, 267, 35)
Local $hInput2 = GUICtrlCreateInput("", 60, 97, 267, 35)
Local $cInputDummy = GUICtrlCreateDummy()

GUISetState()

Local $Accle = [["{ENTER}",$cInputDummy]]
GUISetAccelerators($Accle)

While 1
    $hMsg = GUIGetMsg()
    Switch $hMsg

        Case $GUI_EVENT_CLOSE
            Exit
        Case $cInputDummy

            If _WinAPI_GetFocus() = GUICtrlGetHandle($hInput) Then
                BClick()
            EndIf

        Case $hButton

            BClick()
    EndSwitch

WEnd



Func BClick()
    MsgBox(0,"","Button is Clicked")
EndFunc

M23

[kcvinu]

@Melba23 Thanks a lot.