Dragging GUI makes script pause

[algiuxas]

Hello,

When I move GUI, script pause until I release GUI.

I need to make script not pause while dragging GUI.
 

GUICreate("Hello world!",250,175,-1,-1)
Opt("GUIOnEventMode", 1)
GUISetOnEvent(-3, "exit_") ; Check if closed
GUISetState()

While 1
    ToolTip("This tooltip should move.")
    Sleep(50)
WEnd

Func exit_()
    GUIDelete()
    Exit
EndFunc

 

Edited July 19, 2016 by algiuxas

[JLogan3o13]

@algiuxas we can't offer much in the way of help when you don't include any of your code. Obviously, we have many GUI scripts on this forum, and they aren't all freezing when dragged, so there is something going on in your script specifically. Rather than having us consult our crystal ball, how about posting your code?

[algiuxas]

30 minutes ago, JLogan3o13 said:

@algiuxas we can't offer much in the way of help when you don't include any of your code. Obviously, we have many GUI scripts on this forum, and they aren't all freezing when dragged, so there is something going on in your script specifically. Rather than having us consult our crystal ball, how about posting your code?

GUICreate("Hello world!",250,175,-1,-1)
Opt("GUIOnEventMode", 1)
GUISetOnEvent(-3, "exit_") ; if closed, exit.
GUISetState()

While 1
    ToolTip("This tooltip should move.")
    Sleep(50)
WEnd

Func exit_()
    GUIDelete()
    Exit
EndFunc

I wrote this right now, and it still haves the same problem, script pauses while moving GUI.
I mean that it pauses, I didn't mean that it crashes, exits or etc., sorry.

Edited July 19, 2016 by algiuxas

[UEZ]

Try this:

#Include <Timers.au3>
#include <WindowsConstants.au3>

Global $hGUI = GUICreate("Hello world!",250,175,-1,-1)
Opt("GUIOnEventMode", 1)
GUISetOnEvent(-3, "exit_") ; Check if closed
GUISetState()

Global $iMs = 30
GUIRegisterMsg($WM_TIMER, "_Interrupt")
DllCall("User32.dll", "int", "SetTimer", "hwnd", $hGUI, "int", 0, "int", $iMs, "int", 0)


While 1
    Sleep(50)
WEnd

Func exit_()
    GUIRegisterMsg($WM_TIMER, "")
    GUIDelete()
    Exit
EndFunc

Func _Interrupt()
    ToolTip("This tooltip should move.")
EndFunc

 

[algiuxas]

1 minute ago, UEZ said:

Try this:

#Include <Timers.au3>
#include <WindowsConstants.au3>

Global $hGUI = GUICreate("Hello world!",250,175,-1,-1)
Opt("GUIOnEventMode", 1)
GUISetOnEvent(-3, "exit_") ; Check if closed
GUISetState()

Global $iMs = 30
GUIRegisterMsg($WM_TIMER, "_Interrupt")
DllCall("User32.dll", "int", "SetTimer", "hwnd", $hGUI, "int", 0, "int", $iMs, "int", 0)


While 1
    Sleep(50)
WEnd

Func exit_()
    GUIRegisterMsg($WM_TIMER, "")
    GUIDelete()
    Exit
EndFunc

Func _Interrupt()
    ToolTip("This tooltip should move.")
EndFunc

 

Thanks,
but this loop took about 40 milisecounds, is there a way to make it faster, like in a normal loop(0.01ms)?

[BrewManNH]

Actually, with a 50ms sleep in there it takes at least 50ms. You can't use a sleep value under 10ms, sleep won't go lower.

[algiuxas]

Just now, BrewManNH said:

Actually, with a 50ms sleep in there it takes at least 50ms. You can't use a sleep value under 10ms, sleep won't go lower.

I tested it without sleep

[UEZ]

FYI: The function _Interrupt() is called every 30 ms.

Global $iMs = 30

 

Edited July 19, 2016 by UEZ

[algiuxas]

Just now, UEZ said:

FYI: The function _Interrupt() is called every 30 ms.

Thank you, didn't saw that.

[algiuxas]

I found a problem - if it's a big script or it took long to execute it, it will pause anyway.

Edited July 19, 2016 by algiuxas

[algiuxas]

This doesn't work...
 

#Include <Timers.au3>
#include <WindowsConstants.au3>

Global $hGUI = GUICreate("Hello world!",250,175,-1,-1)
Opt("GUIOnEventMode", 1)
GUISetOnEvent(-3, "exit_") ; Check if closed
GUISetState()
Global $t = TimerInit()
Global $iMs = 0
GUIRegisterMsg($WM_TIMER, "_Interrupt")
DllCall("User32.dll", "int", "SetTimer", "hwnd", $hGUI, "int", 0, "int", $iMs, "int", 0)


While 1
ToolTip("h")
WEnd

Func exit_()
    GUIRegisterMsg($WM_TIMER, "")
    GUIDelete()
    Exit
EndFunc

Func _Interrupt()
    ToolTip(TimerDiff($t)&@CRLF)
    sleep(Random(50,1000,1)
    $t = TimerInit()
EndFunc

I need another way to avoid pausing the script while moving/resizing GUI,

because I'm not sure how much time will one loop took.

Edited July 19, 2016 by algiuxas

[UEZ]

I think you don't have understand the timer functionality.

The script will interrupt the execution every 30ms to call the _Interrupt(). When you put a sleep within that function the functionality of the timer will get obsolete.

 

You have to put the code which should run in any case to the _Interrupt() function. I don't know what is not working in your big script.

[Leo1906]

On 19.7.2016 at 11:14 PM, UEZ said:

The script will interrupt the execution every 30ms to call the _Interrupt(). When you put a sleep within that function the functionality of the timer will get obsolete.

If it interrupts the script execution .. what is the difference to Adlib? Why not just register the function as adlib?

 

On 19.7.2016 at 10:28 PM, BrewManNH said:

Actually, with a 50ms sleep in there it takes at least 50ms. You can't use a sleep value under 10ms, sleep won't go lower.

Isn't Sleep(1) a possibillity and below 10 ms?
i thought I read so

[UEZ]

26 minutes ago, Leo1906 said:

f it interrupts the script execution .. what is the difference to Adlib? Why not just register the function as adlib?

Adlib doesn't let continue the script on GUI move.

[Leo1906]

1 minute ago, UEZ said:

Adlib doesn't let continue the script on GUI move.

Ok thank you for the explanation
Learned something new

[AutoBert]

9 hours ago, Leo1906 said:

Isn't Sleep(1) a possibillity and below 10 ms?
i thought I read so

it's below 10 but the shortest possible sleep is 10 so sleep(1), sleep(5) and sleep(10) will effect the same.