Regex date

[Chiitus]

Hello guys, i have a problem in this regex because its not groupping right.

Look:

(\d{1,2}\s?[\055|\056|\057|\134]\s?\d{1,2}(\s?[\055|\056|\057|\134]\s?\d{2,4})?)

It checks for day or dayday, month or monthmonth, yearyear or yearyearyear+year.

separated with or without space and the characters "\/.-"

But, a problem! I tried to regex the date with or without the "separator + year" Eg: 05/05 or 05/05/05, but when i have 05/05/05, regex are separating 05/05 and /05

Iam using group "()" wrong?

Need help here

Thx adv!

~~EDIT:

Script used: (from autoitscript.com/forum/topic/129697-split-string-by-regular-expression/#comment-901335)

#include <Array.au3>

Local $sString = ClipGet()

; Extract the delimiters
$aDelim = StringRegExp($sString, '(\d{1,2}\s?[\055|\056|\057|\134]\s?\d{1,2}(\s?[\055|\056|\057|\134]\s?\d{2,4})?)', 3)

; Split the string on the delimiters
$aParts = StringSplit(StringRegExpReplace($sString, '(\d{1,2}\s?[\055|\056|\057|\134]\s?\d{1,2}(\s?[\055|\056|\057|\134]\s?\d{2,4})?)', "$<SEPARATOR>$"), "$<SEPARATOR>$", 3)

; Add the delimter to the start of the part
For $i = 0 To UBound($aParts) - 1
   ;$aParts[$i + 1] = $aDelim[$i] & $aParts[$i + 1]
Next

; Set the count
$aParts[0] = UBound($aParts)

; Display the result
_ArrayDisplay($aParts)
_ArrayDisplay($aDelim)

Results in array: (the array parts in all string is ok; but the string delimitator himself is getting separated in every string that have year together)

String used as test:

Quote

02 / 9 \ 16 – test

07 - 9 . 16 – test

09/9/16 – test

14\9\16 – test

16-9-16 – test

21.9.16 – test

23/9 – test

28\9 – test

Cheers.

Edited September 8, 2016 by Chiitus

[Jos]

It helps when you post a small script that demonstrates the issue, so we can have a play with it.

Jos

[Chiitus]

2 hours ago, Jos said:

It helps when you post a small script that demonstrates the issue, so we can have a play with it.

Jos

Topic edited!

Thanks for the info

[Jos]

3 hours ago, Chiitus said:

Local $sString = ClipGet()

What about the string to test with?

Ok copied your test data into a file to make life easy.

Jos

Edited September 8, 2016 by Jos

[jguinch]

are you sure that the pattern [\055|\056|\057|\134] matches what you expect ? https://regex101.com/r/zQ5xY4/1

 

[Chiitus]

12 minutes ago, jguinch said:

are you sure that the pattern [\055|\056|\057|\134] matches what you expect ? https://regex101.com/r/zQ5xY4/1

 

It match "\/.-" one of these chars. But in this link you posted, regex are founding char "|", isnt this char a "OR" operator in regex?

EDIT: From AutoIt regex tutorial link: codeproject.com/Articles/9099/The-Minute-Regex-Tutorial;

\xxx ~> Character ASCII octal code.

Edited September 8, 2016 by Chiitus

[jchd]

I find it rare that people use octal nowadays, in regexp patterns or elsewhere.

[jchd]

Inside a character class, the bar | doesn't mean alternation, it stands for itself (redondantly here).

[jchd]

But one question remains: what format do you want the final result to be?

[Malkey]

If you do not want the delimliter and year only to be specifically matched then make that part of the RE pattern a non-capturing group.
See example.

#include <Array.au3>

Local $sString = StringRegExpReplace(FileRead(@ScriptFullPath), "(?is)^.*#cs\R|\R?#ce.*$", "") ; ClipGet()
ConsoleWrite($sString & @CRLF)

$a = StringRegExp($sString, "((?:[0-9]{1,2}[\h\-\\/.]{0,3}){2,3})", 3)
_ArrayDisplay($a)

; Modified $aDelim from Post#1
$aDelim = StringRegExp($sString, '(\d{1,2}\s?[\055|\056|\057|\134]\s?\d{1,2}(?:\s?[\055|\056|\057|\134]\s?\d{2,4})?)', 3)
; Note addition of "?:" in the RegExp pattern in the line above here~~~~~~~~~^
_ArrayDisplay($aDelim, "$aDelim")

; Data for variable $sString - Copied from Post#1
#cs

02 / 9 \ 16 – test

07 - 9 . 16 – test

09/9/16 – test

14\9\16 – test

16-9-16 – test


21.9.16 – test


23/9 – test


28\9 – test

#ce

 

[jguinch]

"|" between [ ] matches the literal character "|", so it should be removed : [\055\056\057\134]

Edited September 9, 2016 by jguinch

[pluto41]

This works also. Sort of.

#include <array.au3>
Local $date = "01.12\1967"  ; test data

Local $a = StringRegExp ( $date, "\d{1,2}\s?[-/\.\\]\s?\d{1,2}\s?[-/\.\\]\s?\d{2,4}", 3)
_ArrayDisplay($a)

 

[Chiitus]

23 hours ago, jchd said:

But one question remains: what format do you want the final result to be?

Ya, octal was stupid move, i changed to char himself. Thx!

[Chiitus]

15 hours ago, Malkey said:

If you do not want the delimliter and year only to be specifically matched then make that part of the RE pattern a non-capturing group.
See example.

#include <Array.au3>

Local $sString = StringRegExpReplace(FileRead(@ScriptFullPath), "(?is)^.*#cs\R|\R?#ce.*$", "") ; ClipGet()
ConsoleWrite($sString & @CRLF)

$a = StringRegExp($sString, "((?:[0-9]{1,2}[\h\-\\/.]{0,3}){2,3})", 3)
_ArrayDisplay($a)

; Modified $aDelim from Post#1
$aDelim = StringRegExp($sString, '(\d{1,2}\s?[\055|\056|\057|\134]\s?\d{1,2}(?:\s?[\055|\056|\057|\134]\s?\d{2,4})?)', 3)
; Note addition of "?:" in the RegExp pattern in the line above here~~~~~~~~~^
_ArrayDisplay($aDelim, "$aDelim")

; Data for variable $sString - Copied from Post#1
#cs

02 / 9 \ 16 – test

07 - 9 . 16 – test

09/9/16 – test

14\9\16 – test

16-9-16 – test


21.9.16 – test


23/9 – test


28\9 – test

#ce

 

Worked like a charm!!

Thank you!!!

[Chiitus]

9 hours ago, pluto41 said:

This works also. Sort of.

#include <array.au3>
Local $date = "01.12\1967"  ; test data

Local $a = StringRegExp ( $date, "\d{1,2}\s?[-/\.\\]\s?\d{1,2}\s?[-/\.\\]\s?\d{2,4}", 3)
_ArrayDisplay($a)

 

Not testes, but thanks anyway!!

[Chiitus]

How can i mark as solved this topic?

Amazing forum guys, thanks for the help!!!

 

~~EDIT:

I did a improve in the regex code.

Now check for a valid day (0-31; dont check by month) and check a valid month (1-12).

Including leading zero.

Check it out:

$aDelim = StringRegExp($texto, '((?:\n0[1-9]\s?[|\\/.-]\s?\b(?:0[1-9]|[1-9]|1[1-2])\b|\n[1-9]\s?[|\\/.-]\s?\b(?:0[1-9]|[1-9]|1[1-2])\b|\n[1-2][0-9]\s?[|\\/.-]\s?\b(?:0[1-9]|[1-9]|1[1-2])\b|\n3[0-1]\s?[|\\/.-]\s?\b(?:0[1-9]|[1-9]|1[1-2])\b)(?:\s?[|\\/.-]\s?\d{2,4})?)', 3)

 

Edited September 11, 2016 by Chiitus